lib/standard_cells.cir

   1 * standard_cells.cir, netlists for verifying standard cells
   2 * Conrad Ziesler and Tim Edwards, MultiGiG, Inc.
   3 * Standard cells are from the IIT standard cell library.
   4
   5 .subckt MUX2X1 vdd gnd A B Y S
   6 M1 x1 A gnd gnd nfet l=180n w=1.80u m=1
   7 M2 x2 A vdd vdd pfet l=180n w=3.60u m=1
   8 M3 x2 S Y vdd pfet l=180n w=3.60u m=1
   9 M4 x1 sbar Y gnd nfet l=180n w=1.80u m=1
  10 M5 sbar S vdd vdd pfet l=180n w=1.80u m=1
  11 M6 sbar S gnd gnd nfet l=180n w=0.90u m=1
  12 M7 Y sbar x3 vdd pfet l=180n w=3.60u m=1
  13 M8 Y S x4 gnd nfet l=180n w=1.80u m=1
  14 M9 x3 B vdd vdd pfet l=180n w=3.60u m=1
  15 M10 x4 B gnd gnd nfet l=180n w=1.80u m=1
  16 .ends
  17
  18 .subckt TBUFX2 vdd gnd A Y En
  19 M1 enb En gnd gnd nfet l=180n w=1.80u m=1
  20 M2 enb En vdd vdd pfet l=180n w=3.60u m=1
  21 M4 i A vdd vdd pfet l=180n w=3.60u m=2
  22 M3 i enb Y vdd pfet l=180n w=3.60u m=2
  23 M5 j En Y gnd nfet l=180n w=1.80u m=2
  24 M6 j A gnd gnd nfet l=180n w=1.80u m=2
  25 .ends
  26
  27 .subckt BUFX4 vdd gnd A Y
  28 M1 x A gnd gnd nfet l=180n w=1.35u m=1
  29 M2 x A vdd vdd pfet l=180n w=2.70u m=1
  30 M3 Y x gnd gnd nfet l=180n w=1.80u m=2
  31 M4 Y x vdd vdd pfet l=180n w=3.60u m=2
  32 .ends
  33
  34 .subckt BUFX2 vdd gnd A Y
  35 M1 x A gnd gnd nfet l=180n w=0.90u m=1
  36 M2 x A vdd vdd pfet l=180n w=1.80u m=1
  37 M3 Y x gnd gnd nfet l=180n w=1.80u m=1
  38 M4 Y x vdd vdd pfet l=180n w=3.60u m=1
  39 .ends
  40
  41 .subckt INVX1 vdd gnd A Y
  42 M1 Y A gnd gnd nfet l=180n w=0.90u m=1
  43 M2 Y A vdd vdd pfet l=180n w=1.80u m=1
  44 .ends
  45
  46 .subckt INVX2 vdd gnd A Y
  47 M1 Y A gnd gnd nfet l=180n w=1.80u m=1
  48 M2 Y A vdd vdd pfet l=180n w=3.60u m=1
  49 .ends
  50
  51 .subckt NOR2X1 vdd gnd A B Y
  52 M1 Y A gnd gnd nfet l=180n w=0.90u m=1
  53 M2 Y B gnd gnd nfet l=180n w=0.90u m=1
  54 M3 x1 A vdd vdd pfet l=180n w=3.60u m=1
  55 M4 Y  B x1  vdd pfet l=180n w=3.60u m=1
  56 .ends
  57
  58 .subckt NOR3X1 vdd gnd A B C Y
  59 M1 Y A gnd gnd nfet l=180n w=0.90u m=1
  60 M2 Y B gnd gnd nfet l=180n w=0.90u m=1
  61 M3 Y C gnd gnd nfet l=180n w=0.90u m=1
  62 M4 x1 A vdd vdd pfet l=180n w=2.70u m=2
  63 M5 x2 B x1  vdd pfet l=180n w=2.70u m=2
  64 M6 Y  C x2  vdd pfet l=180n w=2.70u m=2
  65 .ends
  66
  67 .subckt NAND2X1 vdd gnd A B Y
  68 M1 x1 A gnd gnd nfet l=180n w=1.80u m=1
  69 M2 Y  B x1  gnd nfet l=180n w=1.80u m=1
  70 M3 Y  A vdd vdd pfet l=180n w=1.80u m=1
  71 M4 Y  B vdd vdd pfet l=180n w=1.80u m=1
  72 .ends
  73
  74 .subckt NAND3X1 vdd gnd A B C Y
  75 M1 x1 A gnd gnd nfet l=180n w=2.70u m=1
  76 M2 x2 B x1  gnd nfet l=180n w=2.70u m=1
  77 M3 Y  C x2  gnd nfet l=180n w=2.70u m=1
  78 M4 Y  A vdd vdd pfet l=180n w=1.80u m=1
  79 M5 Y  B vdd vdd pfet l=180n w=1.80u m=1
  80 M6 Y  C vdd vdd pfet l=180n w=1.80u m=1
  81 .ends
  82
  83 .subckt OR2X1 vdd gnd A B Y
  84 M1 x2 A gnd gnd nfet l=180n w=0.90u m=1
  85 M2 x2 B gnd gnd nfet l=180n w=0.90u m=1
  86 M3 x1 B vdd vdd pfet l=180n w=3.60u m=1
  87 M4 x2 A x1  vdd pfet l=180n w=3.60u m=1
  88 M5 Y x2 gnd gnd nfet l=180n w=0.90u m=1
  89 M6 Y x2 vdd vdd pfet l=180n w=1.80u m=1
  90 .ends
  91
  92 .subckt LATCH vdd gnd CLK D Q
  93 M1 cb CLK gnd gnd nfet l=180n w=0.90u m=2
  94 M2 cb CLK vdd vdd pfet l=180n w=0.90u m=4
  95
  96 M3 x2 D  vdd vdd pfet l=180n w=0.90u m=2
  97 M4 qb cb   x2  vdd pfet l=180n w=0.90u m=2
  98 M5 x4 D  gnd  gnd nfet l=180n w=0.90u m=1
  99 M6 qb CLK   x4   gnd nfet l=180n w=0.90u m=1
 100
 101 M7  x5 Q  vdd vdd pfet l=180n w=0.90u m=1
 102 M8  qb CLK    x5  vdd pfet l=180n w=0.90u m=1
 103 M9  x7 Q   gnd  gnd nfet l=180n w=0.90u m=1
 104 M10 qb cb    x7   gnd nfet l=180n w=0.90u m=1
 105
 106 M11 Q qb gnd gnd nfet l=180n w=0.90u m=2
 107 M12 Q qb vdd vdd pfet l=180n w=0.90u m=4
 108 .ends