test.lisp

   1 ;;; -*- show-trailing-whitespace: t; indent-tabs-mode: nil -*-
   2
   3 ;;; Copyright (c) 2007,2008 David Lichteblau, Ivan Shvedunov.
   4 ;;; All rights reserved.
   5
   6 ;;; Redistribution and use in source and binary forms, with or without
   7 ;;; modification, are permitted provided that the following conditions
   8 ;;; are met:
   9 ;;;
  10 ;;;   * Redistributions of source code must retain the above copyright
  11 ;;;     notice, this list of conditions and the following disclaimer.
  12 ;;;
  13 ;;;   * Redistributions in binary form must reproduce the above
  14 ;;;     copyright notice, this list of conditions and the following
  15 ;;;     disclaimer in the documentation and/or other materials
  16 ;;;     provided with the distribution.
  17 ;;;
  18 ;;; THIS SOFTWARE IS PROVIDED BY THE AUTHOR 'AS IS' AND ANY EXPRESSED
  19 ;;; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  20 ;;; WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  21 ;;; ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY
  22 ;;; DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  23 ;;; DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE
  24 ;;; GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  25 ;;; INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  26 ;;; WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
  27 ;;; NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  28 ;;; SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29
  30 (in-package :xuriella)
  31
  32 (defparameter *tests-directory*
  33   "/home/david/src/XSLT-testsuite-04/testsuite/TESTS/")
  34
  35 (defclass test-case ()
  36   ((id :initarg :id :accessor test-id)
  37    (category :initarg :category :accessor test-category)
  38    (operation :initarg :operation :accessor test-operation)
  39    (data-pathname :initarg :data-pathname :accessor test-data-pathname)
  40    (stylesheet-pathname :initarg :stylesheet-pathname
  41                         :accessor test-stylesheet-pathname)
  42    (data-pathname-2 :initarg :data-pathname-2 :accessor test-data-pathname-2)
  43    (stylesheet-pathname-2 :initarg :stylesheet-pathname-2
  44                           :accessor test-stylesheet-pathname-2)
  45    (output-pathname :initarg :output-pathname
  46                     :accessor test-official-output-pathname)
  47    (output-compare :initarg :output-compare
  48                    :accessor test-output-compare)))
  49
  50 (defmethod print-object ((object test-case) stream)
  51   (print-unreadable-object (object stream :identity nil :type t)
  52     (format stream "~A ~A/~A"
  53             (test-operation object)
  54             (test-category object)
  55             (test-id object))))
  56
  57
  58 ;;;; SIMPLIFY-TESTS
  59
  60 ;;; Translate catalog.xml into an actually usable katalog.xml
  61 ;;; by running the test cases through xsltproc to see what it thinks
  62 ;;; about them.
  63
  64 (defun simplify-tests (&optional (d *tests-directory*))
  65   (with-open-file (stream (merge-pathnames "katalog.xml" d)
  66                           :direction :output
  67                           :if-exists :supersede
  68                           :element-type '(unsigned-byte 8))
  69     (cxml:with-xml-output (cxml:make-octet-stream-sink stream)
  70       (cxml:with-element "simplified-test-suite"
  71         (klacks:with-open-source
  72             (source (klacks:make-tapping-source
  73                      (cxml:make-source (merge-pathnames "catalog.xml" d))))
  74           (let ((*default-pathname-defaults* (merge-pathnames d)))
  75             (map-original-tests #'simplify-test source)))))))
  76
  77 (defun map-original-tests (run-test source &key (test (constantly t)))
  78   (let ((total 0)
  79         (pass 0)
  80         major-path)
  81     (loop
  82        while (klacks:find-event source :start-element)
  83        for lname = (klacks:current-lname source)
  84        do
  85        (cond
  86          ((equal lname "major-path")
  87           (klacks:skip source :start-element)
  88           (setf major-path
  89                 (namestring
  90                  (merge-pathnames (klacks:consume-characters source)))))
  91          ((equal lname "test-case")
  92           (let* ((<test-case>
  93                   (stp:document-element
  94                    (klacks:serialize-element source (stp:make-builder))))
  95                  (test-case (parse-original-test major-path <test-case>)))
  96             (when (funcall test test-case)
  97               (incf total)
  98               (when (funcall run-test test-case)
  99                 (incf pass)))))
 100          (t
 101           (klacks:skip source :start-element))))
 102     (format t "~&Passed ~D/~D tests.~%" pass total)))
 103
 104 (defun parse-original-test (major-path <test-case>)
 105   (let* ((file-path
 106           (stp:string-value
 107            (stp:find-recursively-if (stp:of-name "file-path") <test-case>)))
 108          (base (concatenate 'string major-path "/" file-path))
 109          (out-base (concatenate 'string major-path "/REF_OUT/" file-path))
 110          (scenario
 111           (stp:find-recursively-if (stp:of-name "scenario") <test-case>))
 112          data
 113          stylesheet
 114          supplemental-stylesheet
 115          supplemental-data
 116          output
 117          compare)
 118     (dolist (<input> (stp:filter-recursively (stp:of-name "input-file")
 119                                              <test-case>))
 120       (let ((role (stp:attribute-value <input> "role"))
 121             (path (concatenate 'string base "/" (stp:string-value <input>))))
 122         (cond
 123           ((equal role "principal-data")
 124            (setf data path))
 125           ((equal role "principal-stylesheet")
 126            (setf stylesheet path))
 127           ((equal role "supplemental-stylesheet")
 128            (setf supplemental-stylesheet path))
 129           ((equal role "supplemental-data")
 130            (setf supplemental-data path))
 131           (t
 132            (error "unrecognized role: ~A" role)))))
 133     (dolist (<output> (stp:filter-recursively (stp:of-name "output-file")
 134                                             <test-case>))
 135       (let ((role (stp:attribute-value <output> "role"))
 136             (path (concatenate 'string out-base
 137                                "/"
 138                                (stp:string-value <output>))))
 139         (cond
 140           ((equal role "principal")
 141            (setf output path)
 142            (setf compare (stp:attribute-value <output> "compare")))
 143           (t
 144            (error "unrecognized role: ~A" role)))))
 145     (make-instance 'test-case
 146                    :id (stp:attribute-value <test-case> "id")
 147                    :category (stp:attribute-value <test-case> "category")
 148                    :operation (stp:attribute-value scenario "operation")
 149                    :data-pathname data
 150                    :stylesheet-pathname stylesheet
 151                    :stylesheet-pathname-2 supplemental-stylesheet
 152                    :data-pathname-2 supplemental-data
 153                    :output-pathname output
 154                    :output-compare compare)))
 155
 156 (defun write-simplified-test (test-case operation)
 157   (cxml:with-element "test-case"
 158     (cxml:attribute "id" (test-id test-case))
 159     (cxml:attribute "category" (test-category test-case))
 160     (flet ((p (l p)
 161              (cxml:attribute l (and p (namestring p)))))
 162       (p "data" (test-data-pathname test-case))
 163       (p "stylesheet" (noindent-stylesheet-pathname test-case))
 164       (p "data-2" (test-data-pathname-2 test-case))
 165       (p "stylesheet-2" (test-stylesheet-pathname-2 test-case))
 166       (p "output" (test-official-output-pathname test-case))
 167       (p "compare" (test-output-compare test-case)))
 168     (cxml:attribute "operation" operation)))
 169
 170 (defun test-output-pathname (test type)
 171   (make-pathname :name (test-id test)
 172                  :type type
 173                  :defaults (test-data-pathname test)))
 174
 175 (defun sanitize-stylesheet (in out)
 176   (if (probe-file in)
 177       (handler-case
 178           (let ((d (cxml:parse (pathname in) (stp:make-builder))))
 179             (xpath:with-namespaces ((nil #.*xsl*))
 180               (xpath:do-node-set (output (xpath:evaluate "//output" d))
 181                 (let ((a (stp:find-attribute-named output "indent")))
 182                   (when a
 183                     (stp:detach a)))))
 184             (with-open-file (s out
 185                                :direction :output
 186                                :if-exists :rename-and-delete
 187                                :element-type '(unsigned-byte 8))
 188               (stp:serialize d (cxml:make-octet-stream-sink s))))
 189         (error (c)
 190           (warn "ignoring bogus stylesheet ~A: ~A" in c)
 191           (copy-file in out)))
 192       (warn "oops, ignoring missing stylesheet: ~A" in)))
 193
 194 (defun noindent-stylesheet-pathname (test-case)
 195   (make-pathname :type "noindent-xsl"
 196                  :defaults (test-stylesheet-pathname test-case)))
 197
 198 (defun simplify-test (test-case)
 199   (flet ((report (status &optional (fmt "") &rest args)
 200            (format t "~&~A ~A [~A]~?~%"
 201                    status
 202                    (test-id test-case)
 203                    (test-category test-case)
 204                    fmt
 205                    args)))
 206     (let* ((data (test-data-pathname test-case))
 207            (stylesheet (test-stylesheet-pathname test-case))
 208            (noindent-stylesheet (noindent-stylesheet-pathname test-case))
 209            #+xuriella::xsltproc
 210            (out (test-output-pathname test-case "xsltproc"))
 211            (saxon-out (test-output-pathname test-case "saxon")))
 212       (sanitize-stylesheet stylesheet noindent-stylesheet)
 213       (if (equal (test-operation test-case) "standard")
 214           (handler-case
 215               (progn
 216                 #+xuriella::xsltproc (xsltproc noindent-stylesheet data out)
 217                 (saxon noindent-stylesheet data saxon-out)
 218                 (report "PASS")
 219                 (write-simplified-test test-case "standard")
 220                 t)
 221             (error (c)
 222               (report "FAIL" ": ~A" c)
 223               (write-simplified-test test-case "execution-error")
 224               nil))
 225           (handler-case
 226               (progn
 227                 #+xuriella::xsltproc
 228                 (xsltproc noindent-stylesheet data "/dev/null")
 229                 (saxon noindent-stylesheet data "/dev/null")
 230                 (report "FAIL" ": expected error not signalled")
 231                 ;; let's ignore unexpected successes for now
 232                 nil)
 233             (error (c)
 234               (report "PASS" ": expected error ~A" c)
 235               (write-simplified-test test-case "execution-error")
 236               t))))))
 237
 238 (defun xsltproc (stylesheet input output)
 239   (flet ((full-namestring (x)
 240            (namestring (merge-pathnames x))))
 241     (let* ((asdf::*verbose-out* (make-string-output-stream))
 242            (code (asdf:run-shell-command
 243                   "cd ~S && xsltproc ~S ~S >~S"
 244                   (full-namestring "")
 245                   (full-namestring stylesheet)
 246                   (full-namestring input)
 247                   (full-namestring output))))
 248       (unless (zerop code)
 249         (error "running xsltproc failed with code ~A [~%~A~%]"
 250                code
 251                (get-output-stream-string asdf::*verbose-out*))))))
 252
 253 (defun saxon (stylesheet input output)
 254   (flet ((full-namestring (x)
 255            (namestring (merge-pathnames x))))
 256     (let* ((asdf::*verbose-out* (make-string-output-stream))
 257            (code (asdf:run-shell-command
 258                   "cd ~S && java -jar /usr/share/java/saxon.jar ~S ~S >~S"
 259                   (full-namestring "")
 260                   (full-namestring input)
 261                   (full-namestring stylesheet)
 262                   (full-namestring output))))
 263       (unless (zerop code)
 264         (error "running saxon failed with code ~A [~%~A~%]"
 265                code
 266                (get-output-stream-string asdf::*verbose-out*))))))
 267
 268
 269 ;;;; RUN-TESTS and DRIBBLE-TESTS
 270
 271 ;;; Process katalog.xml
 272
 273 (defun dribble-tests
 274     (&key filter (directory *tests-directory*) (file "TEST"))
 275   (let ((*package* (find-package 'cl-user))
 276         (*print-circle* nil))
 277     (with-open-file (dribble
 278                      (merge-pathnames file
 279                                       (slot-value (asdf:find-system :xuriella)
 280                                                   'asdf::relative-pathname))
 281                      :direction :output
 282                      :if-exists :supersede
 283                      :external-format :utf-8)
 284       (let* ((dribble (make-broadcast-stream dribble *standard-output*))
 285              (*standard-output* dribble)
 286              (*trace-output* dribble)
 287              (*error-output* dribble)
 288              (*terminal-io* (make-two-way-stream *standard-input* dribble)))
 289         (handler-bind ((warning
 290                         (lambda (c)
 291                           (warn "~A" (replace-junk (princ-to-string c)))
 292                           (muffle-warning c))))
 293           (run-tests :filter filter
 294                      :directory directory))))))
 295
 296 (defparameter *bad-tests*
 297   '( ;; some tests wants us to recover from this error, yet this one doesn't:
 298     "copy_copy61"
 299     "copy_copy62"
 300
 301     ;; we perform recovery, but saxon doesn't.  Recovery results in non-XML
 302     ;; output, which we can't parse for comparison against the official test
 303     ;; case.
 304     "output_output75"
 305
 306     ;; we'd pass these tests, but the test authors forgot to declare the
 307     ;; entity they're writing, so we can't parse it for comparison.
 308     "output_output06"
 309     "output_output10"
 310     "output_output61"
 311
 312     ;; another similar test where the output is unparsable, except that
 313     ;; here an entity declaration wouldn't have helped either:
 314     "Copying_ResultTreeFragmentWithEscapedText"
 315
 316     ;; the following tests take a lot of time due to the problems of current matching algorithm:
 317     "impincl_impincl16"
 318     "match_match13"
 319     ;; stack exhaustion -- matching problem i think
 320     "Keys_PerfRepro3"
 321     ;; probably the same problem (but I haven't checked):
 322     "numbering_numbering03"
 323     "numbering_numbering10"
 324     "numbering_numbering11"
 325     "numbering_numbering80"
 326     "numbering_numbering81"
 327     "numbering_numbering94"
 328     "numbering_numbering95"
 329     "Import__91164"))
 330
 331 (defun run-tests (&key filter (directory *tests-directory*))
 332   (when (typep filter '(or string cons))
 333     (setf filter (cl-ppcre:create-scanner filter)))
 334   (klacks:with-open-source
 335       (source (klacks:make-tapping-source
 336                (cxml:make-source (merge-pathnames "katalog.xml" directory))))
 337     (let ((*default-pathname-defaults* (merge-pathnames directory)))
 338       (map-tests #'run-test
 339                  source
 340                  :test (lambda (test)
 341                          (and (or (null filter)
 342                                   (cl-ppcre:all-matches
 343                                    filter
 344                                    (format nil "~A/~A"
 345                                            (test-category test)
 346                                            (test-id test))))
 347                               (not (find (test-id test)
 348                                          *bad-tests*
 349                                          :test #'equal))))))))
 350
 351 (defun run-named-test (name &optional (d *tests-directory*))
 352   (let ((*break-on-signals* 'error))
 353     (run-tests :filter (format nil "/~A$" name) :directory d)))
 354
 355 (defun copy-file (p q)
 356   (with-open-file (in p :element-type '(unsigned-byte 8))
 357     (with-open-file (out q
 358                          :element-type '(unsigned-byte 8)
 359                          :direction :output
 360                          :if-exists :rename-and-delete)
 361       (let ((buf (make-array 8192 :element-type '(unsigned-byte 8))))
 362         (loop for pos = (read-sequence buf in)
 363            until (zerop pos)
 364            do (write-sequence buf out :end pos))))))
 365
 366 (defun find-named-test (name &optional (d *tests-directory*))
 367   (klacks:with-open-source
 368       (source (klacks:make-tapping-source
 369                (cxml:make-source (merge-pathnames "katalog.xml" d))))
 370     (block nil
 371       (map-tests (lambda (test)
 372                    (return test))
 373                  source
 374                  :test (lambda (test) (equal (test-id test) name))))))
 375
 376 (defun copy-test-files (name &optional (d *tests-directory*))
 377   (let* ((test (find-named-test name d))
 378          (*default-pathname-defaults* (merge-pathnames d))
 379          (*break-on-signals* 'error)
 380          (target-dir (merge-pathnames "copied-test/"
 381                                       (asdf:component-pathname
 382                                        (asdf:find-system :xuriella))))
 383          (xsl (merge-pathnames "test.xsl" target-dir))
 384          (xml (merge-pathnames "test.xml" target-dir))
 385          (txt (merge-pathnames "official-output.txt" target-dir))
 386          (expected (merge-pathnames "expected.xml" target-dir))
 387          (actual (merge-pathnames "actual.xml" target-dir)))
 388     (ensure-directories-exist target-dir)
 389     (copy-file (test-stylesheet-pathname test) xsl)
 390     (copy-file (test-data-pathname test) xml)
 391     (when (test-official-output-pathname test)
 392       (copy-file (test-official-output-pathname test) txt))
 393     (format t "Test stylesheet copied to:~%  ~A~%~%" xsl)
 394     (format t "Test data copied to:~%  ~A~%~%" xml)
 395     (when (test-official-output-pathname test)
 396       (format t "Official output file:~%  ~A~%~%" txt))
 397     (format t "Run xsltproc like this:~%  cd ~A~%  xsltproc ~A ~A >~A~%~%"
 398             (namestring target-dir)
 399             (enough-namestring xsl target-dir)
 400             (enough-namestring xml target-dir)
 401             (enough-namestring expected target-dir))
 402     (format t "Run saxon like this:~%  cd ~A~%  java -jar /usr/share/java/saxon.jar ~A ~A >~A~%~%"
 403             (namestring target-dir)
 404             (enough-namestring xml target-dir)
 405             (enough-namestring xsl target-dir)
 406             (enough-namestring expected target-dir))
 407     (format t "Run MSXSL like this:~%  cd ~A~%  wine msxsl.exe ~A ~A >~A~%~%"
 408             (namestring target-dir)
 409             (enough-namestring xml target-dir)
 410             (enough-namestring xsl target-dir)
 411             (enough-namestring expected target-dir))
 412     (format t "Run xuriella like this:~%")
 413     `(apply-stylesheet ,xsl ,xml :output ,actual)))
 414
 415 (defun map-tests (run-test source &key (test (constantly t)))
 416   (let ((total 0)
 417         (pass 0))
 418     (loop
 419        while (klacks:find-event source :start-element)
 420        for lname = (klacks:current-lname source)
 421        do
 422        (cond
 423          ((equal lname "test-case")
 424           (let* ((<test-case>
 425                   (stp:document-element
 426                    (klacks:serialize-element source (stp:make-builder))))
 427                  (test-case (parse-test <test-case>)))
 428             (when (funcall test test-case)
 429               (incf total)
 430               (when (funcall run-test test-case)
 431                 (incf pass)))))
 432          (t
 433           (klacks:skip source :start-element))))
 434     (format t "~&Passed ~D/~D tests.~%" pass total)))
 435
 436 (defun parse-test (<test-case>)
 437   (stp:with-attributes (id category operation
 438                            data stylesheet data-2 stylesheet-2
 439                            output compare)
 440       <test-case>
 441     (make-instance 'test-case
 442                    :id id
 443                    :category category
 444                    :operation operation
 445                    :data-pathname data
 446                    :stylesheet-pathname stylesheet
 447                    :data-pathname-2 data-2
 448                    :stylesheet-pathname-2 stylesheet-2
 449                    :output-pathname output
 450                    :output-compare compare)))
 451
 452 ;; read from file P, skipping the XMLDecl or TextDecl and Doctype at the
 453 ;; beginning, if any.
 454 (defun slurp-for-comparison (p)
 455   (with-open-file (s p :element-type '(unsigned-byte 8))
 456     (unless (and (eql (read-byte s nil) #xef)
 457                  (eql (read-byte s nil) #xbb)
 458                  (eql (read-byte s nil) #xbf))
 459       (file-position s 0))
 460     (if (plusp (file-length s))
 461         (slurp-for-comparison-1 p s t)
 462         "<wrapper/>")))
 463
 464 (defun slurp-for-comparison-1 (p s junk-info)
 465   (let ((pos (file-position s))         ;for UTF-8 "BOM"
 466         (xstream (runes:make-xstream s :speed 1))
 467         (prev-pos 0))
 468     (setf (runes:xstream-name xstream)
 469           (cxml::make-stream-name
 470            :entity-name "main document"
 471            :entity-kind :main
 472            :uri (cxml::pathname-to-uri (merge-pathnames p))))
 473     (let ((source
 474            (flet ((er (pub sys)
 475                     pub sys
 476                     (flexi-streams:make-in-memory-input-stream
 477                      #())))
 478              (cxml:make-source xstream
 479                                :pathname p
 480                                :entity-resolver #'er))))
 481       (unless (eq junk-info :nada)
 482         (loop
 483            for key = (progn
 484                        (setf prev-pos (runes:xstream-position xstream))
 485                        (klacks:peek-next source))
 486            until (eq key :start-document))
 487         (cxml::with-source (source cxml::context)
 488           (when (eq (cxml::zstream-token-category
 489                      (cxml::main-zstream cxml::context))
 490                     :NMTOKEN)
 491             ;; oops, doesn't look like XML at all
 492             (file-position s pos)
 493             (return-from slurp-for-comparison-1
 494               (slurp-for-comparison-1 p s :nada)))))
 495       (etypecase junk-info
 496         (integer
 497          (dotimes (x junk-info)
 498            (setf prev-pos (runes:xstream-position xstream))
 499            (klacks:peek-next source)))
 500         ((eql t)
 501          (let ((nskip 0))
 502            (handler-case
 503                (loop
 504                   (case (klacks:peek-next source)
 505                     (:start-element (return))
 506                     (:characters
 507                      (if (whitespacep (klacks:current-characters source))
 508                          (incf nskip)
 509                          (return)))
 510                     (t
 511                      (incf nskip))))
 512              ((or file-error cxml:xml-parse-error) ()
 513                (when (zerop nskip)
 514                  (setf nskip nil))))
 515            ;; retry
 516            (with-open-file (u p :element-type '(unsigned-byte 8))
 517              (file-position u pos)
 518              (return-from slurp-for-comparison-1
 519                (slurp-for-comparison-1 p u nskip)))))
 520         ((member nil :nada)))
 521       (with-output-to-string (r)
 522         (let* ((seen-char
 523                 (cxml::with-source (source cxml::context)
 524                   (ecase (cxml::zstream-token-category
 525                           (cxml::main-zstream cxml::context))
 526                     (:seen-< #\<)
 527                     (:? #\?)
 528                     ((nil :s)
 529                      (setf prev-pos (runes:xstream-position xstream))
 530                      nil))))
 531                (off-by-one-p (or seen-char (eq junk-info :nada)))
 532                (new-pos (- prev-pos (if off-by-one-p 1 0))))
 533           ;; copy doctype over
 534           (with-open-file (u p :element-type '(unsigned-byte 8))
 535             (file-position u pos)
 536             (let ((y (runes:make-xstream u :speed 1)))
 537               (loop
 538                  while (< (runes:xstream-position y) new-pos)
 539                  do (write-char (runes:read-rune y) r))))
 540           (write-line "<wrapper>" r)
 541           (when seen-char
 542             (write-char seen-char r)))
 543         (loop
 544            for char = (runes:read-rune xstream)
 545            until (eq char :eof)
 546            do (write-char char r))
 547         (write-line "</wrapper>" r)))))
 548
 549 (defun parse-for-comparison (p)
 550   (let* ((d (flet ((er (pub sys)
 551                     pub sys
 552                     (flexi-streams:make-in-memory-input-stream
 553                      #())))
 554               (cxml:parse (slurp-for-comparison p)
 555                           (make-text-normalizer (stp:make-builder))
 556                           :entity-resolver #'er)))
 557          (de (stp:document-element d)))
 558     (let ((first (stp:first-child de)))
 559       (when (typep first 'stp:text)
 560         (cond
 561           ((whitespacep (stp:data first))
 562            (stp:delete-child first de))
 563           (t
 564            (setf (stp:data first)
 565                  (cl-ppcre:regex-replace #.(format nil "^[~A]+" *whitespace*)
 566                                          (stp:data first)
 567                                          ""))))))
 568     (let ((last (stp:last-child de)))
 569       (when (typep last 'stp:text)
 570         (cond
 571           ((whitespacep (stp:data last))
 572            (stp:delete-child last de))
 573           (t
 574            (setf (stp:data last)
 575                  (cl-ppcre:regex-replace #.(format nil "[~A]+$" *whitespace*)
 576                                          (stp:data last)
 577                                          ""))))))
 578     d))
 579
 580 (defun output-equal-p (compare p q &key normalize)
 581   (handler-case
 582       (ecase compare
 583         (:xml (xml-output-equal-p p q normalize))
 584         (:html (html-output-equal-p p q))
 585         (:text (text-output-equal-p p q)))
 586     ((or error parse-number::invalid-number) (c)
 587       (warn "comparison failed: ~A" c)
 588       nil)))
 589
 590 ;; Workaround for namespace_namespace23 and other tests:
 591 ;;  - For these tests, saxon and msxsl output a declaration for the XSL
 592 ;;    namespace without using that declaration.
 593 ;;  - I think saxon and msxsl are both wrong.
 594 ;;  - The official test output agrees with my assessment.
 595 ;;    (So does libxslt, but that's not to be trusted. :-))
 596 ;;  - Here's the catch: The official test output is broken in its whitespace
 597 ;;    handling.
 598 ;; So let's normalize spaces in test output that looks like an XSLT
 599 ;; stylesheet, allowing us to pass these tests using the official test output.
 600 (defun maybe-normalize-test-spaces (wrapper force)
 601   (stp:do-children (wrapper-child wrapper)
 602     (when (and (typep wrapper-child 'stp:element)
 603                (or (equal (stp:namespace-uri wrapper-child) *xsl*)
 604                    force))
 605       (strip-stylesheet wrapper-child)
 606       (labels ((recurse (e &optional preserve)
 607                  (stp:do-children (child e)
 608                    (typecase child
 609                      (stp:text
 610                       (setf (stp:data child)
 611                             (normalize-whitespace (stp:data child))))
 612                      (stp:element
 613                          (stp:with-attributes ((space "space" *xml*))
 614                              child
 615                            (let ((new-preserve
 616                                   (cond
 617                                     ((namep child "text") t)
 618                                     ((not space) preserve)
 619                                     ((equal space "preserve") t)
 620                                     (t nil))))
 621                              (recurse child new-preserve))))))))
 622         (recurse wrapper-child)))))
 623
 624 (defun xml-output-equal-p (p q normalize)
 625   (let ((r (parse-for-comparison p))
 626         (s (parse-for-comparison q)))
 627     (maybe-normalize-test-spaces (stp:document-element r) normalize)
 628     (maybe-normalize-test-spaces (stp:document-element s) normalize)
 629     (and (let ((u (stp:document-type r))
 630                (v (stp:document-type s)))
 631            (if u
 632                (and v (node= u v))
 633                (null v)))
 634          (node= (stp:document-element r) (stp:document-element s)))))
 635
 636 ;; FIXME: don't do this in <pre> etc.
 637 (defun normalize-html-whitespace (node)
 638   (when (typep node 'stp:parent-node)
 639     ;; ignore newlines after start tags completely
 640     (let ((first (stp:first-child node)))
 641       (when (and (typep first 'stp:text)
 642                  (alexandria:starts-with #\newline (stp:data first)))
 643         (setf (stp:data first) (subseq (stp:data first) 1))))
 644     ;; ignore newlines before end tags completely
 645     (let ((last (stp:last-child node)))
 646       (when (and (typep last 'stp:text)
 647                  (alexandria:ends-with #\newline (stp:data last)))
 648         (setf (stp:data last)
 649               (subseq (stp:data last) 0 (length (stp:data last))))))
 650     ;; normalize sequences of whitespace
 651     (stp:do-children (child node)
 652       (if (typep child 'stp:text)
 653           (setf (stp:data child)
 654                 (let ((str (normalize-whitespace (stp:data child))))
 655                   (when
 656                       ;; FIXME!  Here we remove whitespace entirely.
 657                       ;; Totally incorrect, but I don't see how we could
 658                       ;; watch Saxon's output otherwise.
 659                       (equal str " ")
 660                     (setf str ""))
 661                   str))
 662           (normalize-html-whitespace child)))
 663     ;; just to be sure, join adjacent nodes
 664     (cxml-stp-impl::normalize-text-nodes! node)))
 665
 666 ;; FIXME: this check is too lenient, because chtml is an error-correcting
 667 ;; parser.
 668 (defun html-output-equal-p (p q)
 669   (let ((r (chtml:parse (pathname p) (stp:make-builder)))
 670         (s (chtml:parse (pathname q) (stp:make-builder))))
 671     (normalize-html-whitespace r)
 672     (normalize-html-whitespace s)
 673     (node= (stp:document-element r) (stp:document-element s))))
 674
 675 (defun text-output-equal-p (p q)
 676   (with-open-file (a p :element-type '(unsigned-byte 8))
 677     (with-open-file (b q :element-type '(unsigned-byte 8))
 678       (let ((len (file-length a)))
 679         (and (eql len (file-length b))
 680              (let ((d (make-array len :element-type '(unsigned-byte 8)))
 681                    (e (make-array len :element-type '(unsigned-byte 8))))
 682                (read-sequence d a)
 683                (read-sequence e b)
 684                (equalp d e)))))))
 685
 686 (defun strip-addresses (str)
 687   (cl-ppcre:regex-replace-all "{[0-9a-fA-F]+}\\>" str "{xxxxxxxx}>"))
 688
 689 (defun slurp-output-method (p)
 690   (xpath:with-namespaces ((nil #.*xsl*))
 691     (let* ((d (handler-bind
 692                   ((warning #'muffle-warning))
 693                 (cxml:parse (pathname p) (stp:make-builder))))
 694            (output (xpath:first-node (xpath:evaluate "//output" d))))
 695       (if output
 696           (let ((method (stp:attribute-value output "method")))
 697             (if method
 698                 (intern (string-upcase method) :keyword)
 699                 :xml))
 700           :xml))))
 701
 702 (defun replace-junk (str)
 703   (cl-ppcre:regex-replace-all
 704    `(:group ,(namestring *tests-directory*))
 705    (map 'string
 706         (lambda (c)
 707           (if (or (eql c #\newline) (<= 32 (char-code c) 126))
 708               c
 709               #\?))
 710         str)
 711    "..."))
 712
 713 (defun run-test (test)
 714   (let ((expected-saxon (test-output-pathname test "saxon"))
 715         #+xuriella::xsltproc
 716         (expected-xsltproc (test-output-pathname test "xsltproc"))
 717         (actual (test-output-pathname test "xuriella"))
 718         (official (test-official-output-pathname test))
 719         (force-normalization
 720          (find (test-id test) '("Namespace-alias__91782") :test #'equal))
 721         (output-method nil))
 722     (handler-bind ((|hey test suite, this is an HTML document|
 723                     (lambda (c)
 724                       (declare (ignore c))
 725                       (setf output-method :html))))
 726       (labels ((uri-resolver (uri)
 727                  (if (search "%5c%5c%5c%5cwebxtest%5c%5cmanagedshadow%5c%5cmanaged_b2%5c%5ctestdata%5c%5cxslt%5c%5celement%5c%5cxslt_element_NSShared.xml"
 728                              uri)
 729                      (cxml::pathname-to-uri
 730                       (merge-pathnames
 731                        "MSFT_Conformance_Tests/Elements/xslt_element_NSShared.xml"
 732                        *tests-directory*))
 733                      uri))
 734                (doit ()
 735                  (with-open-file (s actual
 736                                     :if-exists :rename-and-delete
 737                                     :direction :output
 738                                     :element-type '(unsigned-byte 8))
 739                    (handler-bind ((xslt-error
 740                                    (lambda (c)
 741                                      (declare (ignore c))
 742                                      (when (find-restart 'recover)
 743                                        (invoke-restart 'recover)))))
 744                      (apply-stylesheet (pathname (test-stylesheet-pathname test))
 745                                        (pathname (test-data-pathname test))
 746                                        :output s
 747                                        :uri-resolver #'uri-resolver))))
 748                (pp (label pathname)
 749                  (when pathname
 750                    (format t "  ~A: ~A~%"
 751                            label
 752                            (enough-namestring pathname *tests-directory*))))
 753                (report (ok &optional (fmt "") &rest args)
 754                  (write-string
 755                   (replace-junk
 756                    (strip-addresses
 757                     (format nil "~&~:[FAIL~;PASS~] ~A [~A]~?~%"
 758                             ok
 759                             (test-id test)
 760                             (test-category test)
 761                             fmt
 762                             args))))
 763                  (pp "Stylesheet" (test-stylesheet-pathname test))
 764                  (pp "Data" (test-data-pathname test))
 765                  (pp "Supplemental stylesheet"
 766                      (test-stylesheet-pathname-2 test))
 767                  (pp "Supplemental data" (test-data-pathname-2 test))
 768                  (pp "Expected output (1)" expected-saxon)
 769                  #+xuriella::xsltproc
 770                  (pp "Expected output (2)" expected-xsltproc)
 771                  (pp "Actual output" actual)
 772                  (terpri)
 773                  ok))
 774         (cond
 775           ((equal (test-operation test) "standard")
 776            (handler-case
 777                (progn
 778                  (when (find (test-id test)
 779                              nil ;;'("axes_axes47" "attribset_attribset20")
 780                              :test #'equal)
 781                    (error "skipping problematic test"))
 782                  (doit)
 783                  (let* ((output-method
 784                          (or output-method
 785                              (slurp-output-method
 786                               (test-stylesheet-pathname test))))
 787                         (saxon-matches-p
 788                          (output-equal-p output-method
 789                                          expected-saxon
 790                                          actual))
 791                         #+xuriella::xsltproc
 792                         (xsltproc-matches-p
 793                          (output-equal-p output-method
 794                                          expected-xsltproc
 795                                          actual))
 796                         (official-matches-p
 797                          (output-equal-p output-method
 798                                          official
 799                                          actual
 800                                          :normalize force-normalization)))
 801                    (cond
 802                      ((or saxon-matches-p
 803                           #+xuriella::xsltproc xsltproc-matches-p
 804                           official-matches-p)
 805                       (report t)
 806                       #+xuriella::xsltproc
 807                       (report t ": saxon ~A, xsltproc ~A~:[~; (MISMATCH)~]"
 808                               saxon-matches-p
 809                               xsltproc-matches-p
 810                               (if saxon-matches-p
 811                                   (not xsltproc-matches-p)
 812                                   xsltproc-matches-p)))
 813                      (t
 814                       (report nil ": output doesn't match")))))
 815              ((or error parse-number::invalid-number) (c)
 816                (report nil ": ~A" c))))
 817           (t
 818            (handler-case
 819                (doit)
 820              (xslt-error (c)
 821                (report t ": raised an xslt-error as expected" c))
 822              ((or error parse-number::invalid-number) (c)
 823                (report nil ": condition of incorrect type: ~%~A" c))
 824              (:no-error (result)
 825                (cond
 826                  ((not (and official (probe-file official)))
 827                   (report nil ": expected error not signalled: " result))
 828                  ((output-equal-p
 829                    (or output-method
 830                        (slurp-output-method (test-stylesheet-pathname test)))
 831                    official
 832                    actual
 833                    :normalize force-normalization)
 834                   (report t))
 835                  (t
 836                   (report nil ": saxon error not signalled and official output not a match")))))))))))
 837
 838 (defun run-xpath-tests ()
 839   (run-tests "XPath-Expression/|XSLT-Data-Model/"))
 840
 841
 842 ;;;; from cxml-stp-test
 843
 844 (defun assert-node= (a b)
 845   (unless (node= a b)
 846     (error "assertion failed: ~S and ~S are not NODE=" a b)))
 847
 848 (defun child-count (node)
 849   (stp:count-children-if (constantly t) node))
 850
 851 (defun named-node-= (a b)
 852   (and (equal (stp:namespace-uri a) (stp:namespace-uri b))
 853        ;; (equal (stp:namespace-prefix a) (stp:namespace-prefix b))
 854        (equal (stp:local-name a) (stp:local-name b))))
 855
 856 (defun parent-node-= (e f)
 857   (and (eql (child-count e)
 858             (child-count f))
 859        (every #'node= (stp:list-children e) (stp:list-children f))))
 860
 861 (defmethod node= ((e stp:element) (f stp:element))
 862   (and (named-node-= e f)
 863        (parent-node-= e f)
 864        (null
 865         (set-exclusive-or (stp:list-attributes e) (stp:list-attributes f)
 866                           :test #'node=))
 867        (block nil
 868          (flet ((check-namespaces (a b)
 869                   (let ((result ()))
 870                     (stp:map-extra-namespaces
 871                      (lambda (k v)
 872                        (unless (equal v (stp:find-namespace k b))
 873                          (return nil)))
 874                      a)
 875                     result)))
 876            (check-namespaces e f)
 877            (check-namespaces f e))
 878          t)))
 879
 880 (defmethod node= ((a stp:node) (b stp:node))
 881   nil)
 882
 883 (defmethod node= ((e stp:document) (f stp:document))
 884   (parent-node-= e f))
 885
 886 (defmethod node= ((a stp:attribute) (b stp:attribute))
 887   (and (named-node-= a b)
 888        (equal (stp:value a) (stp:value b))))
 889
 890 (defmethod node= ((a stp:comment) (b stp:comment))
 891   (equal (stp:data a) (stp:data b)))
 892
 893 (defmethod node= ((a stp:text) (b stp:text))
 894   (equal (stp:data a) (stp:data b)))
 895
 896 (defmethod node= ((a stp:processing-instruction)
 897                   (b stp:processing-instruction))
 898   (and (equal (stp:data a) (stp:data b))
 899        (equal (stp:target a) (stp:target b))))
 900
 901 (defmethod node= ((a stp:document-type) (b stp:document-type))
 902   (and (equal (stp:root-element-name a) (stp:root-element-name b))
 903        (equal (stp:public-id a) (stp:public-id b))
 904        (equal (stp:system-id a) (stp:system-id b))
 905        (equal (stp:internal-subset a) (stp:internal-subset b))))
 906
 907 (xpath-sys:define-xpath-function/eager
 908     xslt :print
 909     (thing)
 910   (if (xpath:node-set-p thing)
 911       (loop
 912          initially (format t ";;; node set:~%")
 913          for i from 0
 914          for node in (xpath:all-nodes thing)
 915          do
 916            (format t ";;;   ~D: ~A~%" i (type-of node)))
 917       (format t ";;; ~A~%" thing))
 918   thing)