ao/acinclude.m4

   1 # Configure paths for ESD
   2 # Manish Singh    98-9-30
   3 # stolen back from Frank Belew
   4 # stolen from Manish Singh
   5 # Shamelessly stolen from Owen Taylor
   6
   7 dnl AM_PATH_ESD([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
   8 dnl Test for ESD, and define ESD_CFLAGS and ESD_LIBS
   9 dnl
  10
  11 AC_DEFUN([AM_PATH_ESD],
  12 [dnl
  13 dnl Get the cflags and libraries from the esd-config script
  14 dnl
  15 AC_ARG_WITH(esd-prefix,[  --with-esd-prefix=PFX   Prefix where ESD is installed (optional)],
  16             esd_prefix="$withval", esd_prefix="")
  17 AC_ARG_WITH(esd-exec-prefix,[  --with-esd-exec-prefix=PFX Exec prefix where ESD is installed (optional)],
  18             esd_exec_prefix="$withval", esd_exec_prefix="")
  19 AC_ARG_ENABLE(esdtest, [  --disable-esdtest       Do not try to compile and run a test ESD program],
  20                     , enable_esdtest=yes)
  21
  22   if test x$esd_exec_prefix != x ; then
  23      esd_args="$esd_args --exec-prefix=$esd_exec_prefix"
  24      if test x${ESD_CONFIG+set} != xset ; then
  25         ESD_CONFIG=$esd_exec_prefix/bin/esd-config
  26      fi
  27   fi
  28   if test x$esd_prefix != x ; then
  29      esd_args="$esd_args --prefix=$esd_prefix"
  30      if test x${ESD_CONFIG+set} != xset ; then
  31         ESD_CONFIG=$esd_prefix/bin/esd-config
  32      fi
  33   fi
  34
  35   AC_PATH_PROG(ESD_CONFIG, esd-config, no)
  36   min_esd_version=ifelse([$1], ,0.2.7,$1)
  37   AC_MSG_CHECKING(for ESD - version >= $min_esd_version)
  38   no_esd=""
  39   if test "$ESD_CONFIG" = "no" ; then
  40     no_esd=yes
  41   else
  42     ESD_CFLAGS=`$ESD_CONFIG $esdconf_args --cflags`
  43     ESD_LIBS=`$ESD_CONFIG $esdconf_args --libs`
  44
  45     esd_major_version=`$ESD_CONFIG $esd_args --version | \
  46            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
  47     esd_minor_version=`$ESD_CONFIG $esd_args --version | \
  48            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
  49     esd_micro_version=`$ESD_CONFIG $esd_config_args --version | \
  50            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
  51     if test "x$enable_esdtest" = "xyes" ; then
  52       ac_save_CFLAGS="$CFLAGS"
  53       ac_save_LIBS="$LIBS"
  54       CFLAGS="$CFLAGS $ESD_CFLAGS"
  55       LIBS="$LIBS $ESD_LIBS"
  56 dnl
  57 dnl Now check if the installed ESD is sufficiently new. (Also sanity
  58 dnl checks the results of esd-config to some extent
  59 dnl
  60       rm -f conf.esdtest
  61       AC_TRY_RUN([
  62 #include <stdio.h>
  63 #include <stdlib.h>
  64 #include <string.h>
  65 #include <esd.h>
  66
  67 char*
  68 my_strdup (char *str)
  69 {
  70   char *new_str;
  71
  72   if (str)
  73     {
  74       new_str = malloc ((strlen (str) + 1) * sizeof(char));
  75       strcpy (new_str, str);
  76     }
  77   else
  78     new_str = NULL;
  79
  80   return new_str;
  81 }
  82
  83 int main ()
  84 {
  85   int major, minor, micro;
  86   char *tmp_version;
  87
  88   system ("touch conf.esdtest");
  89
  90   /* HP/UX 9 (%@#!) writes to sscanf strings */
  91   tmp_version = my_strdup("$min_esd_version");
  92   if (sscanf(tmp_version, "%d.%d.%d", &major, &minor, &micro) != 3) {
  93      printf("%s, bad version string\n", "$min_esd_version");
  94      exit(1);
  95    }
  96
  97    if (($esd_major_version > major) ||
  98       (($esd_major_version == major) && ($esd_minor_version > minor)) ||
  99       (($esd_major_version == major) && ($esd_minor_version == minor) && ($esd_micro_version >= micro)))
 100     {
 101       return 0;
 102     }
 103   else
 104     {
 105       printf("\n*** 'esd-config --version' returned %d.%d.%d, but the minimum version\n", $esd_major_version, $esd_minor_version, $esd_micro_version);
 106       printf("*** of ESD required is %d.%d.%d. If esd-config is correct, then it is\n", major, minor, micro);
 107       printf("*** best to upgrade to the required version.\n");
 108       printf("*** If esd-config was wrong, set the environment variable ESD_CONFIG\n");
 109       printf("*** to point to the correct copy of esd-config, and remove the file\n");
 110       printf("*** config.cache before re-running configure\n");
 111       return 1;
 112     }
 113 }
 114
 115 ],, no_esd=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 116        CFLAGS="$ac_save_CFLAGS"
 117        LIBS="$ac_save_LIBS"
 118      fi
 119   fi
 120   if test "x$no_esd" = x ; then
 121      AC_MSG_RESULT(yes)
 122      ifelse([$2], , :, [$2])
 123   else
 124      AC_MSG_RESULT(no)
 125      if test "$ESD_CONFIG" = "no" ; then
 126        echo "*** The esd-config script installed by ESD could not be found"
 127        echo "*** If ESD was installed in PREFIX, make sure PREFIX/bin is in"
 128        echo "*** your path, or set the ESD_CONFIG environment variable to the"
 129        echo "*** full path to esd-config."
 130      else
 131        if test -f conf.esdtest ; then
 132         :
 133        else
 134           echo "*** Could not run ESD test program, checking why..."
 135           CFLAGS="$CFLAGS $ESD_CFLAGS"
 136           LIBS="$LIBS $ESD_LIBS"
 137           AC_TRY_LINK([
 138 #include <stdio.h>
 139 #include <esd.h>
 140 ],      [ return 0; ],
 141         [ echo "*** The test program compiled, but did not run. This usually means"
 142           echo "*** that the run-time linker is not finding ESD or finding the wrong"
 143           echo "*** version of ESD. If it is not finding ESD, you'll need to set your"
 144           echo "*** LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf to point"
 145           echo "*** to the installed location  Also, make sure you have run ldconfig if that"
 146           echo "*** is required on your system"
 147           echo "***"
 148           echo "*** If you have an old version installed, it is best to remove it, although"
 149           echo "*** you may also be able to get things to work by modifying LD_LIBRARY_PATH"],
 150         [ echo "*** The test program failed to compile or link. See the file config.log for the"
 151           echo "*** exact error that occured. This usually means ESD was incorrectly installed"
 152           echo "*** or that you have moved ESD since it was installed. In the latter case, you"
 153           echo "*** may want to edit the esd-config script: $ESD_CONFIG" ])
 154           CFLAGS="$ac_save_CFLAGS"
 155           LIBS="$ac_save_LIBS"
 156        fi
 157      fi
 158      ESD_CFLAGS=""
 159      ESD_LIBS=""
 160      ifelse([$3], , :, [$3])
 161   fi
 162   AC_SUBST(ESD_CFLAGS)
 163   AC_SUBST(ESD_LIBS)
 164   rm -f conf.esdtest
 165 ])
 166
 167
 168 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
 169 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
 170 dnl also defines GSTUFF_PKG_ERRORS on error
 171 AC_DEFUN([PKG_CHECK_MODULES], [
 172   succeeded=no
 173
 174   if test -z "$PKG_CONFIG"; then
 175     AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 176   fi
 177
 178   if test "$PKG_CONFIG" = "no" ; then
 179      echo "*** The pkg-config script could not be found. Make sure it is"
 180      echo "*** in your path, or set the PKG_CONFIG environment variable"
 181      echo "*** to the full path to pkg-config."
 182      echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
 183   else
 184      PKG_CONFIG_MIN_VERSION=0.9.0
 185      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
 186         AC_MSG_CHECKING(for $2)
 187
 188         if $PKG_CONFIG --exists "$2" ; then
 189             AC_MSG_RESULT(yes)
 190             succeeded=yes
 191
 192             AC_MSG_CHECKING($1_CFLAGS)
 193             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
 194             AC_MSG_RESULT($$1_CFLAGS)
 195
 196             AC_MSG_CHECKING($1_LIBS)
 197             $1_LIBS=`$PKG_CONFIG --libs "$2"`
 198             AC_MSG_RESULT($$1_LIBS)
 199         else
 200             $1_CFLAGS=""
 201             $1_LIBS=""
 202             ## If we have a custom action on failure, don't print errors, but
 203             ## do set a variable so people can do so.
 204             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
 205             ifelse([$4], ,echo $$1_PKG_ERRORS,)
 206         fi
 207
 208         AC_SUBST($1_CFLAGS)
 209         AC_SUBST($1_LIBS)
 210      else
 211         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
 212         echo "*** See http://www.freedesktop.org/software/pkgconfig"
 213      fi
 214   fi
 215
 216   if test $succeeded = yes; then
 217      ifelse([$3], , :, [$3])
 218   else
 219      ifelse([$4], , AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.]), [$4])
 220   fi
 221 ])