test.lisp

   1 ;;; -*- show-trailing-whitespace: t; indent-tabs-mode: nil -*-
   2
   3 ;;; Copyright (c) 2007,2008 David Lichteblau, Ivan Shvedunov.
   4 ;;; All rights reserved.
   5
   6 ;;; Redistribution and use in source and binary forms, with or without
   7 ;;; modification, are permitted provided that the following conditions
   8 ;;; are met:
   9 ;;;
  10 ;;;   * Redistributions of source code must retain the above copyright
  11 ;;;     notice, this list of conditions and the following disclaimer.
  12 ;;;
  13 ;;;   * Redistributions in binary form must reproduce the above
  14 ;;;     copyright notice, this list of conditions and the following
  15 ;;;     disclaimer in the documentation and/or other materials
  16 ;;;     provided with the distribution.
  17 ;;;
  18 ;;; THIS SOFTWARE IS PROVIDED BY THE AUTHOR 'AS IS' AND ANY EXPRESSED
  19 ;;; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  20 ;;; WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  21 ;;; ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY
  22 ;;; DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  23 ;;; DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE
  24 ;;; GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  25 ;;; INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  26 ;;; WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
  27 ;;; NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  28 ;;; SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29
  30 (in-package :xuriella)
  31
  32 (defparameter *tests-directory*
  33   "/home/david/src/XSLT-testsuite-04/testsuite/TESTS/")
  34
  35 (defclass test-case ()
  36   ((id :initarg :id :accessor test-id)
  37    (category :initarg :category :accessor test-category)
  38    (operation :initarg :operation :accessor test-operation)
  39    (data-pathname :initarg :data-pathname :accessor test-data-pathname)
  40    (stylesheet-pathname :initarg :stylesheet-pathname
  41                         :accessor test-stylesheet-pathname)
  42    (data-pathname-2 :initarg :data-pathname-2 :accessor test-data-pathname-2)
  43    (stylesheet-pathname-2 :initarg :stylesheet-pathname-2
  44                           :accessor test-stylesheet-pathname-2)
  45    (output-pathname :initarg :output-pathname
  46                     :accessor test-official-output-pathname)
  47    (output-compare :initarg :output-compare
  48                    :accessor test-output-compare)))
  49
  50 (defmethod print-object ((object test-case) stream)
  51   (print-unreadable-object (object stream :identity nil :type t)
  52     (format stream "~A ~A/~A"
  53             (test-operation object)
  54             (test-category object)
  55             (test-id object))))
  56
  57
  58 ;;;; SIMPLIFY-TESTS
  59
  60 ;;; Translate catalog.xml into an actually usable katalog.xml
  61 ;;; by running the test cases through xsltproc to see what it thinks
  62 ;;; about them.
  63
  64 (defun simplify-tests (&optional (d *tests-directory*))
  65   (with-open-file (stream (merge-pathnames "katalog.xml" d)
  66                           :direction :output
  67                           :if-exists :supersede
  68                           :element-type '(unsigned-byte 8))
  69     (cxml:with-xml-output (cxml:make-octet-stream-sink stream)
  70       (cxml:with-element "simplified-test-suite"
  71         (klacks:with-open-source
  72             (source (klacks:make-tapping-source
  73                      (cxml:make-source (merge-pathnames "catalog.xml" d))))
  74           (let ((*default-pathname-defaults* (merge-pathnames d)))
  75             (map-original-tests #'simplify-test source)))))))
  76
  77 (defun map-original-tests (run-test source &key (test (constantly t)))
  78   (let ((total 0)
  79         (pass 0)
  80         major-path)
  81     (loop
  82        while (klacks:find-event source :start-element)
  83        for lname = (klacks:current-lname source)
  84        do
  85        (cond
  86          ((equal lname "major-path")
  87           (klacks:skip source :start-element)
  88           (setf major-path
  89                 (namestring
  90                  (merge-pathnames (klacks:consume-characters source)))))
  91          ((equal lname "test-case")
  92           (let* ((<test-case>
  93                   (stp:document-element
  94                    (klacks:serialize-element source (stp:make-builder))))
  95                  (test-case (parse-original-test major-path <test-case>)))
  96             (when (funcall test test-case)
  97               (incf total)
  98               (when (funcall run-test test-case)
  99                 (incf pass)))))
 100          (t
 101           (klacks:skip source :start-element))))
 102     (format t "~&Passed ~D/~D tests.~%" pass total)))
 103
 104 (defun parse-original-test (major-path <test-case>)
 105   (let* ((file-path
 106           (stp:string-value
 107            (stp:find-recursively-if (stp:of-name "file-path") <test-case>)))
 108          (base (concatenate 'string major-path "/" file-path))
 109          (out-base (concatenate 'string major-path "/REF_OUT/" file-path))
 110          (scenario
 111           (stp:find-recursively-if (stp:of-name "scenario") <test-case>))
 112          data
 113          stylesheet
 114          supplemental-stylesheet
 115          supplemental-data
 116          output
 117          compare)
 118     (dolist (<input> (stp:filter-recursively (stp:of-name "input-file")
 119                                              <test-case>))
 120       (let ((role (stp:attribute-value <input> "role"))
 121             (path (concatenate 'string base "/" (stp:string-value <input>))))
 122         (cond
 123           ((equal role "principal-data")
 124            (setf data path))
 125           ((equal role "principal-stylesheet")
 126            (setf stylesheet path))
 127           ((equal role "supplemental-stylesheet")
 128            (setf supplemental-stylesheet path))
 129           ((equal role "supplemental-data")
 130            (setf supplemental-data path))
 131           (t
 132            (error "unrecognized role: ~A" role)))))
 133     (dolist (<output> (stp:filter-recursively (stp:of-name "output-file")
 134                                             <test-case>))
 135       (let ((role (stp:attribute-value <output> "role"))
 136             (path (concatenate 'string out-base
 137                                "/"
 138                                (stp:string-value <output>))))
 139         (cond
 140           ((equal role "principal")
 141            (setf output path)
 142            (setf compare (stp:attribute-value <output> "compare")))
 143           (t
 144            (error "unrecognized role: ~A" role)))))
 145     (make-instance 'test-case
 146                    :id (stp:attribute-value <test-case> "id")
 147                    :category (stp:attribute-value <test-case> "category")
 148                    :operation (stp:attribute-value scenario "operation")
 149                    :data-pathname data
 150                    :stylesheet-pathname stylesheet
 151                    :stylesheet-pathname-2 supplemental-stylesheet
 152                    :data-pathname-2 supplemental-data
 153                    :output-pathname output
 154                    :output-compare compare)))
 155
 156 (defun write-simplified-test (test-case operation)
 157   (cxml:with-element "test-case"
 158     (cxml:attribute "id" (test-id test-case))
 159     (cxml:attribute "category" (test-category test-case))
 160     (flet ((p (l p)
 161              (cxml:attribute l (and p (namestring p)))))
 162       (p "data" (test-data-pathname test-case))
 163       (p "stylesheet" (noindent-stylesheet-pathname test-case))
 164       (p "data-2" (test-data-pathname-2 test-case))
 165       (p "stylesheet-2" (test-stylesheet-pathname-2 test-case))
 166       (p "output" (test-official-output-pathname test-case))
 167       (p "compare" (test-output-compare test-case)))
 168     (cxml:attribute "operation" operation)))
 169
 170 (defun test-output-pathname (test type)
 171   (make-pathname :name (test-id test)
 172                  :type type
 173                  :defaults (test-data-pathname test)))
 174
 175 (defun sanitize-stylesheet (in out)
 176   (if (probe-file in)
 177       (handler-case
 178           (let ((d (cxml:parse (pathname in) (stp:make-builder))))
 179             (xpath:with-namespaces ((nil #.*xsl*))
 180               (xpath:do-node-set (output (xpath:evaluate "//output" d))
 181                 (let ((a (stp:find-attribute-named output "indent")))
 182                   (when a
 183                     (stp:detach a)))))
 184             (with-open-file (s out
 185                                :direction :output
 186                                :if-exists :rename-and-delete
 187                                :element-type '(unsigned-byte 8))
 188               (stp:serialize d (cxml:make-octet-stream-sink s))))
 189         (error (c)
 190           (warn "ignoring bogus stylesheet ~A: ~A" in c)
 191           (copy-file in out)))
 192       (warn "oops, ignoring missing stylesheet: ~A" in)))
 193
 194 (defun noindent-stylesheet-pathname (test-case)
 195   (make-pathname :type "noindent-xsl"
 196                  :defaults (test-stylesheet-pathname test-case)))
 197
 198 (defun simplify-test (test-case)
 199   (flet ((report (status &optional (fmt "") &rest args)
 200            (format t "~&~A ~A [~A]~?~%"
 201                    status
 202                    (test-id test-case)
 203                    (test-category test-case)
 204                    fmt
 205                    args)))
 206     (let* ((data (test-data-pathname test-case))
 207            (stylesheet (test-stylesheet-pathname test-case))
 208            (noindent-stylesheet (noindent-stylesheet-pathname test-case))
 209            #+xuriella::xsltproc
 210            (out (test-output-pathname test-case "xsltproc"))
 211            (saxon-out (test-output-pathname test-case "saxon")))
 212       (sanitize-stylesheet stylesheet noindent-stylesheet)
 213       (if (equal (test-operation test-case) "standard")
 214           (handler-case
 215               (progn
 216                 #+xuriella::xsltproc (xsltproc noindent-stylesheet data out)
 217                 (saxon noindent-stylesheet data saxon-out)
 218                 (report "PASS")
 219                 (write-simplified-test test-case "standard")
 220                 t)
 221             (error (c)
 222               (report "FAIL" ": ~A" c)
 223               (write-simplified-test test-case "execution-error")
 224               nil))
 225           (handler-case
 226               (progn
 227                 #+xuriella::xsltproc
 228                 (xsltproc noindent-stylesheet data "/dev/null")
 229                 (saxon noindent-stylesheet data "/dev/null")
 230                 (report "FAIL" ": expected error not signalled")
 231                 ;; let's ignore unexpected successes for now
 232                 nil)
 233             (error (c)
 234               (report "PASS" ": expected error ~A" c)
 235               (write-simplified-test test-case "execution-error")
 236               t))))))
 237
 238 (defun xsltproc (stylesheet input output)
 239   (flet ((full-namestring (x)
 240            (namestring (merge-pathnames x))))
 241     (let* ((asdf::*verbose-out* (make-string-output-stream))
 242            (code (asdf:run-shell-command
 243                   "cd ~S && xsltproc ~S ~S >~S"
 244                   (full-namestring "")
 245                   (full-namestring stylesheet)
 246                   (full-namestring input)
 247                   (full-namestring output))))
 248       (unless (zerop code)
 249         (error "running xsltproc failed with code ~A [~%~A~%]"
 250                code
 251                (get-output-stream-string asdf::*verbose-out*))))))
 252
 253 (defun saxon (stylesheet input output)
 254   (flet ((full-namestring (x)
 255            (namestring (merge-pathnames x))))
 256     (let* ((asdf::*verbose-out* (make-string-output-stream))
 257            (code (asdf:run-shell-command
 258                   "cd ~S && java -jar /usr/share/java/saxon.jar ~S ~S >~S"
 259                   (full-namestring "")
 260                   (full-namestring input)
 261                   (full-namestring stylesheet)
 262                   (full-namestring output))))
 263       (unless (zerop code)
 264         (error "running saxon failed with code ~A [~%~A~%]"
 265                code
 266                (get-output-stream-string asdf::*verbose-out*))))))
 267
 268
 269 ;;;; RUN-TESTS and DRIBBLE-TESTS
 270
 271 ;;; Process katalog.xml
 272
 273 ;; temporary configuration until we support enough XSLT that it's worth
 274 ;; running all tests:
 275 (defparameter *default-categories*
 276   ;; '("XSLT-Data-Model" "XPath-Expression" "XPath-Data-Model")
 277   nil)
 278
 279 (defun dribble-tests (&optional (category *default-categories*)
 280                       (d *tests-directory*))
 281   (let ((*package* (find-package 'cl-user)))
 282     (with-open-file (dribble
 283                      (merge-pathnames "TEST"
 284                                       (slot-value (asdf:find-system :xuriella)
 285                                                   'asdf::relative-pathname))
 286                      :direction :output
 287                      :if-exists :supersede
 288                      :external-format :utf-8)
 289       (let* ((dribble (make-broadcast-stream dribble *standard-output*))
 290              (*standard-output* dribble)
 291              (*trace-output* dribble)
 292              (*error-output* dribble)
 293              (*terminal-io* (make-two-way-stream *standard-input* dribble)))
 294         (handler-bind ((warning
 295                         (lambda (c)
 296                           (warn "~A" (replace-junk (princ-to-string c)))
 297                           (muffle-warning c))))
 298           (run-tests category d))))))
 299
 300 (defparameter *bad-tests*
 301   '( ;; some tests wants us to recover from this error, yet this one doesn't:
 302     "copy_copy61"
 303     "copy_copy62"
 304     ;; the following tests take a lot of time due to the problems of current matching algorithm:
 305     "impincl_impincl16"
 306     "match_match13"
 307     ;; stack exhaustion -- matching problem i think
 308     "Keys_PerfRepro3"
 309     ;; probably the same problem (but I haven't checked):
 310     "numbering_numbering03"
 311     "numbering_numbering80"
 312     "numbering_numbering81"
 313     "Import__91164"))
 314
 315 (defun run-tests (&optional (categories *default-categories*)
 316                   (d *tests-directory*))
 317   (unless (listp categories)
 318     (setf categories (list categories)))
 319   (klacks:with-open-source
 320       (source (klacks:make-tapping-source
 321                (cxml:make-source (merge-pathnames "katalog.xml" d))))
 322     (let ((*default-pathname-defaults* (merge-pathnames d)))
 323       (map-tests #'run-test
 324                  source
 325                  :test (lambda (test)
 326                          (and (or (null categories)
 327                                   (find (test-category test)
 328                                         categories
 329                                         :test #'equal))
 330                               (not (find (test-id test)
 331                                          *bad-tests*
 332                                          :test #'equal))))))))
 333
 334 (defun run-named-test (name &optional (d *tests-directory*))
 335   (klacks:with-open-source
 336       (source (klacks:make-tapping-source
 337                (cxml:make-source (merge-pathnames "katalog.xml" d))))
 338     (let ((*default-pathname-defaults* (merge-pathnames d))
 339           (*break-on-signals* 'error))
 340       (map-tests #'run-test
 341                  source
 342                  :test (lambda (test) (equal (test-id test) name))))))
 343
 344 (defun copy-file (p q)
 345   (with-open-file (in p :element-type '(unsigned-byte 8))
 346     (with-open-file (out q
 347                          :element-type '(unsigned-byte 8)
 348                          :direction :output
 349                          :if-exists :rename-and-delete)
 350       (let ((buf (make-array 8192 :element-type '(unsigned-byte 8))))
 351         (loop for pos = (read-sequence buf in)
 352            until (zerop pos)
 353            do (write-sequence buf out :end pos))))))
 354
 355 (defun find-named-test (name &optional (d *tests-directory*))
 356   (klacks:with-open-source
 357       (source (klacks:make-tapping-source
 358                (cxml:make-source (merge-pathnames "katalog.xml" d))))
 359     (block nil
 360       (map-tests (lambda (test)
 361                    (return test))
 362                  source
 363                  :test (lambda (test) (equal (test-id test) name))))))
 364
 365 (defun copy-test-files (name &optional (d *tests-directory*))
 366   (let* ((test (find-named-test name d))
 367          (*default-pathname-defaults* (merge-pathnames d))
 368          (*break-on-signals* 'error)
 369          (target-dir (merge-pathnames "copied-test/"
 370                                       (asdf:component-pathname
 371                                        (asdf:find-system :xuriella))))
 372          (xsl (merge-pathnames "test.xsl" target-dir))
 373          (xml (merge-pathnames "test.xml" target-dir))
 374          (txt (merge-pathnames "official-output.txt" target-dir))
 375          (expected (merge-pathnames "expected.xml" target-dir))
 376          (actual (merge-pathnames "actual.xml" target-dir)))
 377     (ensure-directories-exist target-dir)
 378     (copy-file (test-stylesheet-pathname test) xsl)
 379     (copy-file (test-data-pathname test) xml)
 380     (when (test-official-output-pathname test)
 381       (copy-file (test-official-output-pathname test) txt))
 382     (format t "Test stylesheet copied to:~%  ~A~%~%" xsl)
 383     (format t "Test data copied to:~%  ~A~%~%" xml)
 384     (when (test-official-output-pathname test)
 385       (format t "Official output file:~%  ~A~%~%" txt))
 386     (format t "Run xsltproc like this:~%  cd ~A~%  xsltproc ~A ~A >~A~%~%"
 387             (namestring target-dir)
 388             (enough-namestring xsl target-dir)
 389             (enough-namestring xml target-dir)
 390             (enough-namestring expected target-dir))
 391     (format t "Run saxon like this:~%  cd ~A~%  java -jar /usr/share/java/saxon.jar ~A ~A >~A~%~%"
 392             (namestring target-dir)
 393             (enough-namestring xml target-dir)
 394             (enough-namestring xsl target-dir)
 395             (enough-namestring expected target-dir))
 396     (format t "Run MSXSL like this:~%  cd ~A~%  wine msxsl.exe ~A ~A >~A~%~%"
 397             (namestring target-dir)
 398             (enough-namestring xml target-dir)
 399             (enough-namestring xsl target-dir)
 400             (enough-namestring expected target-dir))
 401     (format t "Run xuriella like this:~%")
 402     `(apply-stylesheet ,xsl ,xml :output ,actual)))
 403
 404 (defun map-tests (run-test source &key (test (constantly t)))
 405   (let ((total 0)
 406         (pass 0))
 407     (loop
 408        while (klacks:find-event source :start-element)
 409        for lname = (klacks:current-lname source)
 410        do
 411        (cond
 412          ((equal lname "test-case")
 413           (let* ((<test-case>
 414                   (stp:document-element
 415                    (klacks:serialize-element source (stp:make-builder))))
 416                  (test-case (parse-test <test-case>)))
 417             (when (funcall test test-case)
 418               (incf total)
 419               (when (funcall run-test test-case)
 420                 (incf pass)))))
 421          (t
 422           (klacks:skip source :start-element))))
 423     (format t "~&Passed ~D/~D tests.~%" pass total)))
 424
 425 (defun parse-test (<test-case>)
 426   (stp:with-attributes (id category operation
 427                            data stylesheet data-2 stylesheet-2
 428                            output compare)
 429       <test-case>
 430     (make-instance 'test-case
 431                    :id id
 432                    :category category
 433                    :operation operation
 434                    :data-pathname data
 435                    :stylesheet-pathname stylesheet
 436                    :data-pathname-2 data-2
 437                    :stylesheet-pathname-2 stylesheet-2
 438                    :output-pathname output
 439                    :output-compare compare)))
 440
 441 ;; read from file P, skipping the XMLDecl or TextDecl and Doctype at the
 442 ;; beginning, if any.
 443 (defun slurp-for-comparison (p)
 444   (with-open-file (s p :element-type '(unsigned-byte 8))
 445     (unless (and (eql (read-byte s nil) #xef)
 446                  (eql (read-byte s nil) #xbb)
 447                  (eql (read-byte s nil) #xbf))
 448       (file-position s 0))
 449     (if (plusp (file-length s))
 450         (let ((xstream (runes:make-xstream s :speed 1)))
 451           (setf (runes:xstream-name xstream)
 452                 (cxml::make-stream-name
 453                  :entity-name "main document"
 454                  :entity-kind :main
 455                  :uri (cxml::pathname-to-uri (merge-pathnames p))))
 456           (let ((source (cxml:make-source xstream :pathname p)))
 457             (loop
 458                for key = (klacks:peek-next source)
 459                until (eq key :start-document))
 460             (with-output-to-string (r)
 461               (write-line "<wrapper>" r)
 462               (cxml::with-source (source cxml::context)
 463                 (when (eq (cxml::zstream-token-category
 464                            (cxml::main-zstream cxml::context))
 465                           :seen-<)
 466                   (write-char #\< r)))
 467               (loop
 468                  for char = (runes:read-rune xstream)
 469                  until (eq char :eof)
 470                  do (write-char char r))
 471               (write-line "</wrapper>" r))))
 472         "<wrapper/>")))
 473
 474 (defun parse-for-comparison (p)
 475   (let* ((d (cxml:parse (slurp-for-comparison p)
 476                         (make-text-normalizer (stp:make-builder))))
 477          (de (stp:document-element d)))
 478     (let ((first (stp:first-child de)))
 479       (when (typep first 'stp:text)
 480         (cond
 481           ((whitespacep (stp:data first))
 482            (stp:delete-child first de))
 483           (t
 484            (setf (stp:data first)
 485                  (cl-ppcre:regex-replace #.(format nil "^[~A]+" *whitespace*)
 486                                          (stp:data first)
 487                                          ""))))))
 488     (let ((last (stp:last-child de)))
 489       (when (typep last 'stp:text)
 490         (cond
 491           ((whitespacep (stp:data last))
 492            (stp:delete-child last de))
 493           (t
 494            (setf (stp:data last)
 495                  (cl-ppcre:regex-replace #.(format nil "[~A]+$" *whitespace*)
 496                                          (stp:data last)
 497                                          ""))))))
 498     d))
 499
 500 (defun output-equal-p (compare p q)
 501   (handler-case
 502       (ecase compare
 503         (:xml (xml-output-equal-p p q))
 504         (:html (html-output-equal-p p q))
 505         (:text (text-output-equal-p p q)))
 506     ((or error parse-number::invalid-number) (c)
 507       (warn "comparison failed: ~A" c)
 508       nil)))
 509
 510 ;; Workaround for namespace_namespace23 and other tests:
 511 ;;  - For these tests, saxon and msxsl output a declaration for the XSL
 512 ;;    namespace without using that declaration.
 513 ;;  - I think saxon and msxsl are both wrong.
 514 ;;  - The official test output agrees with my assessment.
 515 ;;    (So does libxslt, but that's not to be trusted. :-))
 516 ;;  - Here's the catch: The official test output is broken in its whitespace
 517 ;;    handling.
 518 ;; So let's normalize spaces in test output that looks like an XSLT
 519 ;; stylesheet, allowing us to pass these tests using the official test output.
 520 (defun maybe-normalize-test-spaces (wrapper)
 521   (stp:do-children (wrapper-child wrapper)
 522     (when (and (typep wrapper-child 'stp:element)
 523                (equal (stp:namespace-uri wrapper-child) *xsl*))
 524       (strip-stylesheet wrapper-child)
 525       (labels ((recurse (e &optional preserve)
 526                  (stp:do-children (child e)
 527                    (typecase child
 528                      (stp:text
 529                       (setf (stp:data child)
 530                             (normalize-whitespace (stp:data child))))
 531                      (stp:element
 532                          (stp:with-attributes ((space "space" *xml*))
 533                              child
 534                            (let ((new-preserve
 535                                   (cond
 536                                     ((namep child "text") t)
 537                                     ((not space) preserve)
 538                                     ((equal space "preserve") t)
 539                                     (t nil))))
 540                              (recurse child new-preserve))))))))
 541         (recurse wrapper-child)))))
 542
 543 (defun xml-output-equal-p (p q)
 544   (let ((r (parse-for-comparison p))
 545         (s (parse-for-comparison q)))
 546     (maybe-normalize-test-spaces (stp:document-element r))
 547     (maybe-normalize-test-spaces (stp:document-element s))
 548     (node= (stp:document-element r) (stp:document-element s))))
 549
 550 ;; FIXME: don't do this in <pre> etc.
 551 (defun normalize-html-whitespace (node)
 552   (when (typep node 'stp:parent-node)
 553     ;; ignore newlines after start tags completely
 554     (let ((first (stp:first-child node)))
 555       (when (and (typep first 'stp:text)
 556                  (alexandria:starts-with #\newline (stp:data first)))
 557         (setf (stp:data first) (subseq (stp:data first) 1))))
 558     ;; ignore newlines before end tags completely
 559     (let ((last (stp:last-child node)))
 560       (when (and (typep last 'stp:text)
 561                  (alexandria:ends-with #\newline (stp:data last)))
 562         (setf (stp:data last)
 563               (subseq (stp:data last) 0 (length (stp:data last))))))
 564     ;; normalize sequences of whitespace
 565     (stp:do-children (child node)
 566       (if (typep child 'stp:text)
 567           (setf (stp:data child)
 568                 (let ((str (normalize-whitespace (stp:data child))))
 569                   (when
 570                       ;; FIXME!  Here we remove whitespace entirely.
 571                       ;; Totally incorrect, but I don't see how we could
 572                       ;; watch Saxon's output otherwise.
 573                       (equal str " ")
 574                     (setf str ""))
 575                   str))
 576           (normalize-html-whitespace child)))
 577     ;; just to be sure, join adjacent nodes
 578     (cxml-stp-impl::normalize-text-nodes! node)))
 579
 580 ;; FIXME: this check is too lenient, because chtml is an error-correcting
 581 ;; parser.
 582 (defun html-output-equal-p (p q)
 583   (let ((r (chtml:parse (pathname p) (stp:make-builder)))
 584         (s (chtml:parse (pathname q) (stp:make-builder))))
 585     (normalize-html-whitespace r)
 586     (normalize-html-whitespace s)
 587     (node= (stp:document-element r) (stp:document-element s))))
 588
 589 (defun text-output-equal-p (p q)
 590   (with-open-file (a p :element-type '(unsigned-byte 8))
 591     (with-open-file (b q :element-type '(unsigned-byte 8))
 592       (let ((len (file-length a)))
 593         (and (eql len (file-length b))
 594              (let ((d (make-array len :element-type '(unsigned-byte 8)))
 595                    (e (make-array len :element-type '(unsigned-byte 8))))
 596                (read-sequence d a)
 597                (read-sequence e b)
 598                (equalp d e)))))))
 599
 600 (defun strip-addresses (str)
 601   (cl-ppcre:regex-replace-all "{[0-9a-fA-F]+}\\>" str "{xxxxxxxx}>"))
 602
 603 (defun slurp-output-method (p)
 604   (xpath:with-namespaces ((nil #.*xsl*))
 605     (let* ((d (handler-bind
 606                   ((warning #'muffle-warning))
 607                 (cxml:parse (pathname p) (stp:make-builder))))
 608            (output (xpath:first-node (xpath:evaluate "//output" d))))
 609       (if output
 610           (let ((method (stp:attribute-value output "method")))
 611             (if method
 612                 (intern (string-upcase method) :keyword)
 613                 :xml))
 614           :xml))))
 615
 616 (defun replace-junk (str)
 617   (cl-ppcre:regex-replace-all
 618    `(:group ,(namestring *tests-directory*))
 619    (map 'string
 620         (lambda (c)
 621           (if (or (eql c #\newline) (<= 32 (char-code c) 126))
 622               c
 623               #\?))
 624         str)
 625    "..."))
 626
 627 (defun run-test (test)
 628   (let ((expected-saxon (test-output-pathname test "saxon"))
 629         #+xuriella::xsltproc
 630         (expected-xsltproc (test-output-pathname test "xsltproc"))
 631         (actual (test-output-pathname test "xuriella"))
 632         (official (test-official-output-pathname test)))
 633     (labels ((uri-resolver (uri)
 634                (if (search "%5c%5c%5c%5cwebxtest%5c%5cmanagedshadow%5c%5cmanaged_b2%5c%5ctestdata%5c%5cxslt%5c%5celement%5c%5cxslt_element_NSShared.xml"
 635                            uri)
 636                    (cxml::pathname-to-uri
 637                     (merge-pathnames
 638                      "MSFT_Conformance_Tests/Elements/xslt_element_NSShared.xml"
 639                      *tests-directory*))
 640                    uri))
 641              (doit ()
 642                (with-open-file (s actual
 643                                   :if-exists :rename-and-delete
 644                                   :direction :output
 645                                   :element-type '(unsigned-byte 8))
 646                  (handler-bind ((xslt-error
 647                                  (lambda (c)
 648                                    (declare (ignore c))
 649                                    (when (find-restart 'recover)
 650                                      (invoke-restart 'recover)))))
 651                    (apply-stylesheet (pathname (test-stylesheet-pathname test))
 652                                      (pathname (test-data-pathname test))
 653                                      :output s
 654                                      :uri-resolver #'uri-resolver))))
 655              (pp (label pathname)
 656                (when pathname
 657                  (format t "  ~A: ~A~%"
 658                          label
 659                          (enough-namestring pathname *tests-directory*))))
 660              (report (ok &optional (fmt "") &rest args)
 661                (write-string
 662                 (replace-junk
 663                  (strip-addresses
 664                   (format nil "~&~:[FAIL~;PASS~] ~A [~A]~?~%"
 665                           ok
 666                           (test-id test)
 667                           (test-category test)
 668                           fmt
 669                           args))))
 670                (pp "Stylesheet" (test-stylesheet-pathname test))
 671                (pp "Data" (test-data-pathname test))
 672                (pp "Supplemental stylesheet"
 673                    (test-stylesheet-pathname-2 test))
 674                (pp "Supplemental data" (test-data-pathname-2 test))
 675                (pp "Expected output (1)" expected-saxon)
 676                #+xuriella::xsltproc
 677                (pp "Expected output (2)" expected-xsltproc)
 678                (pp "Actual output" actual)
 679                (terpri)
 680                ok))
 681       (cond
 682         ((equal (test-operation test) "standard")
 683          (handler-case
 684              (let ((output-method
 685                     (slurp-output-method (test-stylesheet-pathname test))))
 686                (when (find (test-id test)
 687                            nil ;;'("axes_axes47" "attribset_attribset20")
 688                            :test #'equal)
 689                  (error "skipping problematic test"))
 690                (doit)
 691                (let ((saxon-matches-p
 692                       (output-equal-p output-method
 693                                       expected-saxon
 694                                       actual))
 695                      #+xuriella::xsltproc
 696                      (xsltproc-matches-p
 697                       (output-equal-p output-method
 698                                       expected-xsltproc
 699                                       actual))
 700                      (official-matches-p
 701                       (output-equal-p output-method
 702                                       official
 703                                       actual)))
 704                  (cond
 705                    ((or saxon-matches-p
 706                         #+xuriella::xsltproc xsltproc-matches-p
 707                         official-matches-p)
 708                     (report t)
 709                     #+xuriella::xsltproc
 710                     (report t ": saxon ~A, xsltproc ~A~:[~; (MISMATCH)~]"
 711                             saxon-matches-p
 712                             xsltproc-matches-p
 713                             (if saxon-matches-p
 714                                 (not xsltproc-matches-p)
 715                                 xsltproc-matches-p)))
 716                    (t
 717                     (report nil ": output doesn't match")))))
 718            ((or error parse-number::invalid-number) (c)
 719             (report nil ": ~A" c))))
 720         (t
 721          (handler-case
 722              (doit)
 723            (xslt-error (c)
 724              (report t ": raised an xslt-error as expected" c))
 725            ((or error parse-number::invalid-number) (c)
 726              (report nil ": condition of incorrect type: ~%~A" c))
 727            (:no-error (result)
 728              (cond
 729                ((not (and official (probe-file official)))
 730                 (report nil ": expected error not signalled: " result))
 731                ((output-equal-p
 732                  (slurp-output-method (test-stylesheet-pathname test))
 733                  official
 734                  actual)
 735                 (report t))
 736                (t
 737                 (report nil ": saxon error not signalled and official output not a match"))))))))))
 738
 739 (defun run-xpath-tests ()
 740   (run-tests '("XPath-Expression" "XSLT-Data-Model")))
 741
 742
 743 ;;;; from cxml-stp-test
 744
 745 (defun assert-node= (a b)
 746   (unless (node= a b)
 747     (error "assertion failed: ~S and ~S are not NODE=" a b)))
 748
 749 (defun child-count (node)
 750   (stp:count-children-if (constantly t) node))
 751
 752 (defun named-node-= (a b)
 753   (and (equal (stp:namespace-uri a) (stp:namespace-uri b))
 754        ;; (equal (stp:namespace-prefix a) (stp:namespace-prefix b))
 755        (equal (stp:local-name a) (stp:local-name b))))
 756
 757 (defun parent-node-= (e f)
 758   (and (eql (child-count e)
 759             (child-count f))
 760        (every #'node= (stp:list-children e) (stp:list-children f))))
 761
 762 (defmethod node= ((e stp:element) (f stp:element))
 763   (and (named-node-= e f)
 764        (parent-node-= e f)
 765        (null
 766         (set-exclusive-or (stp:list-attributes e) (stp:list-attributes f)
 767                           :test #'node=))
 768        (block nil
 769          (flet ((check-namespaces (a b)
 770                   (let ((result ()))
 771                     (stp:map-extra-namespaces
 772                      (lambda (k v)
 773                        (unless (equal v (stp:find-namespace k b))
 774                          (return nil)))
 775                      a)
 776                     result)))
 777            (check-namespaces e f)
 778            (check-namespaces f e))
 779          t)))
 780
 781 (defmethod node= ((a stp:node) (b stp:node))
 782   nil)
 783
 784 (defmethod node= ((e stp:document) (f stp:document))
 785   (parent-node-= e f))
 786
 787 (defmethod node= ((a stp:attribute) (b stp:attribute))
 788   (and (named-node-= a b)
 789        (equal (stp:value a) (stp:value b))))
 790
 791 (defmethod node= ((a stp:comment) (b stp:comment))
 792   (equal (stp:data a) (stp:data b)))
 793
 794 (defmethod node= ((a stp:text) (b stp:text))
 795   (equal (stp:data a) (stp:data b)))
 796
 797 (defmethod node= ((a stp:processing-instruction)
 798                   (b stp:processing-instruction))
 799   (and (equal (stp:data a) (stp:data b))
 800        (equal (stp:target a) (stp:target b))))
 801
 802 (defmethod node= ((a stp:document-type) (b stp:document-type))
 803   (and (equal (stp:root-element-name a) (stp:root-element-name b))
 804        (equal (stp:public-id a) (stp:public-id b))
 805        (equal (stp:system-id a) (stp:system-id b))
 806        (equal (stp:internal-subset a) (stp:internal-subset b))))
 807
 808 (xpath-sys:define-xpath-function/eager
 809     xslt :print
 810     (thing)
 811   (if (xpath:node-set-p thing)
 812       (loop
 813          initially (format t ";;; node set:~%")
 814          for i from 0
 815          for node in (xpath:all-nodes thing)
 816          do
 817            (format t ";;;   ~D: ~A~%" i (type-of node)))
 818       (format t ";;; ~A~%" thing))
 819   thing)