cmake/scripts/android/Install.cmake

   1 # Android packaging
   2
   3 # Configure files into packaging environment.
   4 configure_file(${CMAKE_SOURCE_DIR}/tools/android/packaging/Makefile.in
   5                ${CMAKE_BINARY_DIR}/tools/android/packaging/Makefile @ONLY)
   6 configure_file(${CMAKE_SOURCE_DIR}/tools/android/packaging/gradle.properties
   7                ${CMAKE_BINARY_DIR}/tools/android/packaging/gradle.properties COPYONLY)
   8 configure_file(${CMAKE_SOURCE_DIR}/tools/android/packaging/build.gradle
   9                ${CMAKE_BINARY_DIR}/tools/android/packaging/build.gradle COPYONLY)
  10 configure_file(${CMAKE_SOURCE_DIR}/tools/android/packaging/gradlew
  11                ${CMAKE_BINARY_DIR}/tools/android/packaging/gradlew COPYONLY)
  12 configure_file(${CMAKE_SOURCE_DIR}/tools/android/packaging/settings.gradle
  13                ${CMAKE_BINARY_DIR}/tools/android/packaging/settings.gradle COPYONLY)
  14 configure_file(${CMAKE_SOURCE_DIR}/tools/android/packaging/gradle/wrapper/gradle-wrapper.jar
  15                ${CMAKE_BINARY_DIR}/tools/android/packaging/gradle/wrapper/gradle-wrapper.jar COPYONLY)
  16 configure_file(${CMAKE_SOURCE_DIR}/tools/android/packaging/gradle/wrapper/gradle-wrapper.properties
  17                ${CMAKE_BINARY_DIR}/tools/android/packaging/gradle/wrapper/gradle-wrapper.properties COPYONLY)
  18 configure_file(${CMAKE_SOURCE_DIR}/tools/android/packaging/xbmc/jni/Android.mk
  19                ${CMAKE_BINARY_DIR}/tools/android/packaging/xbmc/jni/Android.mk COPYONLY)
  20 file(WRITE ${CMAKE_BINARY_DIR}/tools/depends/Makefile.include
  21      "$(PREFIX)/lib/${APP_NAME_LC}/lib${APP_NAME_LC}.so: ;\n")
  22
  23 string(REPLACE "." ";" APP_VERSION_CODE_LIST ${APP_VERSION_CODE})
  24 list(GET APP_VERSION_CODE_LIST 0 major)
  25 list(GET APP_VERSION_CODE_LIST 1 minor)
  26 list(GET APP_VERSION_CODE_LIST 2 patch)
  27 unset(APP_VERSION_CODE_LIST)
  28 math(EXPR APP_VERSION_CODE_ANDROID "(${major} * 100 + ${minor}) * 1000 + ${patch}")
  29 unset(major)
  30 unset(minor)
  31 unset(patch)
  32
  33 set(package_files strings.xml
  34                   colors.xml
  35                   searchable.xml
  36                   AndroidManifest.xml
  37                   build.gradle
  38                   src/Splash.java
  39                   src/Main.java
  40                   src/XBMCBroadcastReceiver.java
  41                   src/XBMCInputDeviceListener.java
  42                   src/XBMCJsonRPC.java
  43                   src/XBMCMainView.java
  44                   src/XBMCMediaSession.java
  45                   src/XBMCRecommendationBuilder.java
  46                   src/XBMCSearchableActivity.java
  47                   src/XBMCSettingsContentObserver.java
  48                   src/XBMCProperties.java
  49                   src/XBMCVideoView.java
  50                   src/XBMCFile.java
  51                   src/XBMCTextureCache.java
  52                   src/XBMCURIUtils.java
  53                   src/channels/SyncChannelJobService.java
  54                   src/channels/SyncProgramsJobService.java
  55                   src/channels/model/XBMCDatabase.java
  56                   src/channels/model/Subscription.java
  57                   src/channels/util/SharedPreferencesHelper.java
  58                   src/channels/util/TvUtil.java
  59                   src/interfaces/XBMCAudioManagerOnAudioFocusChangeListener.java
  60                   src/interfaces/XBMCSurfaceTextureOnFrameAvailableListener.java
  61                   src/interfaces/XBMCNsdManagerResolveListener.java
  62                   src/interfaces/XBMCNsdManagerRegistrationListener.java
  63                   src/interfaces/XBMCNsdManagerDiscoveryListener.java
  64                   src/interfaces/XBMCMediaDrmOnEventListener.java
  65                   src/interfaces/XBMCDisplayManagerDisplayListener.java
  66                   src/interfaces/XBMCSpeechRecognitionListener.java
  67                   src/interfaces/XBMCConnectivityManagerNetworkCallback.java
  68                   src/model/TVEpisode.java
  69                   src/model/Movie.java
  70                   src/model/TVShow.java
  71                   src/model/File.java
  72                   src/model/Album.java
  73                   src/model/Song.java
  74                   src/model/MusicVideo.java
  75                   src/model/Media.java
  76                   src/content/XBMCFileContentProvider.java
  77                   src/content/XBMCMediaContentProvider.java
  78                   src/content/XBMCContentProvider.java
  79                   src/content/XBMCYTDLContentProvider.java
  80                   )
  81 foreach(file IN LISTS package_files)
  82   configure_file(${CMAKE_SOURCE_DIR}/tools/android/packaging/xbmc/${file}.in
  83                  ${CMAKE_BINARY_DIR}/tools/android/packaging/xbmc/${file} @ONLY)
  84 endforeach()
  85
  86 # Copy files to the location expected by the Android packaging scripts.
  87 add_custom_target(bundle
  88     COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_SOURCE_DIR}/tools/android/packaging/media
  89                                                ${CMAKE_BINARY_DIR}/tools/android/packaging/media
  90     COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_SOURCE_DIR}/tools/android/packaging/xbmc/res
  91                                                ${CMAKE_BINARY_DIR}/tools/android/packaging/xbmc/res
  92     COMMAND ${CMAKE_COMMAND} -E copy_directory ${DEPENDS_PATH}/lib/python${PYTHON_VERSION} ${libdir}/python${PYTHON_VERSION}
  93     COMMAND ${CMAKE_COMMAND} -E copy_directory ${DEPENDS_PATH}/share/${APP_NAME_LC} ${datadir}/${APP_NAME_LC}
  94     COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:${APP_NAME_LC}>
  95                                      ${libdir}/${APP_NAME_LC}/$<TARGET_FILE_NAME:${APP_NAME_LC}>)
  96 add_dependencies(bundle ${APP_NAME_LC})
  97
  98 # This function is used to prepare a prefix expected by the Android packaging
  99 # scripts. It creates a bundle_files command that is added to the bundle target.
 100 function(add_bundle_file file destination relative)
 101   if(NOT TARGET bundle_files)
 102     file(REMOVE ${CMAKE_BINARY_DIR}/${CORE_BUILD_DIR}/BundleFiles.cmake)
 103     add_custom_target(bundle_files COMMAND ${CMAKE_COMMAND} -P ${CMAKE_BINARY_DIR}/${CORE_BUILD_DIR}/BundleFiles.cmake)
 104     add_dependencies(bundle bundle_files)
 105     add_dependencies(bundle_files ${APP_NAME_LC})
 106   endif()
 107
 108   if(TARGET ${file})
 109     # Add support for IMPORTED lib targets
 110     # If we need specific properties from other target types later, we can add them
 111     # here with some validity checks
 112     get_target_property(imploc_file ${file} IMPORTED_LOCATION)
 113     if(imploc_file)
 114       set(file ${imploc_file})
 115     else()
 116       return()
 117     endif()
 118   endif()
 119
 120   string(REPLACE "${relative}/" "" outfile ${file})
 121   get_filename_component(file ${file} REALPATH)
 122   get_filename_component(outdir ${outfile} DIRECTORY)
 123   file(APPEND ${CMAKE_BINARY_DIR}/${CORE_BUILD_DIR}/BundleFiles.cmake
 124        "file(COPY \"${file}\" DESTINATION \"${destination}/${outdir}\")\n")
 125   if(file MATCHES "\\.so\\..+$")
 126     get_filename_component(srcfile "${file}" NAME)
 127     string(REGEX REPLACE "\\.so\\..+$" "\.so" destfile ${srcfile})
 128     file(APPEND ${CMAKE_BINARY_DIR}/${CORE_BUILD_DIR}/BundleFiles.cmake
 129          "file(RENAME \"${destination}/${outdir}/${srcfile}\" \"${destination}/${outdir}/${destfile}\")\n")
 130   endif()
 131 endfunction()
 132
 133 # Copy files into prefix
 134 foreach(file IN LISTS XBT_FILES install_data)
 135   string(REPLACE "${CMAKE_BINARY_DIR}/" "" file ${file})
 136   add_bundle_file(${CMAKE_BINARY_DIR}/${file} ${datarootdir}/${APP_NAME_LC} ${CMAKE_BINARY_DIR})
 137 endforeach()
 138
 139 # libdvdnav is currently the only LIBRARY_FILES item remaining for android
 140 foreach(library IN LISTS LIBRARY_FILES)
 141   add_bundle_file(${library} ${libdir}/${APP_NAME_LC} ${CMAKE_BINARY_DIR})
 142 endforeach()
 143
 144 if(TARGET ${APP_NAME_LC}::Shairplay)
 145   add_bundle_file(${APP_NAME_LC}::Shairplay ${libdir} "")
 146 endif()
 147
 148 # Main targets from Makefile.in
 149 if(CPU MATCHES i686)
 150   set(CPU x86)
 151 endif()
 152 foreach(target apk apk-clean)
 153   add_custom_target(${target}
 154       COMMAND env PATH=${NATIVEPREFIX}/bin:$ENV{PATH} ${CMAKE_MAKE_PROGRAM} -j1
 155               -C ${CMAKE_BINARY_DIR}/tools/android/packaging
 156               CMAKE_SOURCE_DIR=${CMAKE_SOURCE_DIR}
 157               CC=${CMAKE_C_COMPILER}
 158               CPU=${CPU}
 159               HOST=${HOST}
 160               TOOLCHAIN=${TOOLCHAIN}
 161               PREFIX=${prefix}
 162               DEPENDS_PATH=${DEPENDS_PATH}
 163               NDKROOT=${NDKROOT}
 164               SDKROOT=${SDKROOT}
 165               STRIP=${CMAKE_STRIP}
 166               ${target}
 167       WORKING_DIRECTORY ${CMAKE_BINARY_DIR}/tools/android/packaging
 168       VERBATIM
 169   )
 170   if(NOT target STREQUAL apk-clean)
 171     add_dependencies(${target} bundle)
 172   endif()
 173 endforeach()