instructions.lisp

   1 ;;; -*- show-trailing-whitespace: t; indent-tabs-mode: nil -*-
   2
   3 ;;; Copyright (c) 2007,2008 David Lichteblau, Ivan Shvedunov.
   4 ;;; All rights reserved.
   5
   6 ;;; Redistribution and use in source and binary forms, with or without
   7 ;;; modification, are permitted provided that the following conditions
   8 ;;; are met:
   9 ;;;
  10 ;;;   * Redistributions of source code must retain the above copyright
  11 ;;;     notice, this list of conditions and the following disclaimer.
  12 ;;;
  13 ;;;   * Redistributions in binary form must reproduce the above
  14 ;;;     copyright notice, this list of conditions and the following
  15 ;;;     disclaimer in the documentation and/or other materials
  16 ;;;     provided with the distribution.
  17 ;;;
  18 ;;; THIS SOFTWARE IS PROVIDED BY THE AUTHOR 'AS IS' AND ANY EXPRESSED
  19 ;;; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  20 ;;; WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  21 ;;; ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY
  22 ;;; DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  23 ;;; DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE
  24 ;;; GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  25 ;;; INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  26 ;;; WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
  27 ;;; NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  28 ;;; SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29
  30 (in-package :xuriella)
  31
  32 #+sbcl
  33 (declaim (optimize (debug 2)))
  34
  35
  36 ;;;; Instructions
  37
  38 (defparameter *available-instructions* (make-hash-table :test 'equal))
  39
  40 (defmacro define-instruction (name (args-var env-var) &body body)
  41   `(setf (get ',name 'xslt-instruction)
  42          (lambda (,args-var ,env-var)
  43            (declare (ignorable ,env-var))
  44            ,@body)))
  45
  46 (define-instruction if (args env)
  47   (destructuring-bind (test then &optional else) args
  48     (let ((test-thunk (compile-xpath test env))
  49           (then-thunk (compile-instruction then env))
  50           (else-thunk (when else (compile-instruction else env))))
  51       (lambda (ctx)
  52         (cond
  53           ((xpath:boolean-value (funcall test-thunk ctx))
  54            (funcall then-thunk ctx))
  55           (else-thunk
  56            (funcall else-thunk ctx)))))))
  57
  58 (define-instruction when (args env)
  59   (destructuring-bind (test &rest body) args
  60     (compile-instruction `(if ,test (progn ,@body)) env)))
  61
  62 (define-instruction unless (args env)
  63   (destructuring-bind (test &rest body) args
  64     (compile-instruction `(if (:not ,test) (progn ,@body)) env)))
  65
  66 (define-instruction cond (args env)
  67   (if args
  68       (destructuring-bind ((test &body body) &rest clauses) args
  69         (compile-instruction (if (eq test t)
  70                                  `(progn ,@body)
  71                                  `(if ,test
  72                                       (progn ,@body)
  73                                       (cond ,@clauses)))
  74                              env))
  75       (constantly nil)))
  76
  77 (define-instruction progn (args env)
  78   (if args
  79       (let ((first-thunk (compile-instruction (first args) env))
  80             (rest-thunk (compile-instruction `(progn ,@(rest args)) env)))
  81         (lambda (ctx)
  82           (funcall first-thunk ctx)
  83           (funcall rest-thunk ctx)))
  84       (constantly nil)))
  85
  86 (defun decode-qname/runtime (qname namespaces attributep)
  87   (handler-case
  88       (multiple-value-bind (prefix local-name)
  89           (split-qname qname)
  90         (values local-name
  91                 (if (or prefix (not attributep))
  92                     (or (cdr (assoc prefix namespaces :test 'equal))
  93                         (xslt-error "namespace not found: ~A" prefix))
  94                     "")
  95                 prefix))
  96     (cxml:well-formedness-violation ()
  97       (xslt-error "not a qname: ~A" qname))))
  98
  99 (define-instruction xsl:element (args env)
 100   (destructuring-bind ((name &key namespace use-attribute-sets)
 101                        &body body)
 102       args
 103     (declare (ignore use-attribute-sets)) ;fixme
 104     (multiple-value-bind (name-thunk constant-name-p)
 105         (compile-avt name env)
 106       (multiple-value-bind (ns-thunk constant-ns-p)
 107           (if namespace
 108               (compile-avt namespace env)
 109               (values nil t))
 110         (let ((body-thunk (compile-instruction `(progn ,@body) env)))
 111           (if (and constant-name-p constant-ns-p)
 112               (compile-element/constant-name name namespace env body-thunk)
 113               (compile-element/runtime name-thunk ns-thunk body-thunk)))))))
 114
 115 (defun compile-element/constant-name (qname namespace env body-thunk)
 116   ;; the simple case: compile-time decoding of the QName
 117   (multiple-value-bind (local-name uri prefix)
 118       (decode-qname qname env nil)
 119     (when namespace
 120       (setf uri namespace))
 121     (lambda (ctx)
 122       (cond
 123         (uri
 124          (with-element (local-name uri :suggested-prefix prefix)
 125            (funcall body-thunk ctx)))
 126         (t
 127          ;; ERROR rather than CERROR because saxon doesn't do the recovery,
 128          ;; and the official output illustrates recovery but is useless as
 129          ;; always.
 130          (xslt-error "namespace not found: ~A" prefix)
 131          #+(or)
 132          (let ((*start-tag-written-p* t))
 133            (declare (special *start-tag-written-p*))
 134            (funcall body-thunk ctx)))))))
 135
 136 (defun compile-element/runtime (name-thunk ns-thunk body-thunk)
 137   ;; run-time decoding of the QName, but using the same namespaces
 138   ;; that would have been known at compilation time.
 139   (let ((namespaces *namespaces*))
 140     (lambda (ctx)
 141       (let ((qname (funcall name-thunk ctx)))
 142         (multiple-value-bind (local-name uri prefix)
 143             (decode-qname/runtime qname namespaces nil)
 144           (when ns-thunk
 145             (setf uri (funcall ns-thunk ctx)))
 146           (unless uri
 147             (setf uri ""))
 148           (with-element (local-name uri :suggested-prefix prefix)
 149             (funcall body-thunk ctx)))))))
 150
 151 (define-instruction xsl:use-attribute-sets (args env)
 152   (destructuring-bind (str) args
 153     (let ((sets (mapcar (lambda (qname)
 154                           (multiple-value-list (decode-qname qname env nil)))
 155                         (words str))))
 156       (lambda (ctx)
 157         (loop for (local-name uri nil) in sets do
 158              (dolist (thunk (find-attribute-set local-name uri))
 159                (funcall thunk ctx)))))))
 160
 161 (define-instruction xsl:attribute (args env)
 162   (destructuring-bind ((name &key namespace) &body body) args
 163     (when (null name)
 164       (xslt-error "xsl:attribute: name not specified"))
 165     (multiple-value-bind (name-thunk constant-name-p)
 166         (compile-avt name env)
 167       (multiple-value-bind (ns-thunk constant-ns-p)
 168           (if namespace
 169               (compile-avt namespace env)
 170               (values nil t))
 171         (let ((value-thunk (compile-instruction `(progn ,@body) env)))
 172           (if (and constant-name-p constant-ns-p)
 173               (compile-attribute/constant-name name namespace env value-thunk)
 174               (compile-attribute/runtime name-thunk ns-thunk value-thunk)))))))
 175
 176 (defun compile-attribute/constant-name (qname namespace env value-thunk)
 177   ;; the simple case: compile-time decoding of the QName
 178   (multiple-value-bind (local-name uri prefix)
 179       (decode-qname qname env t)
 180     (when namespace
 181       (setf uri namespace))
 182     (lambda (ctx)
 183       (write-attribute local-name
 184                        (or uri "")
 185                        (with-toplevel-text-output-sink (s)
 186                          (with-xml-output s
 187                            (funcall value-thunk ctx)))
 188                        :suggested-prefix prefix))))
 189
 190 (defun compile-attribute/runtime (name-thunk ns-thunk value-thunk)
 191   ;; run-time decoding of the QName, but using the same namespaces
 192   ;; that would have been known at compilation time.
 193   (let ((namespaces *namespaces*))
 194     (lambda (ctx)
 195       (let ((qname (funcall name-thunk ctx)))
 196         (multiple-value-bind (local-name uri prefix)
 197             (decode-qname/runtime qname namespaces t)
 198           (when ns-thunk
 199             (setf uri (funcall ns-thunk ctx)))
 200           (write-attribute local-name
 201                            (or uri "")
 202                            (with-toplevel-text-output-sink (s)
 203                              (with-xml-output s
 204                                (funcall value-thunk ctx)))
 205                            :suggested-prefix prefix))))))
 206
 207 ;; zzz Also elides (later) namespaces hidden by (earlier) ones.
 208 ;; zzz Reverses order.
 209 (defun remove-excluded-namespaces
 210     (namespaces &optional (excluded-uris *excluded-namespaces*))
 211   (let ((koerbchen '())
 212         (kroepfchen '()))
 213     (loop
 214        for cons in namespaces
 215        for (prefix* . uri) = cons
 216        for prefix = (or prefix* "")
 217        do
 218          (cond
 219            ((find prefix kroepfchen :test #'equal))
 220            ((find prefix koerbchen :test #'equal :key #'car))
 221            ((find uri excluded-uris :test #'equal)
 222             (push prefix kroepfchen))
 223            (t
 224             (push cons koerbchen))))
 225     koerbchen))
 226
 227 (define-instruction xsl:literal-element (args env)
 228   (destructuring-bind
 229         ((local-name &optional (uri "") suggested-prefix) &body body)
 230       args
 231     (let ((body-thunk (compile-instruction `(progn ,@body) env))
 232           (namespaces (remove-excluded-namespaces *namespaces*)))
 233       (lambda (ctx)
 234         (with-element (local-name (or uri "")
 235                                   :suggested-prefix suggested-prefix
 236                                   :extra-namespaces namespaces
 237                                   :process-aliases t)
 238           (funcall body-thunk ctx))))))
 239
 240 (define-instruction xsl:literal-attribute (args env)
 241   (destructuring-bind ((local-name &optional uri suggested-prefix) value) args
 242     (let ((value-thunk (compile-avt value env)))
 243       (lambda (ctx)
 244         (write-attribute local-name
 245                          uri
 246                          (funcall value-thunk ctx)
 247                          :process-aliases t
 248                          :suggested-prefix suggested-prefix)))))
 249
 250 (define-instruction xsl:text (args env)
 251   (destructuring-bind (str) args
 252     (lambda (ctx)
 253       (declare (ignore ctx))
 254       (write-text str))))
 255
 256 (define-instruction xsl:unescaped-text (args env)
 257   (destructuring-bind (str) args
 258     (lambda (ctx)
 259       (declare (ignore ctx))
 260       (write-unescaped str))))
 261
 262 (define-instruction xsl:processing-instruction (args env)
 263   (destructuring-bind (name &rest body) args
 264     (let ((name-thunk (compile-avt name env))
 265           (value-thunk (compile-instruction `(progn ,@body) env)))
 266       (lambda (ctx)
 267         (write-processing-instruction
 268          (funcall name-thunk ctx)
 269          (with-toplevel-text-output-sink (s)
 270            (with-xml-output s
 271              (funcall value-thunk ctx))))))))
 272
 273 (define-instruction xsl:comment (args env)
 274   (let ((value-thunk (compile-instruction `(progn ,@args) env)))
 275     (lambda (ctx)
 276       (write-comment (with-toplevel-text-output-sink (s)
 277                        (with-xml-output s
 278                          (funcall value-thunk ctx)))))))
 279
 280 (define-instruction xsl:value-of (args env)
 281   (destructuring-bind (xpath) args
 282     (let ((thunk (compile-xpath xpath env)))
 283       (xslt-trace-thunk
 284        (lambda (ctx)
 285          (write-text (xpath:string-value (funcall thunk ctx))))
 286        "value-of ~s = ~s" xpath :result))))
 287
 288 (define-instruction xsl:unescaped-value-of (args env)
 289   (destructuring-bind (xpath) args
 290     (let ((thunk (compile-xpath xpath env)))
 291       (lambda (ctx)
 292         (write-unescaped (xpath:string-value (funcall thunk ctx)))))))
 293
 294 (define-instruction xsl:copy-of (args env)
 295   (destructuring-bind (xpath) args
 296     (let ((thunk (compile-xpath xpath env))
 297           ;; FIXME: what was this for?  --david
 298           #+(or) (v (intern-variable "varName" "")))
 299       (xslt-trace-thunk
 300        (lambda (ctx)
 301          (let ((result (funcall thunk ctx)))
 302            (typecase result
 303              (xpath:node-set ;; FIXME: variables can contain node sets w/fragments inside. Maybe just fragments would do?
 304               (xpath:map-node-set #'copy-into-result (xpath:sort-node-set result)))
 305              (result-tree-fragment
 306               (copy-into-result result))
 307              (t
 308               (write-text (xpath:string-value result))))))
 309        "copy-of ~s" xpath))))
 310
 311 (defun copy-into-result (node)
 312   (cond
 313     ((result-tree-fragment-p node)
 314      (stp:do-children (child (result-tree-fragment-node node))
 315        (copy-into-result child)))
 316     ((xpath-protocol:node-type-p node :element)
 317      (with-element ((xpath-protocol:local-name node)
 318                     (xpath-protocol:namespace-uri node)
 319                     :suggested-prefix (xpath-protocol:namespace-prefix node)
 320                     :extra-namespaces (namespaces-as-alist node))
 321        (map-pipe-eagerly #'copy-into-result
 322                          (xpath-protocol:attribute-pipe node))
 323        (map-pipe-eagerly #'copy-into-result
 324                          (xpath-protocol:child-pipe node))))
 325     ((xpath-protocol:node-type-p node :document)
 326      (map-pipe-eagerly #'copy-into-result
 327                        (xpath-protocol:child-pipe node)))
 328     (t
 329      (copy-leaf-node node))))
 330
 331 (defparameter *lower-first-order*
 332   #(#\  #\! #\" #\# #\$ #\% #\& #\' #\( #\) #\* #\+ #\, #\- #\. #\/ #\0 #\1 #\2
 333     #\3 #\4 #\5 #\6 #\7 #\8 #\9 #\: #\; #\< #\= #\> #\? #\@ #\H #\J #\L #\N #\P
 334     #\R #\T #\V #\X #\Z #\\ #\^ #\` #\b #\d #\f #\h #\j #\l #\n #\p #\r #\t #\v
 335     #\x #\z #\A #\B #\C #\D #\E #\F #\G #\I #\K #\M #\O #\Q #\S #\U #\W #\Y #\[
 336     #\] #\_ #\a #\c #\e #\g #\i #\k #\m #\o #\q #\s #\u #\w #\y #\{ #\| #\} #\~
 337     #\Rubout))
 338
 339 (defparameter *upper-first-order*
 340   #(#\  #\! #\" #\# #\$ #\% #\& #\' #\( #\) #\* #\+ #\, #\- #\. #\/ #\0 #\1 #\2
 341     #\3 #\4 #\5 #\6 #\7 #\8 #\9 #\: #\; #\< #\= #\> #\? #\@ #\G #\I #\K #\M #\O
 342     #\Q #\S #\U #\W #\Y #\[ #\] #\_ #\a #\c #\e #\g #\i #\k #\m #\o #\q #\s #\u
 343     #\w #\y #\A #\B #\C #\D #\E #\F #\H #\J #\L #\N #\P #\R #\T #\V #\X #\Z #\\
 344     #\^ #\` #\b #\d #\f #\h #\j #\l #\n #\p #\r #\t #\v #\x #\z #\{ #\| #\} #\~
 345     #\Rubout))
 346
 347 (defun collation-char (char table)
 348   (let ((code (char-code char)))
 349     (if (<= 32 code 127)
 350         (elt table (- code 32))
 351         char)))
 352
 353 (defun make-collation-key (str table)
 354   (map 'string (lambda (char) (collation-char char table)) str))
 355
 356 (defun compare-numbers (n-a n-b)
 357   (cond ((and (xpath::nan-p n-a)
 358               (not (xpath::nan-p n-b)))
 359          -1)
 360         ((and (not (xpath::nan-p n-a))
 361               (xpath::nan-p n-b))
 362          1)
 363         ((xpath::compare-numbers '< n-a n-b) -1)
 364         ((xpath::compare-numbers '> n-a n-b) 1)
 365         (t 0)))
 366
 367 (defun mismatch* (a b)
 368   (let ((pos (mismatch a b)))
 369     (if (and pos (< pos (min (length a) (length b))))
 370         pos
 371         nil)))
 372
 373 (defun compare-strings (i j char-table)
 374   ;; zzz Unicode support!
 375   (let ((pos
 376          (or (mismatch* (string-downcase i) (string-downcase j))
 377              (mismatch* i j))))
 378     (if pos
 379         (let ((c (collation-char (elt i pos) char-table))
 380               (d (collation-char (elt j pos) char-table)))
 381           (cond
 382             ((char< c d) -1)
 383             ((char= c d) 0)
 384             (t 1)))
 385         (signum (- (length i) (length j))))))
 386
 387 (defun make-sorter/lazy (spec env)
 388   (destructuring-bind (&key select lang data-type order case-order)
 389       (cdr spec)
 390     (let ((select-thunk (compile-xpath (or select ".") env))
 391           (lang-thunk (compile-avt (or lang "")  env))
 392           (data-type-thunk (compile-avt (or data-type "") env))
 393           (order-thunk (compile-avt (or order "") env))
 394           (case-order-thunk (compile-avt (or case-order "") env)))
 395       (lambda (ctx)
 396         (let ((numberp
 397                (equal (funcall data-type-thunk ctx) "number"))
 398               (char-table
 399                (if (equal (funcall case-order-thunk ctx) "lower-first")
 400                    *lower-first-order*
 401                    *upper-first-order*))
 402               (f
 403                (if (equal (funcall order-thunk ctx) "descending") -1 1))
 404               (lang
 405                (funcall lang-thunk ctx)))
 406           (declare (ignore lang))
 407           (lambda (a b)
 408             (let ((i (xpath:string-value (funcall select-thunk a)))
 409                   (j (xpath:string-value (funcall select-thunk b))))
 410               (* f
 411                  (if numberp
 412                      (compare-numbers (xpath:number-value i)
 413                                       (xpath:number-value j))
 414                      (compare-strings i j char-table))))))))))
 415
 416 (defun compose-sorters/lazy (sorters)
 417   (if sorters
 418       (let ((this-thunk (car sorters))
 419             (next-thunk (compose-sorters/lazy (rest sorters))))
 420         (lambda (ctx)
 421           (let ((this (funcall this-thunk ctx))
 422                 (next (funcall next-thunk ctx)))
 423             (lambda (a b)
 424               (let ((d (funcall this a b)))
 425                 (if (zerop d)
 426                     (funcall next a b)
 427                     d))))))
 428       (lambda (ctx)
 429         (declare (ignore ctx))
 430         (constantly 0))))
 431
 432 (defun make-sort-predicate/lazy (decls env)
 433   (let ((sorter-thunk
 434          (compose-sorters/lazy
 435           (mapcar (lambda (x) (make-sorter/lazy x env)) decls))))
 436     (lambda (ctx)
 437       (let ((sorter (funcall sorter-thunk ctx)))
 438         (lambda (a b)
 439           (minusp (funcall sorter a b)))))))
 440
 441 (defun contextify-node-list (nodes)
 442   (let ((size (length nodes)))
 443     (loop
 444        for position from 1
 445        for node in nodes
 446        collect
 447          (xpath:make-context node size position))))
 448
 449 (define-instruction xsl:for-each (args env)
 450   (destructuring-bind (select &optional decls &rest body) args
 451     (unless (and (consp decls)
 452                  (eq (car decls) 'declare))
 453       (push decls body)
 454       (setf decls nil))
 455     (let ((select-thunk (compile-xpath select env))
 456           (body-thunk (compile-instruction `(progn ,@body) env))
 457           (sort-predicate-thunk
 458            (when (cdr decls)
 459              (make-sort-predicate/lazy (cdr decls) env))))
 460       (lambda (ctx)
 461         (let ((selected (funcall select-thunk ctx)))
 462           (unless (xpath:node-set-p selected)
 463             (xslt-error "for-each select expression should yield a node-set"))
 464           (let ((nodes (xpath::force (xpath::sorted-pipe-of selected))))
 465             (when sort-predicate-thunk
 466               (setf nodes
 467                     (mapcar #'xpath:context-node
 468                             (stable-sort (contextify-node-list nodes)
 469                                          (funcall sort-predicate-thunk ctx)))))
 470             (dolist (ctx (contextify-node-list nodes))
 471               (funcall body-thunk ctx))))))))
 472
 473 (define-instruction xsl:with-namespaces (args env)
 474   (destructuring-bind ((&rest forms) &rest body) args
 475     (let ((*namespaces* *namespaces*))
 476       (dolist (form forms)
 477         (destructuring-bind (prefix uri) form
 478           (push (cons prefix uri) *namespaces*)))
 479       (compile-instruction `(progn ,@body) env))))
 480
 481 (define-instruction xsl:with-excluded-namespaces (args env)
 482   (destructuring-bind ((&rest uris) &rest body) args
 483     (let ((*excluded-namespaces* (append uris *excluded-namespaces*)))
 484       (compile-instruction `(progn ,@body) env))))
 485
 486 (define-instruction xsl:with-extension-namespaces (args env)
 487   (destructuring-bind ((&rest uris) &rest body) args
 488     (let ((*extension-namespaces* (append uris *extension-namespaces*)))
 489       (compile-instruction `(progn ,@body) env))))
 490
 491 (define-instruction xsl:with-version (args env)
 492   (destructuring-bind (version &rest body) args
 493     (let ((*forwards-compatible-p* (not (equal version "1.0"))))
 494       (compile-instruction `(progn ,@body) env))))
 495
 496 ;; XSLT disallows multiple definitions of the same variable within a
 497 ;; template.  Local variables can shadow global variables though.
 498 ;; Since our LET syntax makes it natural to shadow local variables the
 499 ;; Lisp way, we check for duplicate variables only where instructed to
 500 ;; by the XML syntax parser using WITH-DUPLICATES-CHECK:
 501 (defvar *template-variables* nil)
 502
 503 (define-instruction xsl:with-duplicates-check (args env)
 504   (let ((*template-variables* *template-variables*))
 505     (destructuring-bind ((&rest qnames) &rest body) args
 506       (dolist (qname qnames)
 507         (multiple-value-bind (local-name uri)
 508             (decode-qname qname env nil)
 509           (let ((key (cons local-name uri)))
 510             (when (find key *template-variables* :test #'equal)
 511               (xslt-error "duplicate variable: ~A, ~A" local-name uri))
 512             (push key *template-variables*))))
 513       (compile-instruction `(progn ,@body) env))))
 514
 515 (define-instruction xsl:with-base-uri (args env)
 516   (destructuring-bind (uri &rest body) args
 517     (let ((*instruction-base-uri* uri))
 518       (compile-instruction `(progn ,@body) env))))
 519
 520 (defstruct (result-tree-fragment
 521              (:constructor make-result-tree-fragment (node)))
 522   node)
 523
 524 (define-default-method xpath-protocol:node-p
 525     ((node result-tree-fragment))
 526   t)
 527
 528 (define-default-method xpath-protocol:node-text
 529     ((node result-tree-fragment))
 530   (xpath-protocol:node-text (result-tree-fragment-node node)))
 531
 532 (defun apply-to-result-tree-fragment (ctx thunk)
 533   (let ((document
 534          (with-xml-output (make-stpx-builder)
 535            (with-element ("fragment" "")
 536              (funcall thunk ctx)))))
 537     (make-result-tree-fragment (stp:document-element document))))
 538
 539 (defun compile-var-bindings/nointern (forms env)
 540   (loop
 541     for (name value) in forms
 542     collect (multiple-value-bind (local-name uri)
 543                 (decode-qname name env nil)
 544               (list (cons local-name uri)
 545                     (xslt-trace-thunk
 546                      (compile-value-thunk value env)
 547                      "local variable ~s = ~s" name :result)))))
 548
 549 (define-instruction let (args env)
 550   (destructuring-bind ((&rest forms) &rest body) args
 551     (let* ((old-top (length *lexical-variable-declarations*))
 552            (vars-and-names (compile-var-bindings/nointern forms env))
 553            (vars-and-positions
 554             (loop for ((local-name . uri) thunk) in vars-and-names
 555                collect
 556                  (list (push-variable local-name
 557                                       uri
 558                                       *lexical-variable-declarations*)
 559                        thunk))))
 560       (let ((thunk (compile-instruction `(progn ,@body) env)))
 561         (fill *lexical-variable-declarations* nil :start old-top)
 562         (lambda (ctx)
 563           (loop for (index var-thunk) in vars-and-positions
 564              do (setf (lexical-variable-value index)
 565                       (funcall var-thunk ctx)))
 566           (funcall thunk ctx))))))
 567
 568 (define-instruction let* (args env)
 569   (destructuring-bind ((&rest forms) &rest body) args
 570     (if forms
 571         (compile-instruction `(let (,(car forms))
 572                                 (let* (,@(cdr forms))
 573                                   ,@body))
 574                              env)
 575         (compile-instruction `(progn ,@body) env))))
 576
 577 (define-instruction xsl:message (args env)
 578   (compile-message #'warn args env))
 579
 580 (define-instruction xsl:terminate (args env)
 581   (compile-message #'xslt-error args env))
 582
 583 (defun namespaces-as-alist (element)
 584   (let ((namespaces '()))
 585     (do-pipe (ns (xpath-protocol:namespace-pipe element))
 586       (push (cons (xpath-protocol:local-name ns)
 587                   (xpath-protocol:node-text ns))
 588             namespaces))
 589     namespaces))
 590
 591 (define-instruction xsl:copy (args env)
 592   (let ((body (compile-instruction `(progn ,@args) env)))
 593     (lambda (ctx)
 594       (let ((node (xpath:context-node ctx)))
 595         (cond
 596           ((xpath-protocol:node-type-p node :element)
 597            (with-element
 598                ((xpath-protocol:local-name node)
 599                 (xpath-protocol:namespace-uri node)
 600                 :suggested-prefix (xpath-protocol:namespace-prefix node)
 601                 :extra-namespaces (namespaces-as-alist node))
 602              (funcall body ctx)))
 603           ((xpath-protocol:node-type-p node :document)
 604            (funcall body ctx))
 605           (t
 606            (copy-leaf-node node)))))))
 607
 608 (defun copy-leaf-node (node)
 609   (cond
 610     ((xpath-protocol:node-type-p node :text)
 611      (etypecase (if (typep node 'stripping-node)
 612                     (stripping-node-target node)
 613                     node)
 614        (unescaped-text (write-unescaped (xpath-protocol:node-text node)))
 615        (stp:text (write-text (xpath-protocol:node-text node)))))
 616     ((xpath-protocol:node-type-p node :comment)
 617      (write-comment (xpath-protocol:node-text node)))
 618     ((xpath-protocol:node-type-p node :processing-instruction)
 619      (write-processing-instruction
 620          (xpath-protocol:processing-instruction-target node)
 621        (xpath-protocol:node-text node)))
 622     ((xpath-protocol:node-type-p node :attribute)
 623      (write-attribute
 624       (xpath-protocol:local-name node)
 625       (xpath-protocol:namespace-uri node)
 626       (xpath-protocol:node-text node)
 627       :suggested-prefix (xpath-protocol:namespace-prefix node)))
 628     ((xpath-protocol:node-type-p node :namespace)
 629      (write-extra-namespace
 630       (xpath-protocol:local-name node)
 631       (xpath-protocol:node-text node)
 632       nil))
 633     (t
 634      (error "don't know how to copy node ~A" node))))
 635
 636 (defun compile-message (fn args env)
 637   (let ((thunk (compile-instruction `(progn ,@args) env)))
 638     (lambda (ctx)
 639       (funcall fn
 640                (with-xml-output (cxml:make-string-sink)
 641                  (funcall thunk ctx))))))
 642
 643 (define-instruction xsl:apply-templates (args env)
 644   (destructuring-bind ((&key select mode) &rest param-binding-specs) args
 645     (let* ((decls
 646             (when (and (consp (car param-binding-specs))
 647                        (eq (caar param-binding-specs) 'declare))
 648               (cdr (pop param-binding-specs))))
 649            (select-thunk
 650             (compile-xpath (or select "child::node()") env))
 651            (param-bindings
 652             (compile-var-bindings param-binding-specs env))
 653            (sort-predicate-thunk
 654             (when decls
 655               (make-sort-predicate/lazy decls env))))
 656       (multiple-value-bind (mode-local-name mode-uri)
 657           (and mode (decode-qname mode env nil))
 658         (lambda (ctx)
 659           (apply-templates/list
 660            (xpath::force
 661             (xpath::sorted-pipe-of (funcall select-thunk ctx)))
 662            :param-bindings
 663            (loop for (name nil value-thunk) in param-bindings
 664               collect (list name (funcall value-thunk ctx)))
 665            :sort-predicate (when sort-predicate-thunk
 666                              (funcall sort-predicate-thunk ctx))
 667            :mode (when mode
 668                    (or (find-mode *stylesheet*
 669                                   mode-local-name
 670                                   mode-uri)
 671                        *empty-mode*))))))))
 672
 673 (define-instruction xsl:apply-imports (args env)
 674   (declare (ignore args env))
 675   (lambda (ctx)
 676     (declare (ignore ctx))
 677     (funcall *apply-imports*)))
 678
 679 (define-instruction xsl:call-template (args env)
 680   (destructuring-bind (name &rest param-binding-specs) args
 681     (let ((param-bindings
 682            (compile-var-bindings param-binding-specs env)))
 683       (multiple-value-bind (local-name uri)
 684           (decode-qname name env nil)
 685         (setf name (cons local-name uri)))
 686       (lambda (ctx)
 687         (call-template ctx name
 688                        (loop for (name nil value-thunk) in param-bindings
 689                           collect (list name (funcall value-thunk ctx))))))))
 690
 691 ;; fixme: incompatible with XSLT 2.0
 692 (define-instruction xsl:document (args env)
 693   (destructuring-bind ((href &key method indent doctype-public doctype-system)
 694                        &body body)
 695       args
 696     (declare (ignore doctype-public doctype-system)) ;fixme
 697     (let ((thunk (compile-instruction `(progn ,@body) env))
 698           (href-thunk (compile-avt href env)))
 699       (lambda (ctx)
 700         (let ((pathname
 701                (uri-to-pathname
 702                 (puri:merge-uris (funcall href-thunk ctx)
 703                                  (xpath-protocol:base-uri
 704                                   (xpath:context-node ctx))))))
 705           (ensure-directories-exist pathname) ;really?
 706           (invoke-with-output-sink
 707            (lambda ()
 708              (funcall thunk ctx))
 709            (make-output-specification :method (or method "XML") :indent indent)
 710            pathname))))))
 711
 712 (defun compile-instruction (form env)
 713   (xslt-trace-thunk
 714    (funcall (or (get (car form) 'xslt-instruction)
 715                 (error "undefined instruction: ~A" (car form)))
 716             (cdr form)
 717             env)
 718    "instruction ~s" (car form)))
 719
 720 ;;: WTF: "A right curly brace inside a Literal in an expression is not
 721 ;;; recognized as terminating the expression."
 722 ;;;
 723 ;;; Da hilft nur tagbody.
 724 (defun parse-attribute-value-template (template-string)
 725   (with-input-from-string (input template-string)
 726     (let ((ordinary (make-string-output-stream))
 727           (xpath (make-string-output-stream))
 728           (tokens '())
 729           (c (read-char input nil :eof)))
 730       (flet ((emit ()
 731                (let ((o (get-output-stream-string ordinary)))
 732                  (when (plusp (length o))
 733                    (push (list :data o) tokens)))
 734                (let ((x (get-output-stream-string xpath)))
 735                  (when (plusp (length x))
 736                    (push (list :xpath x) tokens))))
 737              (collect-ordinary ()
 738                (write-char c ordinary))
 739              (collect-xpath ()
 740                (write-char c xpath)))
 741         (macrolet ((goto (target)
 742                      `(progn
 743                         (setf c (read-char input nil :eof))
 744                         (go ,target))))
 745           (tagbody
 746            ordinary
 747              (case c
 748                (#\{
 749                 (goto seen{))
 750                (#\}
 751                 (goto seen-stray-}))
 752                (:eof
 753                 (go done)))
 754              (collect-ordinary)
 755              (goto ordinary)
 756
 757            seen{
 758              (case c
 759                (#\{
 760                 (collect-ordinary)
 761                 (goto ordinary))
 762                (#\'
 763                 (collect-xpath)
 764                 (goto in-single-quote))
 765                (:eof
 766                 (xslt-error "unexpected end of avt")))
 767              (emit)
 768              (collect-xpath)
 769              (goto xpath)
 770
 771            xpath
 772              (case c
 773                (#\'
 774                 (collect-xpath)
 775                 (goto in-single-quote))
 776                (#\"
 777                 (collect-xpath)
 778                 (goto in-double-quote))
 779                (#\}
 780                 (goto seen-closing-}))
 781                (:eof
 782                 (xslt-error "unexpected end of avt")))
 783              (collect-xpath)
 784              (goto xpath)
 785
 786            in-single-quote
 787              (case c
 788                (#\'
 789                 (collect-xpath)
 790                 (goto xpath))
 791                (:eof
 792                 (xslt-error "unexpected end of avt")))
 793              (collect-xpath)
 794              (goto in-single-quote)
 795
 796            in-double-quote
 797              (case c
 798                (#\"
 799                 (collect-xpath)
 800                 (goto xpath))
 801                (:eof
 802                 (xslt-error "unexpected end of avt")))
 803              (collect-xpath)
 804              (goto in-double-quote)
 805
 806            seen-closing-}
 807              (case c
 808                (#\}
 809                 (emit)
 810                 (goto seen-stray-}))
 811                (#\{
 812                 (emit)
 813                 (goto xpath))
 814                (:eof
 815                 (goto done)))
 816              (emit)
 817              (collect-ordinary)
 818              (goto ordinary)
 819
 820            seen-stray-}
 821              (case c
 822                (#\}
 823                 (collect-ordinary)
 824                 (goto ordinary)))
 825              (xslt-error "unexpected closing brace in avt")
 826
 827            done
 828              (emit))))
 829       (nreverse tokens))))
 830
 831 (defun compile-avt (template-string env)
 832   (let* ((constantp t)
 833          (fns
 834           (mapcar (lambda (x)
 835                     (ecase (car x)
 836                       (:data
 837                        (constantly (second x)))
 838                       (:xpath
 839                        (setf constantp nil)
 840                        (compile-xpath (second x) env))))
 841                   (if template-string
 842                       (parse-attribute-value-template template-string)
 843                       (xslt-error "missing avt")))))
 844     (values (lambda (ctx)
 845               (with-output-to-string (s)
 846                 (dolist (fn fns)
 847                   (write-string (xpath:string-value (funcall fn ctx)) s))))
 848             constantp)))
 849
 850
 851 ;;;; Indentation for slime
 852
 853 (defmacro define-indentation (name (&rest args))
 854   (labels ((collect-variables (list)
 855              (loop
 856                 for sub in list
 857                 append
 858                 (etypecase sub
 859                   (list
 860                    (collect-variables sub))
 861                   (symbol
 862                    (if (eql (mismatch "&" (symbol-name sub)) 1)
 863                        nil
 864                        (list sub)))))))
 865     `(defmacro ,name (,@args)
 866        (declare (ignorable ,@(collect-variables args)))
 867        (error "XSL indentation helper ~A used literally in lisp code"
 868               ',name))))
 869
 870 (define-indentation xsl:element
 871     ((name &key namespace use-attribute-sets) &body body))
 872 (define-indentation xsl:literal-element ((name &optional uri) &body body))
 873 (define-indentation xsl:attribute ((name &key namespace) &body body))
 874 (define-indentation xsl:literal-attribute ((name &optional uri) &body body))
 875 (define-indentation xsl:text (str))
 876 (define-indentation xsl:processing-instruction (name &body body))
 877 (define-indentation xsl:comment (&body body))
 878 (define-indentation xsl:value-of (xpath))
 879 (define-indentation xsl:unescaped-value-of (xpath))
 880 (define-indentation xsl:for-each (select &body decls-and-body))
 881 (define-indentation xsl:message (&body body))
 882 (define-indentation xsl:terminate (&body body))
 883 (define-indentation xsl:apply-templates ((&key select mode) &body decls-and-body))
 884 (define-indentation xsl:call-template (name &rest parameters))
 885 (define-indentation xsl:copy-of (xpath))
 886
 887 ;;;;
 888
 889 (defun test-instruction (form document)
 890   (let ((thunk (compile-instruction form (make-instance 'lexical-environment)))
 891         (root (cxml:parse document (stp:make-builder))))
 892     (with-xml-output (cxml:make-string-sink)
 893       (funcall thunk (xpath:make-context root)))))