cmake/modules/FindWebOSHelpers.cmake

   1 #.rst:
   2 # FindWebOSHelpers
   3 # --------
   4 # Finds the WebOSHelpers library
   5 #
   6 # This will define the following target:
   7 #
   8 #   ${APP_NAME_LC}::WebOSHelpers   - The webOS helpers library
   9
  10 if(NOT TARGET ${APP_NAME_LC}::${CMAKE_FIND_PACKAGE_NAME})
  11   find_package(PkgConfig)
  12   if(PKG_CONFIG_FOUND)
  13     if(WebOSHelpers_FIND_VERSION)
  14       if(WebOSHelpers_FIND_VERSION_EXACT)
  15         set(WebOSHelpers_FIND_SPEC "=${WebOSHelpers_FIND_VERSION_COMPLETE}")
  16       else()
  17         set(WebOSHelpers_FIND_SPEC ">=${WebOSHelpers_FIND_VERSION_COMPLETE}")
  18       endif()
  19     endif()
  20
  21     pkg_check_modules(PC_WEBOSHELPERS helpers${WebOSHelpers_FIND_SPEC} QUIET)
  22   endif()
  23
  24   find_path(WEBOSHELPERS_INCLUDE_DIR NAMES webos-helpers/libhelpers.h
  25                                      HINTS ${PC_WEBOSHELPERS_INCLUDEDIR})
  26   find_library(WEBOSHELPERS_LIBRARY NAMES helpers
  27                                     HINTS ${PC_WEBOSHELPERS_LIBDIR})
  28
  29   set(WEBOSHELPERS_VERSION ${PC_WEBOSHELPERS_VERSION})
  30
  31   include(FindPackageHandleStandardArgs)
  32   find_package_handle_standard_args(WebOSHelpers
  33                                     REQUIRED_VARS WEBOSHELPERS_LIBRARY WEBOSHELPERS_INCLUDE_DIR
  34                                     VERSION_VAR WEBOSHELPERS_VERSION)
  35
  36   if(WEBOSHELPERS_FOUND)
  37     add_library(${APP_NAME_LC}::${CMAKE_FIND_PACKAGE_NAME} UNKNOWN IMPORTED)
  38     set_target_properties(${APP_NAME_LC}::${CMAKE_FIND_PACKAGE_NAME} PROPERTIES
  39                                                                      IMPORTED_LOCATION "${WEBOSHELPERS_LIBRARY}"
  40                                                                      INTERFACE_INCLUDE_DIRECTORIES "${WEBOSHELPERS_INCLUDE_DIR}")
  41   else()
  42     if(WebOSHelpers_FIND_REQUIRED)
  43       message(FATAL_ERROR "WebOSHelpers libraries were not found.")
  44     endif()
  45   endif()
  46 endif()