lib/standard_cells_3V.cir

   1 * standard_cells_3V.cir, netlists for verifying standard cells
   2 *
   3 * Conrad Ziesler and Tim Edwards, MultiGiG, Inc., 2005
   4 * Standard cells are from the IIT standard cell library.
   5 *
   6 * These cells have been modified for operation at 3.3V in a
   7 * nominally 1.8V process (generally, 0.18um feature size),
   8 * using thick oxide implant.
   9
  10 .subckt BUFX4_3V vdd gnd A Y
  11 M1 x A gnd gnd nhv l=360n w=1.35u m=1
  12 M2 x A vdd vdd phv l=360n w=2.70u m=1
  13 M3 Y x gnd gnd nhv l=360n w=1.80u m=2
  14 M4 Y x vdd vdd phv l=360n w=3.60u m=2
  15 .ends
  16
  17 .subckt BUFX2_3V vdd gnd A Y
  18 M1 x A gnd gnd nhv l=360n w=0.90u m=1
  19 M2 x A vdd vdd phv l=360n w=1.80u m=1
  20 M3 Y x gnd gnd nhv l=360n w=1.80u m=1
  21 M4 Y x vdd vdd phv l=360n w=3.60u m=1
  22 .ends
  23
  24 .subckt INVX1_3V vdd gnd A Y
  25 M1 Y A gnd gnd nhv l=360n w=0.90u m=1
  26 M2 Y A vdd vdd phv l=360n w=1.80u m=1
  27 .ends
  28
  29 .subckt NOR2X1_3V vdd gnd A B Y
  30 M1 Y A gnd gnd nhv l=360n w=0.90u m=1
  31 M2 Y B gnd gnd nhv l=360n w=0.90u m=1
  32 M3 x1 A vdd vdd phv l=360n w=3.60u m=1
  33 M4 Y  B x1  vdd phv l=360n w=3.60u m=1
  34 .ends
  35
  36 .subckt NOR4X1_3V vdd gnd A B C D Y
  37 M1 Y A gnd gnd nhv l=360n w=0.90u m=1
  38 M2 Y B gnd gnd nhv l=360n w=0.90u m=1
  39 M3 Y C gnd gnd nhv l=360n w=0.90u m=1
  40 M4 Y D gnd gnd nhv l=360n w=0.90u m=1
  41 M5 x1 A vdd vdd phv l=360n w=2.70u m=2
  42 M6 x2 B x1  vdd phv l=360n w=2.70u m=2
  43 M7 x3 C x2  vdd phv l=360n w=2.70u m=2
  44 M8 Y  D x3  vdd phv l=360n w=2.70u m=2
  45 .ends
  46
  47 .subckt NOR3X1_3V vdd gnd A B C Y
  48 M1 Y A gnd gnd nhv l=360n w=0.90u m=1
  49 M2 Y B gnd gnd nhv l=360n w=0.90u m=1
  50 M3 Y C gnd gnd nhv l=360n w=0.90u m=1
  51 M4 x1 A vdd vdd phv l=360n w=2.70u m=2
  52 M5 x2 B x1  vdd phv l=360n w=2.70u m=2
  53 M6 Y  C x2  vdd phv l=360n w=2.70u m=2
  54 .ends
  55
  56 .subckt NAND2X1_3V vdd gnd A B Y
  57 M1 x1 A gnd gnd nhv l=360n w=1.80u m=1
  58 M2 Y  B x1  gnd nhv l=360n w=1.80u m=1
  59 M3 Y  A vdd vdd phv l=360n w=1.80u m=1
  60 M4 Y  B vdd vdd phv l=360n w=1.80u m=1
  61 .ends
  62
  63 .subckt NAND3X1_3V vdd gnd A B C Y
  64 M1 x1 A gnd gnd nhv l=360n w=1.80u m=1
  65 M2 x2 B x1  gnd nhv l=360n w=1.80u m=1
  66 M3 Y  C x2  gnd nhv l=360n w=1.80u m=1
  67 M4 Y  A vdd vdd phv l=360n w=2.70u m=1
  68 M5 Y  B vdd vdd phv l=360n w=2.70u m=1
  69 M6 Y  C vdd vdd phv l=360n w=2.70u m=1
  70 .ends
  71
  72 .subckt NAND4X1_3V vdd gnd A B C D Y
  73 M1 x1 A gnd gnd nhv l=360n w=1.80u m=1
  74 M2 x2 B x1  gnd nhv l=360n w=1.80u m=1
  75 M3 x3 C x2  gnd nhv l=360n w=1.80u m=1
  76 M4 Y  D x3  gnd nhv l=360n w=1.80u m=1
  77 M5 Y  A vdd vdd phv l=360n w=2.70u m=1
  78 M6 Y  B vdd vdd phv l=360n w=2.70u m=1
  79 M7 Y  C vdd vdd phv l=360n w=2.70u m=1
  80 M8 Y  D vdd vdd phv l=360n w=2.70u m=1
  81 .ends
  82
  83 .subckt OR2X1_3V vdd gnd A B Y
  84 M1 x2 A gnd gnd nhv l=360n w=0.90u m=1
  85 M2 x2 B gnd gnd nhv l=360n w=0.90u m=1
  86 M3 x1 B vdd vdd phv l=360n w=3.60u m=1
  87 M4 x2 A x1  vdd phv l=360n w=3.60u m=1
  88 M5 Y x2 gnd gnd nhv l=360n w=0.90u m=1
  89 M6 Y x2 vdd vdd phv l=360n w=1.80u m=1
  90 .ends
  91
  92 .subckt LATCH_3V vdd gnd CLK D Q
  93 M1 cb CLK gnd gnd nhv l=360n w=0.90u m=2
  94 M2 cb CLK vdd vdd phv l=360n w=0.90u m=4
  95
  96 M3 x2 D  vdd vdd phv l=360n w=0.90u m=2
  97 M4 qb cb   x2  vdd phv l=360n w=0.90u m=2
  98 M5 x4 D  gnd  gnd nhv l=360n w=0.90u m=1
  99 M6 qb CLK   x4   gnd nhv l=360n w=0.90u m=1
 100
 101 M7  x5 Q  vdd vdd phv l=360n w=0.90u m=1
 102 M8  qb CLK    x5  vdd phv l=360n w=0.90u m=1
 103 M9  x7 Q   gnd  gnd nhv l=360n w=0.90u m=1
 104 M10 qb cb    x7   gnd nhv l=360n w=0.90u m=1
 105
 106 M11 Q qb gnd gnd nhv l=360n w=0.90u m=2
 107 M12 Q qb vdd vdd phv l=360n w=0.90u m=4
 108 .ends
 109