cmake/modules/FindXRandR.cmake

   1 #.rst:
   2 # FindXRandR
   3 # ----------
   4 # Finds the XRandR library
   5 #
   6 # This will define the following target:
   7 #
   8 #   ${APP_NAME_LC}::XRandR   - The XRANDR library
   9
  10 if(NOT TARGET ${APP_NAME_LC}::${CMAKE_FIND_PACKAGE_NAME})
  11   find_package(PkgConfig)
  12
  13   if(PKG_CONFIG_FOUND)
  14     pkg_check_modules(PC_XRANDR xrandr QUIET)
  15   endif()
  16
  17   find_path(XRANDR_INCLUDE_DIR NAMES X11/extensions/Xrandr.h
  18                                HINTS ${PC_XRANDR_INCLUDEDIR})
  19   find_library(XRANDR_LIBRARY NAMES Xrandr
  20                               HINTS ${PC_XRANDR_LIBDIR})
  21
  22   set(XRANDR_VERSION ${PC_XRANDR_VERSION})
  23
  24   include(FindPackageHandleStandardArgs)
  25   find_package_handle_standard_args(XRandR
  26                                     REQUIRED_VARS XRANDR_LIBRARY XRANDR_INCLUDE_DIR
  27                                     VERSION_VAR XRANDR_VERSION)
  28
  29   if(XRANDR_FOUND)
  30     add_library(${APP_NAME_LC}::${CMAKE_FIND_PACKAGE_NAME} UNKNOWN IMPORTED)
  31     set_target_properties(${APP_NAME_LC}::${CMAKE_FIND_PACKAGE_NAME} PROPERTIES
  32                                                                      IMPORTED_LOCATION "${XRANDR_LIBRARY}"
  33                                                                      INTERFACE_INCLUDE_DIRECTORIES "${XRANDR_INCLUDE_DIR}"
  34                                                                      INTERFACE_COMPILE_DEFINITIONS HAVE_LIBXRANDR)
  35   endif()
  36 endif()