test.lisp

   1 ;;; -*- show-trailing-whitespace: t; indent-tabs-mode: nil -*-
   2
   3 ;;; Copyright (c) 2007,2008 David Lichteblau, Ivan Shvedunov.
   4 ;;; All rights reserved.
   5
   6 ;;; Redistribution and use in source and binary forms, with or without
   7 ;;; modification, are permitted provided that the following conditions
   8 ;;; are met:
   9 ;;;
  10 ;;;   * Redistributions of source code must retain the above copyright
  11 ;;;     notice, this list of conditions and the following disclaimer.
  12 ;;;
  13 ;;;   * Redistributions in binary form must reproduce the above
  14 ;;;     copyright notice, this list of conditions and the following
  15 ;;;     disclaimer in the documentation and/or other materials
  16 ;;;     provided with the distribution.
  17 ;;;
  18 ;;; THIS SOFTWARE IS PROVIDED BY THE AUTHOR 'AS IS' AND ANY EXPRESSED
  19 ;;; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  20 ;;; WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  21 ;;; ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY
  22 ;;; DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  23 ;;; DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE
  24 ;;; GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  25 ;;; INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  26 ;;; WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
  27 ;;; NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  28 ;;; SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29
  30 (in-package :xuriella)
  31
  32 (defparameter *tests-directory*
  33   "/home/david/src/XSLT-testsuite-04/testsuite/TESTS/")
  34
  35 (defclass test-case ()
  36   ((id :initarg :id :accessor test-id)
  37    (category :initarg :category :accessor test-category)
  38    (operation :initarg :operation :accessor test-operation)
  39    (data-pathname :initarg :data-pathname :accessor test-data-pathname)
  40    (stylesheet-pathname :initarg :stylesheet-pathname
  41                         :accessor test-stylesheet-pathname)
  42    (data-pathname-2 :initarg :data-pathname-2 :accessor test-data-pathname-2)
  43    (stylesheet-pathname-2 :initarg :stylesheet-pathname-2
  44                           :accessor test-stylesheet-pathname-2)
  45    (output-pathname :initarg :output-pathname
  46                     :accessor test-official-output-pathname)
  47    (output-compare :initarg :output-compare
  48                    :accessor test-output-compare)))
  49
  50 (defmethod print-object ((object test-case) stream)
  51   (print-unreadable-object (object stream :identity nil :type t)
  52     (format stream "~A ~A/~A"
  53             (test-operation object)
  54             (test-category object)
  55             (test-id object))))
  56
  57
  58 ;;;; SIMPLIFY-TESTS
  59
  60 ;;; Translate catalog.xml into an actually usable katalog.xml
  61 ;;; by running the test cases through xsltproc to see what it thinks
  62 ;;; about them.
  63
  64 (defun simplify-tests (&optional (d *tests-directory*))
  65   (with-open-file (stream (merge-pathnames "katalog.xml" d)
  66                           :direction :output
  67                           :if-exists :supersede
  68                           :element-type '(unsigned-byte 8))
  69     (cxml:with-xml-output (cxml:make-octet-stream-sink stream)
  70       (cxml:with-element "simplified-test-suite"
  71         (klacks:with-open-source
  72             (source (klacks:make-tapping-source
  73                      (cxml:make-source (merge-pathnames "catalog.xml" d))))
  74           (let ((*default-pathname-defaults* (merge-pathnames d)))
  75             (map-original-tests #'simplify-test source)))))))
  76
  77 (defun map-original-tests (run-test source &key (test (constantly t)))
  78   (let ((total 0)
  79         (pass 0)
  80         major-path)
  81     (loop
  82        while (klacks:find-event source :start-element)
  83        for lname = (klacks:current-lname source)
  84        do
  85        (cond
  86          ((equal lname "major-path")
  87           (klacks:skip source :start-element)
  88           (setf major-path
  89                 (namestring
  90                  (merge-pathnames (klacks:consume-characters source)))))
  91          ((equal lname "test-case")
  92           (let* ((<test-case>
  93                   (stp:document-element
  94                    (klacks:serialize-element source (stp:make-builder))))
  95                  (test-case (parse-original-test major-path <test-case>)))
  96             (when (funcall test test-case)
  97               (incf total)
  98               (when (funcall run-test test-case)
  99                 (incf pass)))))
 100          (t
 101           (klacks:skip source :start-element))))
 102     (format t "~&Passed ~D/~D tests.~%" pass total)))
 103
 104 (defun parse-original-test (major-path <test-case>)
 105   (let* ((file-path
 106           (stp:string-value
 107            (stp:find-recursively-if (stp:of-name "file-path") <test-case>)))
 108          (base (concatenate 'string major-path "/" file-path))
 109          (out-base (concatenate 'string major-path "/REF_OUT/" file-path))
 110          (scenario
 111           (stp:find-recursively-if (stp:of-name "scenario") <test-case>))
 112          data
 113          stylesheet
 114          supplemental-stylesheet
 115          supplemental-data
 116          output
 117          compare)
 118     (dolist (<input> (stp:filter-recursively (stp:of-name "input-file")
 119                                              <test-case>))
 120       (let ((role (stp:attribute-value <input> "role"))
 121             (path (concatenate 'string base "/" (stp:string-value <input>))))
 122         (cond
 123           ((equal role "principal-data")
 124            (setf data path))
 125           ((equal role "principal-stylesheet")
 126            (setf stylesheet path))
 127           ((equal role "supplemental-stylesheet")
 128            (setf supplemental-stylesheet path))
 129           ((equal role "supplemental-data")
 130            (setf supplemental-data path))
 131           (t
 132            (error "unrecognized role: ~A" role)))))
 133     (dolist (<output> (stp:filter-recursively (stp:of-name "output-file")
 134                                             <test-case>))
 135       (let ((role (stp:attribute-value <output> "role"))
 136             (path (concatenate 'string out-base
 137                                "/"
 138                                (stp:string-value <output>))))
 139         (cond
 140           ((equal role "principal")
 141            (setf output path)
 142            (setf compare (stp:attribute-value <output> "compare")))
 143           (t
 144            (error "unrecognized role: ~A" role)))))
 145     (make-instance 'test-case
 146                    :id (stp:attribute-value <test-case> "id")
 147                    :category (stp:attribute-value <test-case> "category")
 148                    :operation (stp:attribute-value scenario "operation")
 149                    :data-pathname data
 150                    :stylesheet-pathname stylesheet
 151                    :stylesheet-pathname-2 supplemental-stylesheet
 152                    :data-pathname-2 supplemental-data
 153                    :output-pathname output
 154                    :output-compare compare)))
 155
 156 (defun write-simplified-test (test-case operation)
 157   (cxml:with-element "test-case"
 158     (cxml:attribute "id" (test-id test-case))
 159     (cxml:attribute "category" (test-category test-case))
 160     (flet ((p (l p)
 161              (cxml:attribute l (and p (namestring p)))))
 162       (p "data" (test-data-pathname test-case))
 163       (p "stylesheet" (noindent-stylesheet-pathname test-case))
 164       (p "data-2" (test-data-pathname-2 test-case))
 165       (p "stylesheet-2" (test-stylesheet-pathname-2 test-case))
 166       (p "output" (test-official-output-pathname test-case))
 167       (p "compare" (test-output-compare test-case)))
 168     (cxml:attribute "operation" operation)))
 169
 170 (defun test-output-pathname (test type)
 171   (make-pathname :name (test-id test)
 172                  :type type
 173                  :defaults (test-data-pathname test)))
 174
 175 (defun sanitize-stylesheet (in out)
 176   (if (probe-file in)
 177       (handler-case
 178           (let ((d (cxml:parse (pathname in) (stp:make-builder))))
 179             (xpath:with-namespaces ((nil #.*xsl*))
 180               (xpath:do-node-set (output (xpath:evaluate "//output" d))
 181                 (let ((a (stp:find-attribute-named output "indent")))
 182                   (when a
 183                     (stp:detach a)))))
 184             (with-open-file (s out
 185                                :direction :output
 186                                :if-exists :rename-and-delete
 187                                :element-type '(unsigned-byte 8))
 188               (stp:serialize d (cxml:make-octet-stream-sink s))))
 189         (error (c)
 190           (warn "ignoring bogus stylesheet ~A: ~A" in c)
 191           (copy-file in out)))
 192       (warn "oops, ignoring missing stylesheet: ~A" in)))
 193
 194 (defun noindent-stylesheet-pathname (test-case)
 195   (make-pathname :type "noindent-xsl"
 196                  :defaults (test-stylesheet-pathname test-case)))
 197
 198 (defun simplify-test (test-case)
 199   (flet ((report (status &optional (fmt "") &rest args)
 200            (format t "~&~A ~A [~A]~?~%"
 201                    status
 202                    (test-id test-case)
 203                    (test-category test-case)
 204                    fmt
 205                    args)))
 206     (let* ((data (test-data-pathname test-case))
 207            (stylesheet (test-stylesheet-pathname test-case))
 208            (noindent-stylesheet (noindent-stylesheet-pathname test-case))
 209            #+xuriella::xsltproc
 210            (out (test-output-pathname test-case "xsltproc"))
 211            (saxon-out (test-output-pathname test-case "saxon")))
 212       (sanitize-stylesheet stylesheet noindent-stylesheet)
 213       (if (equal (test-operation test-case) "standard")
 214           (handler-case
 215               (progn
 216                 #+xuriella::xsltproc (xsltproc noindent-stylesheet data out)
 217                 (saxon noindent-stylesheet data saxon-out)
 218                 (report "PASS")
 219                 (write-simplified-test test-case "standard")
 220                 t)
 221             (error (c)
 222               (report "FAIL" ": ~A" c)
 223               (write-simplified-test test-case "execution-error")
 224               nil))
 225           (handler-case
 226               (progn
 227                 #+xuriella::xsltproc
 228                 (xsltproc noindent-stylesheet data "/dev/null")
 229                 (saxon noindent-stylesheet data "/dev/null")
 230                 (report "FAIL" ": expected error not signalled")
 231                 ;; let's ignore unexpected successes for now
 232                 nil)
 233             (error (c)
 234               (report "PASS" ": expected error ~A" c)
 235               (write-simplified-test test-case "execution-error")
 236               t))))))
 237
 238 (defun xsltproc (stylesheet input output)
 239   (flet ((full-namestring (x)
 240            (namestring (merge-pathnames x))))
 241     (let* ((asdf::*verbose-out* (make-string-output-stream))
 242            (code (asdf:run-shell-command
 243                   "cd ~S && xsltproc ~S ~S >~S"
 244                   (full-namestring "")
 245                   (full-namestring stylesheet)
 246                   (full-namestring input)
 247                   (full-namestring output))))
 248       (unless (zerop code)
 249         (error "running xsltproc failed with code ~A [~%~A~%]"
 250                code
 251                (get-output-stream-string asdf::*verbose-out*))))))
 252
 253 (defun saxon (stylesheet input output)
 254   (flet ((full-namestring (x)
 255            (namestring (merge-pathnames x))))
 256     (let* ((asdf::*verbose-out* (make-string-output-stream))
 257            (code (asdf:run-shell-command
 258                   "cd ~S && java -jar /usr/share/java/saxon.jar ~S ~S >~S"
 259                   (full-namestring "")
 260                   (full-namestring input)
 261                   (full-namestring stylesheet)
 262                   (full-namestring output))))
 263       (unless (zerop code)
 264         (error "running saxon failed with code ~A [~%~A~%]"
 265                code
 266                (get-output-stream-string asdf::*verbose-out*))))))
 267
 268
 269 ;;;; RUN-TESTS and DRIBBLE-TESTS
 270
 271 ;;; Process katalog.xml
 272
 273 (defun dribble-tests
 274     (&key filter (directory *tests-directory*) (file "TEST"))
 275   (let ((*package* (find-package 'cl-user))
 276         (*print-circle* nil))
 277     (with-open-file (dribble
 278                      (merge-pathnames file
 279                                       (slot-value (asdf:find-system :xuriella)
 280                                                   'asdf::relative-pathname))
 281                      :direction :output
 282                      :if-exists :supersede
 283                      :external-format :utf-8)
 284       (let* ((dribble (make-broadcast-stream dribble *standard-output*))
 285              (*standard-output* dribble)
 286              (*trace-output* dribble)
 287              (*error-output* dribble)
 288              (*terminal-io* (make-two-way-stream *standard-input* dribble)))
 289         (handler-bind ((warning
 290                         (lambda (c)
 291                           (warn "~A" (replace-junk (princ-to-string c)))
 292                           (muffle-warning c))))
 293           (run-tests :filter filter
 294                      :directory directory))))))
 295
 296 (defparameter *bad-tests*
 297   '(;; Inconsistent tests:
 298     ;;
 299     ;; Some tests wants us to recover from this error, yet this one doesn't:
 300     "copy_copy61"
 301     "copy_copy62"
 302
 303     ;; Should we fix this?
 304     ;;
 305     ;; We signal a run-time error when and if it's actually used.  The test
 306     ;; wants a compilation-time error...
 307     "AttributeSets_RefToUndefinedAttributeSet"
 308
 309     ;; We would pass this:
 310     ;;
 311     ;; We perform recovery, but saxon doesn't.  Recovery results in non-XML
 312     ;; output, which we can't parse for comparison against the official
 313     ;; test case.
 314     "output_output75"
 315     ;;
 316     ;; we'd pass these tests, but the test authors forgot to declare the
 317     ;; entity they're writing, so we can't parse it for comparison.
 318     "output_output06"
 319     "output_output10"
 320     "output_output61"
 321     ;;
 322     ;; another similar test where the output is unparsable, except that
 323     ;; here an entity declaration wouldn't have helped either:
 324     "Copying_ResultTreeFragmentWithEscapedText"
 325
 326     ;; Broken test:
 327     ;;
 328     ;; Input document isn't ns-wf.
 329     "Attributes__78387"
 330     ;;
 331     ;; Someone commented out most of this test...
 332     "BVTs_bvt045"
 333
 334     ;; FIXME: should re-enable these at some point:
 335     ;;
 336     ;; the following tests take a lot of time due to the problems of current matching algorithm:
 337     "impincl_impincl16"
 338     ;; probably the same problem (but I haven't checked):
 339     "Import__91164"
 340
 341     ;; stack exhaustion -- matching problem i think
 342     "Keys_PerfRepro3"
 343
 344     ;; test stylesheet doesn't exist?!
 345     "ConflictResolution__77833"))
 346
 347 ;; Tests where the output isn't a match because of extraneous whitespace.
 348 ;; For these tests, we force space normalization before comparing.
 349 ;;
 350 ;; Possible reasons for this problem are:
 351 ;;   a. The output method is declared in an imported stylesheet.
 352 ;;      SANITIZE-STYLESHEET is supposed to get rid of indent="yes", but it
 353 ;;      misses imported stylesheets.
 354 ;;   b. Saxon output isn't a match, but the official output is.
 355 ;;      But the official output is unaffected by SANITIZE-STYLESHEET.
 356 ;;
 357 (defparameter *whitespace-issues*
 358   (cl-ppcre:create-scanner
 359    "(?smx)
 360     ^(BVTs_bvt044$
 361        |Namespace-alias__91782$
 362        |AttributeSets__91038$
 363        |BVTs_bvt041$
 364        |BVTs_bvt042$
 365        |BVTs_bvt054$
 366        |BVTs_bvt058$
 367        |Import__
 368        )"))
 369
 370 (defparameter *known-failures*
 371   '(
 372     ;; uses EBCDIC-CP-IT (whatever that is), but Babel's only got EBCDIC-US.
 373     ;; Doesn't actually test any differences between the two, so it's
 374     ;; probably just there to annoy us.
 375     "output_output22"
 376
 377     ;; uses KOI, which Babel doesn't support
 378     "BVTs_bvt019"
 379
 380     ;; FIXME?
 381     ;;
 382     ;; This is an HTML output method issue.  The spec says the HTML
 383     ;; output method should output elements with a null namespace URI as
 384     ;; HTML, and if their name isn't recognized, as an inline element.
 385     ;; <xml> here is such an element.  It has an attributes with a
 386     ;; namespace though, and the spec doesn't say what we should do with that
 387     ;; attribute.  We currently output it using Closure HTML, and
 388     ;; lose its namespace.  This test wants the attribute and its
 389     ;; namespace to survive.
 390     "BVTs_bvt054"))
 391
 392 (defun run-tests (&key filter (directory *tests-directory*))
 393   (when (typep filter '(or string cons))
 394     (setf filter (cl-ppcre:create-scanner filter)))
 395   (klacks:with-open-source
 396       (source (klacks:make-tapping-source
 397                (cxml:make-source (merge-pathnames "katalog.xml" directory))))
 398     (let ((*default-pathname-defaults* (merge-pathnames directory)))
 399       (map-tests #'run-test
 400                  source
 401                  :test (lambda (test)
 402                          (and (or (null filter)
 403                                   (cl-ppcre:all-matches
 404                                    filter
 405                                    (format nil "~A/~A"
 406                                            (test-category test)
 407                                            (test-id test))))
 408                               (not (find (test-id test)
 409                                          *bad-tests*
 410                                          :test #'equal))))))))
 411
 412 (defun run-named-test (name &optional (d *tests-directory*))
 413   (let ((*break-on-signals*
 414          '(and error (not babel-encodings:character-encoding-error))))
 415     (run-tests :filter (format nil "/~A$" name) :directory d)))
 416
 417 (defun copy-file (p q)
 418   (with-open-file (in p :element-type '(unsigned-byte 8))
 419     (with-open-file (out q
 420                          :element-type '(unsigned-byte 8)
 421                          :direction :output
 422                          :if-exists :rename-and-delete)
 423       (let ((buf (make-array 8192 :element-type '(unsigned-byte 8))))
 424         (loop for pos = (read-sequence buf in)
 425            until (zerop pos)
 426            do (write-sequence buf out :end pos))))))
 427
 428 (defun find-named-test (name &optional (d *tests-directory*))
 429   (klacks:with-open-source
 430       (source (klacks:make-tapping-source
 431                (cxml:make-source (merge-pathnames "katalog.xml" d))))
 432     (block nil
 433       (map-tests (lambda (test)
 434                    (return test))
 435                  source
 436                  :test (lambda (test) (equal (test-id test) name))))))
 437
 438 (defun copy-test-files (name &optional (d *tests-directory*))
 439   (let* ((test (find-named-test name d))
 440          (*default-pathname-defaults* (merge-pathnames d))
 441          (*break-on-signals*
 442           '(and error (not babel-encodings:character-encoding-error)))
 443          (target-dir (merge-pathnames "copied-test/"
 444                                       (asdf:component-pathname
 445                                        (asdf:find-system :xuriella))))
 446          (xsl (merge-pathnames "test.xsl" target-dir))
 447          (xml (merge-pathnames "test.xml" target-dir))
 448          (txt (merge-pathnames "official-output.txt" target-dir))
 449          (expected (merge-pathnames "expected.xml" target-dir))
 450          (actual (merge-pathnames "actual.xml" target-dir)))
 451     (ensure-directories-exist target-dir)
 452     (copy-file (test-stylesheet-pathname test) xsl)
 453     (copy-file (test-data-pathname test) xml)
 454     (when (test-official-output-pathname test)
 455       (copy-file (test-official-output-pathname test) txt))
 456     (format t "Test stylesheet copied to:~%  ~A~%~%" xsl)
 457     (format t "Test data copied to:~%  ~A~%~%" xml)
 458     (when (test-official-output-pathname test)
 459       (format t "Official output file:~%  ~A~%~%" txt))
 460     (format t "Run xsltproc like this:~%  cd ~A~%  xsltproc ~A ~A >~A~%~%"
 461             (namestring target-dir)
 462             (enough-namestring xsl target-dir)
 463             (enough-namestring xml target-dir)
 464             (enough-namestring expected target-dir))
 465     (format t "Run saxon like this:~%  cd ~A~%  java -jar /usr/share/java/saxon.jar ~A ~A >~A~%~%"
 466             (namestring target-dir)
 467             (enough-namestring xml target-dir)
 468             (enough-namestring xsl target-dir)
 469             (enough-namestring expected target-dir))
 470     (format t "Run MSXSL like this:~%  cd ~A~%  wine msxsl.exe ~A ~A >~A~%~%"
 471             (namestring target-dir)
 472             (enough-namestring xml target-dir)
 473             (enough-namestring xsl target-dir)
 474             (enough-namestring expected target-dir))
 475     (format t "Run xuriella like this:~%")
 476     `(apply-stylesheet ,xsl ,xml :output ,actual)))
 477
 478 (defun map-tests (run-test source &key (test (constantly t)))
 479   (let ((total 0)
 480         (pass 0)
 481         (known 0))
 482     (loop
 483        while (klacks:find-event source :start-element)
 484        for lname = (klacks:current-lname source)
 485        do
 486        (cond
 487          ((equal lname "test-case")
 488           (let* ((<test-case>
 489                   (stp:document-element
 490                    (klacks:serialize-element source (stp:make-builder))))
 491                  (test-case (parse-test <test-case>)))
 492             (when (funcall test test-case)
 493               (incf total)
 494               (ecase (funcall run-test test-case)
 495                 ((nil))
 496                 ((t)
 497                  (incf pass))
 498                 (:known-failure
 499                  (incf known))))))
 500          (t
 501           (klacks:skip source :start-element))))
 502     (format t "~&Passed ~D/~D tests (~D expected failures, ~D unexpected failures).~%"
 503             pass total known (- total pass known))))
 504
 505 (defun parse-test (<test-case>)
 506   (stp:with-attributes (id category operation
 507                            data stylesheet data-2 stylesheet-2
 508                            output compare)
 509       <test-case>
 510     (make-instance 'test-case
 511                    :id id
 512                    :category category
 513                    :operation operation
 514                    :data-pathname data
 515                    :stylesheet-pathname stylesheet
 516                    :data-pathname-2 data-2
 517                    :stylesheet-pathname-2 stylesheet-2
 518                    :output-pathname output
 519                    :output-compare compare)))
 520
 521 ;; read from file P, skipping the XMLDecl or TextDecl and Doctype at the
 522 ;; beginning, if any.
 523 (defun slurp-for-comparison (p)
 524   (with-open-file (s p :element-type '(unsigned-byte 8))
 525     (unless (and (eql (read-byte s nil) #xef)
 526                  (eql (read-byte s nil) #xbb)
 527                  (eql (read-byte s nil) #xbf))
 528       (file-position s 0))
 529     (if (plusp (file-length s))
 530         (slurp-for-comparison-1 p s t)
 531         "<wrapper/>")))
 532
 533 (defun slurp-for-comparison-1 (p s junk-info)
 534   (let ((pos (file-position s))         ;for UTF-8 "BOM"
 535         (xstream (runes:make-xstream s :speed 1))
 536         (prev-pos 0))
 537     (setf (runes:xstream-name xstream)
 538           (cxml::make-stream-name
 539            :entity-name "main document"
 540            :entity-kind :main
 541            :uri (cxml::pathname-to-uri (merge-pathnames p))))
 542     (let ((source
 543            (flet ((er (pub sys)
 544                     pub sys
 545                     (flexi-streams:make-in-memory-input-stream
 546                      #())))
 547              (cxml:make-source xstream
 548                                :pathname p
 549                                :entity-resolver #'er))))
 550       (unless (eq junk-info :nada)
 551         (loop
 552            for key = (progn
 553                        (setf prev-pos (runes:xstream-position xstream))
 554                        (klacks:peek-next source))
 555            until (eq key :start-document))
 556         (cxml::with-source (source cxml::context)
 557           (when (eq (cxml::zstream-token-category
 558                      (cxml::main-zstream cxml::context))
 559                     :NMTOKEN)
 560             ;; oops, doesn't look like XML at all
 561             (file-position s pos)
 562             (return-from slurp-for-comparison-1
 563               (slurp-for-comparison-1 p s :nada)))))
 564       (etypecase junk-info
 565         (integer
 566          (dotimes (x junk-info)
 567            (setf prev-pos (runes:xstream-position xstream))
 568            (klacks:peek-next source)))
 569         ((eql t)
 570          (let ((nskip 0))
 571            (handler-case
 572                (loop
 573                   (case (klacks:peek-next source)
 574                     (:start-element (return))
 575                     (:characters
 576                      (if (whitespacep (klacks:current-characters source))
 577                          (incf nskip)
 578                          (return)))
 579                     (t
 580                      (incf nskip))))
 581              ((or file-error cxml:xml-parse-error) ()
 582                (when (zerop nskip)
 583                  (setf nskip nil))))
 584            ;; retry
 585            (with-open-file (u p :element-type '(unsigned-byte 8))
 586              (file-position u pos)
 587              (return-from slurp-for-comparison-1
 588                (slurp-for-comparison-1 p u nskip)))))
 589         ((member nil :nada)))
 590       (with-output-to-string (r)
 591         (let* ((seen-char
 592                 (cxml::with-source (source cxml::context)
 593                   (ecase (cxml::zstream-token-category
 594                           (cxml::main-zstream cxml::context))
 595                     (:seen-< #\<)
 596                     (:? #\?)
 597                     ((nil :s)
 598                      (setf prev-pos (runes:xstream-position xstream))
 599                      nil))))
 600                (off-by-one-p (or seen-char (eq junk-info :nada)))
 601                (new-pos (- prev-pos (if off-by-one-p 1 0))))
 602           ;; copy doctype over
 603           (with-open-file (u p :element-type '(unsigned-byte 8))
 604             (file-position u pos)
 605             (let ((y (runes:make-xstream u :speed 1)))
 606               (loop
 607                  while (< (runes:xstream-position y) new-pos)
 608                  do (write-char (runes:read-rune y) r))))
 609           (write-line "<wrapper>" r)
 610           (when seen-char
 611             (write-char seen-char r)))
 612         (loop
 613            for char = (runes:read-rune xstream)
 614            until (eq char :eof)
 615            do (write-char char r))
 616         (write-line "</wrapper>" r)))))
 617
 618 (defun parse-for-comparison (p)
 619   (let* ((d (flet ((er (pub sys)
 620                     pub sys
 621                     (flexi-streams:make-in-memory-input-stream
 622                      #())))
 623               (cxml:parse (slurp-for-comparison p)
 624                           (make-text-normalizer (stp:make-builder))
 625                           :entity-resolver #'er)))
 626          (de (stp:document-element d)))
 627     (let ((first (stp:first-child de)))
 628       (when (typep first 'stp:text)
 629         (cond
 630           ((whitespacep (stp:data first))
 631            (stp:delete-child first de))
 632           (t
 633            (setf (stp:data first)
 634                  (cl-ppcre:regex-replace #.(format nil "^[~A]+" *whitespace*)
 635                                          (stp:data first)
 636                                          ""))))))
 637     (let ((last (stp:last-child de)))
 638       (when (typep last 'stp:text)
 639         (cond
 640           ((whitespacep (stp:data last))
 641            (stp:delete-child last de))
 642           (t
 643            (setf (stp:data last)
 644                  (cl-ppcre:regex-replace #.(format nil "[~A]+$" *whitespace*)
 645                                          (stp:data last)
 646                                          ""))))))
 647     d))
 648
 649 (defun output-equal-p (compare p q &key normalize)
 650   (handler-case
 651       (ecase compare
 652         (:xml (xml-output-equal-p p q normalize))
 653         (:html (html-output-equal-p p q))
 654         (:text (text-output-equal-p p q)))
 655     ((or error parse-number::invalid-number) (c)
 656       (warn "comparison failed: ~A" c)
 657       nil)))
 658
 659 ;; Workaround for namespace_namespace23 and other tests:
 660 ;;  - For these tests, saxon and msxsl output a declaration for the XSL
 661 ;;    namespace without using that declaration.
 662 ;;  - I think saxon and msxsl are both wrong.
 663 ;;  - The official test output agrees with my assessment.
 664 ;;    (So does libxslt, but that's not to be trusted. :-))
 665 ;;  - Here's the catch: The official test output is broken in its whitespace
 666 ;;    handling.
 667 ;; So let's normalize spaces in test output that looks like an XSLT
 668 ;; stylesheet, allowing us to pass these tests using the official test output.
 669 (defun maybe-normalize-test-spaces (wrapper force)
 670   (let ((i 0))
 671     (loop while (< i (length (cxml-stp-impl::%children wrapper))) do
 672          (let ((wrapper-child (stp:nth-child i wrapper)))
 673            (cond
 674              ((not (typep wrapper-child 'stp:element))
 675               (if force
 676                   (stp:delete-nth-child i wrapper)
 677                   (incf i)))
 678              ((or (equal (stp:namespace-uri wrapper-child) *xsl*)
 679                   force)
 680               (strip-stylesheet wrapper-child)
 681               (labels ((recurse (e &optional preserve)
 682                          (stp:do-children (child e)
 683                            (typecase child
 684                              (stp:text
 685                               (setf (stp:data child)
 686                                     (normalize-whitespace (stp:data child))))
 687                              (stp:element
 688                                  (stp:with-attributes ((space "space" *xml*))
 689                                      child
 690                                    (let ((new-preserve
 691                                           (cond
 692                                             ((namep child "text") t)
 693                                             ((not space) preserve)
 694                                             ((equal space "preserve") t)
 695                                             (t nil))))
 696                                      (recurse child new-preserve))))))))
 697                 (recurse wrapper-child))
 698               (incf i))
 699              (t
 700               (incf i)))))))
 701
 702 (defun xml-output-equal-p (p q normalize)
 703   (let ((r (parse-for-comparison p))
 704         (s (parse-for-comparison q)))
 705     (maybe-normalize-test-spaces (stp:document-element r) normalize)
 706     (maybe-normalize-test-spaces (stp:document-element s) normalize)
 707     (and (let ((u (stp:document-type r))
 708                (v (stp:document-type s)))
 709            (if u
 710                (and v (node= u v))
 711                (null v)))
 712          (node= (stp:document-element r) (stp:document-element s)))))
 713
 714 ;; FIXME: don't do this in <pre> etc.
 715 (defun normalize-html-whitespace (node)
 716   (when (typep node 'stp:parent-node)
 717     ;; ignore newlines after start tags completely
 718     (let ((first (stp:first-child node)))
 719       (when (and (typep first 'stp:text)
 720                  (alexandria:starts-with #\newline (stp:data first)))
 721         (setf (stp:data first) (subseq (stp:data first) 1))))
 722     ;; ignore newlines before end tags completely
 723     (let ((last (stp:last-child node)))
 724       (when (and (typep last 'stp:text)
 725                  (alexandria:ends-with #\newline (stp:data last)))
 726         (setf (stp:data last)
 727               (subseq (stp:data last) 0 (length (stp:data last))))))
 728     ;; normalize sequences of whitespace
 729     (stp:do-children (child node)
 730       (if (typep child 'stp:text)
 731           (setf (stp:data child)
 732                 (let ((str (normalize-whitespace (stp:data child))))
 733                   (when
 734                       ;; FIXME!  Here we remove whitespace entirely.
 735                       ;; Totally incorrect, but I don't see how we could
 736                       ;; watch Saxon's output otherwise.
 737                       (equal str " ")
 738                     (setf str ""))
 739                   str))
 740           (normalize-html-whitespace child)))
 741     ;; just to be sure, join adjacent nodes
 742     (cxml-stp-impl::normalize-text-nodes! node)))
 743
 744 ;; FIXME: this check is too lenient, because chtml is an error-correcting
 745 ;; parser.
 746 (defun html-output-equal-p (p q)
 747   (let ((r (chtml:parse (pathname p) (stp:make-builder)))
 748         (s (chtml:parse (pathname q) (stp:make-builder))))
 749     (normalize-html-whitespace r)
 750     (normalize-html-whitespace s)
 751     (flet ((fix-case (node)
 752              (xpath:with-namespaces (("xhtml" "http://www.w3.org/1999/xhtml"))
 753                (xpath:do-node-set
 754                    (content (xpath:evaluate "//xhtml:meta/@content" node))
 755                  (setf (stp:value content)
 756                        (string-downcase (stp:value content)))))))
 757       (fix-case r)
 758       (fix-case s))
 759     (node= (stp:document-element r) (stp:document-element s))))
 760
 761 (defun text-output-equal-p (p q)
 762   (with-open-file (a p :element-type '(unsigned-byte 8))
 763     (with-open-file (b q :element-type '(unsigned-byte 8))
 764       (let ((len (file-length a)))
 765         (and (eql len (file-length b))
 766              (let ((d (make-array len :element-type '(unsigned-byte 8)))
 767                    (e (make-array len :element-type '(unsigned-byte 8))))
 768                (read-sequence d a)
 769                (read-sequence e b)
 770                (equalp d e)))))))
 771
 772 (defun strip-addresses (str)
 773   (cl-ppcre:regex-replace-all "{[0-9a-fA-F]+}\\>" str "{xxxxxxxx}>"))
 774
 775 (defun slurp-output-method (p)
 776   (xpath:with-namespaces ((nil #.*xsl*))
 777     (let* ((d (handler-bind
 778                   ((warning #'muffle-warning))
 779                 (cxml:parse (pathname p) (stp:make-builder))))
 780            (output (xpath:first-node (xpath:evaluate "//output" d))))
 781       (if output
 782           (let ((method (stp:attribute-value output "method")))
 783             (if method
 784                 (intern (string-upcase method) :keyword)
 785                 :xml))
 786           :xml))))
 787
 788 (defun replace-junk (str)
 789   (cl-ppcre:regex-replace-all
 790    `(:group ,(namestring *tests-directory*))
 791    (map 'string
 792         (lambda (c)
 793           (if (or (eql c #\newline) (<= 32 (char-code c) 126))
 794               c
 795               #\?))
 796         str)
 797    "..."))
 798
 799 (defun run-test (test)
 800   (let ((expected-saxon (test-output-pathname test "saxon"))
 801         #+xuriella::xsltproc
 802         (expected-xsltproc (test-output-pathname test "xsltproc"))
 803         (actual (test-output-pathname test "xuriella"))
 804         (official (test-official-output-pathname test))
 805         (force-normalization
 806          (cl-ppcre:all-matches *whitespace-issues* (test-id test)))
 807         (output-method nil))
 808     (handler-bind ((|hey test suite, this is an HTML document|
 809                     (lambda (c)
 810                       (declare (ignore c))
 811                       (setf output-method :html))))
 812       (labels ((uri-resolver (uri)
 813                  (if (search "%5c%5c%5c%5cwebxtest%5c%5cmanagedshadow%5c%5cmanaged_b2%5c%5ctestdata%5c%5cxslt%5c%5celement%5c%5cxslt_element_NSShared.xml"
 814                              uri)
 815                      (cxml::pathname-to-uri
 816                       (merge-pathnames
 817                        "MSFT_Conformance_Tests/Elements/xslt_element_NSShared.xml"
 818                        *tests-directory*))
 819                      uri))
 820                (doit ()
 821                  (with-open-file (s actual
 822                                     :if-exists :rename-and-delete
 823                                     :direction :output
 824                                     :element-type '(unsigned-byte 8))
 825                    (handler-bind ((xslt-error
 826                                    (lambda (c)
 827                                      (declare (ignore c))
 828                                      (when (find-restart 'recover)
 829                                        (invoke-restart 'recover)))))
 830                      (apply-stylesheet (pathname (test-stylesheet-pathname test))
 831                                        (let ((p (test-data-pathname test)))
 832                                          (if (search "Elements/Plants.xml" p)
 833                                              (merge-pathnames
 834                                               "MSFT_Conformance_Tests/Elements/plants.xml"
 835                                               *tests-directory*)
 836                                              (pathname p)))
 837                                        :output s
 838                                        :uri-resolver #'uri-resolver))))
 839                (pp (label pathname)
 840                  (when pathname
 841                    (format t "  ~A: ~A~%"
 842                            label
 843                            (enough-namestring pathname *tests-directory*))))
 844                (report (ok &optional (fmt "") &rest args)
 845                  (write-string
 846                   (replace-junk
 847                    (strip-addresses
 848                     (format nil "~&~A ~A [~A]~?~%"
 849                             (cond
 850                               (ok "PASS")
 851                               ((find (test-id test)
 852                                      *known-failures*
 853                                      :test #'equal)
 854                                (setf ok :known-failure)
 855                                "KNOWNFAIL")
 856                               (t
 857                                "FAIL"))
 858                             (test-id test)
 859                             (test-category test)
 860                             fmt
 861                             args))))
 862                  (pp "Stylesheet" (test-stylesheet-pathname test))
 863                  (pp "Data" (test-data-pathname test))
 864                  (pp "Supplemental stylesheet"
 865                      (test-stylesheet-pathname-2 test))
 866                  (pp "Supplemental data" (test-data-pathname-2 test))
 867                  (pp "Expected output (1)" expected-saxon)
 868                  #+xuriella::xsltproc
 869                  (pp "Expected output (2)" expected-xsltproc)
 870                  (pp "Actual output" actual)
 871                  (terpri)
 872                  ok))
 873         (cond
 874           ((equal (test-operation test) "standard")
 875            (handler-case
 876                (progn
 877                  (when (find (test-id test)
 878                              nil ;;'("axes_axes47" "attribset_attribset20")
 879                              :test #'equal)
 880                    (error "skipping problematic test"))
 881                  (doit)
 882                  (let* ((output-method
 883                          (or output-method
 884                              (slurp-output-method
 885                               (test-stylesheet-pathname test))))
 886                         (saxon-matches-p
 887                          (output-equal-p output-method
 888                                          expected-saxon
 889                                          actual
 890                                          :normalize force-normalization))
 891                         #+xuriella::xsltproc
 892                         (xsltproc-matches-p
 893                          (output-equal-p output-method
 894                                          expected-xsltproc
 895                                          actual))
 896                         (official-matches-p
 897                          (output-equal-p output-method
 898                                          official
 899                                          actual
 900                                          :normalize force-normalization)))
 901                    (cond
 902                      ((or saxon-matches-p
 903                           #+xuriella::xsltproc xsltproc-matches-p
 904                           official-matches-p)
 905                       (report t)
 906                       #+xuriella::xsltproc
 907                       (report t ": saxon ~A, xsltproc ~A~:[~; (MISMATCH)~]"
 908                               saxon-matches-p
 909                               xsltproc-matches-p
 910                               (if saxon-matches-p
 911                                   (not xsltproc-matches-p)
 912                                   xsltproc-matches-p)))
 913                      (t
 914                       (report nil ": output doesn't match")))))
 915              ((or error parse-number::invalid-number) (c)
 916                (report nil ": ~A" c))))
 917           (t
 918            (handler-case
 919                (doit)
 920              (xslt-error (c)
 921                (report t ": raised an xslt-error as expected" c))
 922              ((or error parse-number::invalid-number) (c)
 923                (report nil ": condition of incorrect type: ~%~A" c))
 924              (:no-error (result)
 925                (cond
 926                  ((not (and official (probe-file official)))
 927                   (report nil ": expected error not signalled: " result))
 928                  ((output-equal-p
 929                    (or output-method
 930                        (slurp-output-method (test-stylesheet-pathname test)))
 931                    official
 932                    actual
 933                    :normalize force-normalization)
 934                   (report t))
 935                  (t
 936                   (report nil ": saxon error not signalled and official output not a match")))))))))))
 937
 938 (defun run-xpath-tests ()
 939   (run-tests :filter "XPath-Expression/|XSLT-Data-Model/"))
 940
 941
 942 ;;;; from cxml-stp-test
 943
 944 (defun assert-node= (a b)
 945   (unless (node= a b)
 946     (error "assertion failed: ~S and ~S are not NODE=" a b)))
 947
 948 (defun child-count (node)
 949   (stp:count-children-if (constantly t) node))
 950
 951 (defun named-node-= (a b)
 952   (and (equal (stp:namespace-uri a) (stp:namespace-uri b))
 953        ;; (equal (stp:namespace-prefix a) (stp:namespace-prefix b))
 954        (equal (stp:local-name a) (stp:local-name b))))
 955
 956 (defun parent-node-= (e f)
 957   (and (eql (child-count e)
 958             (child-count f))
 959        (every #'node= (stp:list-children e) (stp:list-children f))))
 960
 961 (defmethod node= ((e stp:element) (f stp:element))
 962   (and (named-node-= e f)
 963        (parent-node-= e f)
 964        (null
 965         (set-exclusive-or (stp:list-attributes e) (stp:list-attributes f)
 966                           :test #'node=))
 967        (block nil
 968          (flet ((check-namespaces (a b)
 969                   (let ((result ()))
 970                     (stp:map-extra-namespaces
 971                      (lambda (k v)
 972                        (unless (equal v (stp:find-namespace k b))
 973                          (return nil)))
 974                      a)
 975                     result)))
 976            (check-namespaces e f)
 977            (check-namespaces f e))
 978          t)))
 979
 980 (defmethod node= ((a stp:node) (b stp:node))
 981   nil)
 982
 983 (defmethod node= ((e stp:document) (f stp:document))
 984   (parent-node-= e f))
 985
 986 (defmethod node= ((a stp:attribute) (b stp:attribute))
 987   (and (named-node-= a b)
 988        (equal (stp:value a) (stp:value b))))
 989
 990 (defmethod node= ((a stp:comment) (b stp:comment))
 991   (equal (stp:data a) (stp:data b)))
 992
 993 (defmethod node= ((a stp:text) (b stp:text))
 994   (equal (stp:data a) (stp:data b)))
 995
 996 (defmethod node= ((a stp:processing-instruction)
 997                   (b stp:processing-instruction))
 998   (and (equal (stp:data a) (stp:data b))
 999        (equal (stp:target a) (stp:target b))))
1000
1001 (defmethod node= ((a stp:document-type) (b stp:document-type))
1002   (and (equal (stp:root-element-name a) (stp:root-element-name b))
1003        (equal (stp:public-id a) (stp:public-id b))
1004        (equal (stp:system-id a) (stp:system-id b))
1005        (equal (stp:internal-subset a) (stp:internal-subset b))))
1006
1007 (xpath-sys:define-xpath-function/eager
1008     xslt :print
1009     (thing)
1010   (if (xpath:node-set-p thing)
1011       (loop
1012          initially (format t ";;; node set:~%")
1013          for i from 0
1014          for node in (xpath:all-nodes thing)
1015          do
1016            (format t ";;;   ~D: ~A~%" i (type-of node)))
1017       (format t ";;; ~A~%" thing))
1018   thing)