test.lisp

   1 ;;; -*- show-trailing-whitespace: t; indent-tabs-mode: nil -*-
   2
   3 ;;; Copyright (c) 2007,2008 David Lichteblau, Ivan Shvedunov.
   4 ;;; All rights reserved.
   5
   6 ;;; Redistribution and use in source and binary forms, with or without
   7 ;;; modification, are permitted provided that the following conditions
   8 ;;; are met:
   9 ;;;
  10 ;;;   * Redistributions of source code must retain the above copyright
  11 ;;;     notice, this list of conditions and the following disclaimer.
  12 ;;;
  13 ;;;   * Redistributions in binary form must reproduce the above
  14 ;;;     copyright notice, this list of conditions and the following
  15 ;;;     disclaimer in the documentation and/or other materials
  16 ;;;     provided with the distribution.
  17 ;;;
  18 ;;; THIS SOFTWARE IS PROVIDED BY THE AUTHOR 'AS IS' AND ANY EXPRESSED
  19 ;;; OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  20 ;;; WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  21 ;;; ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY
  22 ;;; DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  23 ;;; DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE
  24 ;;; GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  25 ;;; INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  26 ;;; WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
  27 ;;; NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  28 ;;; SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29
  30 (in-package :xuriella)
  31
  32 (defparameter *tests-directory*
  33   "/home/david/src/XSLT-testsuite-04/testsuite/TESTS/")
  34
  35 (defclass test-case ()
  36   ((id :initarg :id :accessor test-id)
  37    (category :initarg :category :accessor test-category)
  38    (operation :initarg :operation :accessor test-operation)
  39    (data-pathname :initarg :data-pathname :accessor test-data-pathname)
  40    (stylesheet-pathname :initarg :stylesheet-pathname
  41                         :accessor test-stylesheet-pathname)
  42    (data-pathname-2 :initarg :data-pathname-2 :accessor test-data-pathname-2)
  43    (stylesheet-pathname-2 :initarg :stylesheet-pathname-2
  44                           :accessor test-stylesheet-pathname-2)
  45    (output-pathname :initarg :output-pathname
  46                     :accessor test-official-output-pathname)
  47    (output-compare :initarg :output-compare
  48                    :accessor test-output-compare)))
  49
  50 (defmethod print-object ((object test-case) stream)
  51   (print-unreadable-object (object stream :identity nil :type t)
  52     (format stream "~A ~A/~A"
  53             (test-operation object)
  54             (test-category object)
  55             (test-id object))))
  56
  57
  58 ;;;; SIMPLIFY-TESTS
  59
  60 ;;; Translate catalog.xml into an actually usable katalog.xml
  61 ;;; by running the test cases through xsltproc to see what it thinks
  62 ;;; about them.
  63
  64 (defun simplify-tests (&optional (d *tests-directory*))
  65   (with-open-file (stream (merge-pathnames "katalog.xml" d)
  66                           :direction :output
  67                           :if-exists :supersede
  68                           :element-type '(unsigned-byte 8))
  69     (cxml:with-xml-output (cxml:make-octet-stream-sink stream)
  70       (cxml:with-element "simplified-test-suite"
  71         (klacks:with-open-source
  72             (source (klacks:make-tapping-source
  73                      (cxml:make-source (merge-pathnames "catalog.xml" d))))
  74           (let ((*default-pathname-defaults* (merge-pathnames d)))
  75             (map-original-tests #'simplify-test source)))))))
  76
  77 (defun map-original-tests (run-test source &key (test (constantly t)))
  78   (let ((total 0)
  79         (pass 0)
  80         major-path)
  81     (loop
  82        while (klacks:find-event source :start-element)
  83        for lname = (klacks:current-lname source)
  84        do
  85        (cond
  86          ((equal lname "major-path")
  87           (klacks:skip source :start-element)
  88           (setf major-path
  89                 (namestring
  90                  (merge-pathnames (klacks:consume-characters source)))))
  91          ((equal lname "test-case")
  92           (let* ((<test-case>
  93                   (stp:document-element
  94                    (klacks:serialize-element source (stp:make-builder))))
  95                  (test-case (parse-original-test major-path <test-case>)))
  96             (when (funcall test test-case)
  97               (incf total)
  98               (when (funcall run-test test-case)
  99                 (incf pass)))))
 100          (t
 101           (klacks:skip source :start-element))))
 102     (format t "~&Passed ~D/~D tests.~%" pass total)))
 103
 104 (defun parse-original-test (major-path <test-case>)
 105   (let* ((file-path
 106           (stp:string-value
 107            (stp:find-recursively-if (stp:of-name "file-path") <test-case>)))
 108          (base (concatenate 'string major-path "/" file-path))
 109          (out-base (concatenate 'string major-path "/REF_OUT/" file-path))
 110          (scenario
 111           (stp:find-recursively-if (stp:of-name "scenario") <test-case>))
 112          data
 113          stylesheet
 114          supplemental-stylesheet
 115          supplemental-data
 116          output
 117          compare)
 118     (dolist (<input> (stp:filter-recursively (stp:of-name "input-file")
 119                                              <test-case>))
 120       (let ((role (stp:attribute-value <input> "role"))
 121             (path (concatenate 'string base "/" (stp:string-value <input>))))
 122         (cond
 123           ((equal role "principal-data")
 124            (setf data path))
 125           ((equal role "principal-stylesheet")
 126            (setf stylesheet path))
 127           ((equal role "supplemental-stylesheet")
 128            (setf supplemental-stylesheet path))
 129           ((equal role "supplemental-data")
 130            (setf supplemental-data path))
 131           (t
 132            (error "unrecognized role: ~A" role)))))
 133     (dolist (<output> (stp:filter-recursively (stp:of-name "output-file")
 134                                             <test-case>))
 135       (let ((role (stp:attribute-value <output> "role"))
 136             (path (concatenate 'string out-base
 137                                "/"
 138                                (stp:string-value <output>))))
 139         (cond
 140           ((equal role "principal")
 141            (setf output path)
 142            (setf compare (stp:attribute-value <output> "compare")))
 143           (t
 144            (error "unrecognized role: ~A" role)))))
 145     (make-instance 'test-case
 146                    :id (stp:attribute-value <test-case> "id")
 147                    :category (stp:attribute-value <test-case> "category")
 148                    :operation (stp:attribute-value scenario "operation")
 149                    :data-pathname data
 150                    :stylesheet-pathname stylesheet
 151                    :stylesheet-pathname-2 supplemental-stylesheet
 152                    :data-pathname-2 supplemental-data
 153                    :output-pathname output
 154                    :output-compare compare)))
 155
 156 (defun write-simplified-test (test-case operation)
 157   (cxml:with-element "test-case"
 158     (cxml:attribute "id" (test-id test-case))
 159     (cxml:attribute "category" (test-category test-case))
 160     (flet ((p (l p)
 161              (cxml:attribute l (and p (namestring p)))))
 162       (p "data" (test-data-pathname test-case))
 163       (p "stylesheet" (noindent-stylesheet-pathname test-case))
 164       (p "data-2" (test-data-pathname-2 test-case))
 165       (p "stylesheet-2" (test-stylesheet-pathname-2 test-case))
 166       (p "output" (test-official-output-pathname test-case))
 167       (p "compare" (test-output-compare test-case)))
 168     (cxml:attribute "operation" operation)))
 169
 170 (defun test-output-pathname (test type)
 171   (make-pathname :name (test-id test)
 172                  :type type
 173                  :defaults (test-data-pathname test)))
 174
 175 (defun sanitize-stylesheet (in out)
 176   (if (probe-file in)
 177       (handler-case
 178           (let ((d (cxml:parse (pathname in) (stp:make-builder))))
 179             (xpath:with-namespaces ((nil #.*xsl*))
 180               (xpath:do-node-set (output (xpath:evaluate "//output" d))
 181                 (let ((a (stp:find-attribute-named output "indent")))
 182                   (when a
 183                     (stp:detach a)))))
 184             (with-open-file (s out
 185                                :direction :output
 186                                :if-exists :rename-and-delete
 187                                :element-type '(unsigned-byte 8))
 188               (stp:serialize d (cxml:make-octet-stream-sink s))))
 189         (error (c)
 190           (warn "ignoring bogus stylesheet ~A: ~A" in c)
 191           (copy-file in out)))
 192       (warn "oops, ignoring missing stylesheet: ~A" in)))
 193
 194 (defun noindent-stylesheet-pathname (test-case)
 195   (make-pathname :type "noindent-xsl"
 196                  :defaults (test-stylesheet-pathname test-case)))
 197
 198 (defun simplify-test (test-case)
 199   (flet ((report (status &optional (fmt "") &rest args)
 200            (format t "~&~A ~A [~A]~?~%"
 201                    status
 202                    (test-id test-case)
 203                    (test-category test-case)
 204                    fmt
 205                    args)))
 206     (let* ((data (test-data-pathname test-case))
 207            (stylesheet (test-stylesheet-pathname test-case))
 208            (noindent-stylesheet (noindent-stylesheet-pathname test-case))
 209            #+xuriella::xsltproc
 210            (out (test-output-pathname test-case "xsltproc"))
 211            (saxon-out (test-output-pathname test-case "saxon")))
 212       (sanitize-stylesheet stylesheet noindent-stylesheet)
 213       (if (equal (test-operation test-case) "standard")
 214           (handler-case
 215               (progn
 216                 #+xuriella::xsltproc (xsltproc noindent-stylesheet data out)
 217                 (saxon noindent-stylesheet data saxon-out)
 218                 (report "PASS")
 219                 (write-simplified-test test-case "standard")
 220                 t)
 221             (error (c)
 222               (report "FAIL" ": ~A" c)
 223               (write-simplified-test test-case "execution-error")
 224               nil))
 225           (handler-case
 226               (progn
 227                 #+xuriella::xsltproc
 228                 (xsltproc noindent-stylesheet data "/dev/null")
 229                 (saxon noindent-stylesheet data "/dev/null")
 230                 (report "FAIL" ": expected error not signalled")
 231                 ;; let's ignore unexpected successes for now
 232                 nil)
 233             (error (c)
 234               (report "PASS" ": expected error ~A" c)
 235               (write-simplified-test test-case "execution-error")
 236               t))))))
 237
 238 (defun xsltproc (stylesheet input output)
 239   (flet ((full-namestring (x)
 240            (namestring (merge-pathnames x))))
 241     (let* ((asdf::*verbose-out* (make-string-output-stream))
 242            (code (asdf:run-shell-command
 243                   "cd ~S && xsltproc ~S ~S >~S"
 244                   (full-namestring "")
 245                   (full-namestring stylesheet)
 246                   (full-namestring input)
 247                   (full-namestring output))))
 248       (unless (zerop code)
 249         (error "running xsltproc failed with code ~A [~%~A~%]"
 250                code
 251                (get-output-stream-string asdf::*verbose-out*))))))
 252
 253 (defun saxon (stylesheet input output)
 254   (flet ((full-namestring (x)
 255            (namestring (merge-pathnames x))))
 256     (let* ((asdf::*verbose-out* (make-string-output-stream))
 257            (code (asdf:run-shell-command
 258                   "cd ~S && java -jar /usr/share/java/saxon.jar ~S ~S >~S"
 259                   (full-namestring "")
 260                   (full-namestring input)
 261                   (full-namestring stylesheet)
 262                   (full-namestring output))))
 263       (unless (zerop code)
 264         (error "running saxon failed with code ~A [~%~A~%]"
 265                code
 266                (get-output-stream-string asdf::*verbose-out*))))))
 267
 268
 269 ;;;; RUN-TESTS and DRIBBLE-TESTS
 270
 271 ;;; Process katalog.xml
 272
 273 (defun dribble-tests
 274     (&key filter (directory *tests-directory*) (file "TEST"))
 275   (let ((*package* (find-package 'cl-user))
 276         (*print-circle* nil))
 277     (with-open-file (dribble
 278                      (merge-pathnames file
 279                                       (slot-value (asdf:find-system :xuriella)
 280                                                   'asdf::relative-pathname))
 281                      :direction :output
 282                      :if-exists :supersede
 283                      :external-format :utf-8)
 284       (let* ((dribble (make-broadcast-stream dribble *standard-output*))
 285              (*standard-output* dribble)
 286              (*trace-output* dribble)
 287              (*error-output* dribble)
 288              (*terminal-io* (make-two-way-stream *standard-input* dribble)))
 289         (handler-bind ((warning
 290                         (lambda (c)
 291                           (warn "~A" (replace-junk (princ-to-string c)))
 292                           (muffle-warning c))))
 293           (run-tests :filter filter
 294                      :directory directory))))))
 295
 296 (defparameter *bad-tests*
 297   '(;; Inconsistent tests:
 298     ;;
 299     ;; Some tests wants us to recover from this error, yet this one doesn't:
 300     "copy_copy61"
 301     "copy_copy62"
 302
 303     ;; Should we fix this?
 304     ;;
 305     ;; We signal a run-time error when and if it's actually used.  The test
 306     ;; wants a compilation-time error...
 307     "AttributeSets_RefToUndefinedAttributeSet"
 308
 309     ;; We would pass this:
 310     ;;
 311     ;; We perform recovery, but saxon doesn't.  Recovery results in non-XML
 312     ;; output, which we can't parse for comparison against the official
 313     ;; test case.
 314     "output_output75"
 315     ;;
 316     ;; we'd pass these tests, but the test authors forgot to declare the
 317     ;; entity they're writing, so we can't parse it for comparison.
 318     "output_output06"
 319     "output_output10"
 320     "output_output61"
 321     ;;
 322     ;; another similar test where the output is unparsable, except that
 323     ;; here an entity declaration wouldn't have helped either:
 324     "Copying_ResultTreeFragmentWithEscapedText"
 325
 326     ;; Broken test:
 327     ;;
 328     ;; Input document isn't ns-wf.
 329     ;;
 330     ;; FIXME: Tweak the test suite driver to consider a test a success
 331     ;; if Saxon fails and the input isn't well-formed, since that's what
 332     ;; the tests are probably meant to assert.  Or signal an XSLT-ERROR
 333     ;; in this situation after all?
 334     ;;
 335     "Attributes__78387"
 336     "Miscellaneous__84001"
 337     "Namespace_XPath_Conflict_XPath_XSLT"
 338     "Namespace_XPath_DefaultNamespace"
 339     "Namespace_XPath_NavigatorMethods"
 340     "Namespace_XPath_PredefinedPrefix_XMLNS"
 341     "Namespace_XPath_SameQuery_DiffNamespace"
 342     "Namespace_XPath_ScopingRules"
 343
 344     ;;
 345     ;; Someone commented out most of this test...
 346     "BVTs_bvt045"
 347
 348     ;; FIXME: should re-enable these at some point:
 349     ;;
 350     ;; the following tests take a lot of time due to the problems of current matching algorithm:
 351     "impincl_impincl16"
 352     ;; probably the same problem (but I haven't checked):
 353     "Import__91164"
 354
 355     ;; stack exhaustion -- matching problem i think
 356     "Keys_PerfRepro3"
 357
 358     ;; test stylesheet doesn't exist?!
 359     "ConflictResolution__77833"
 360     "Include__77736"
 361
 362     ;; these test the value of generate-id(), which isn't specified
 363     "Keys__91832"
 364     "Keys__91833"))
 365
 366 ;; Tests where the output isn't a match because of extraneous whitespace.
 367 ;; For these tests, we force space normalization before comparing.
 368 ;;
 369 ;; Possible reasons for this problem are:
 370 ;;   a. The output method is declared in an imported stylesheet.
 371 ;;      SANITIZE-STYLESHEET is supposed to get rid of indent="yes", but it
 372 ;;      misses imported stylesheets.
 373 ;;   b. Saxon output isn't a match, but the official output is.
 374 ;;      But the official output is unaffected by SANITIZE-STYLESHEET.
 375 ;;
 376 (defparameter *whitespace-issues*
 377   (cl-ppcre:create-scanner
 378    "(?smx)
 379     ^(BVTs_bvt044$
 380        |Namespace-alias__91782$
 381        |AttributeSets__91038$
 382        |BVTs_bvt041$
 383        |BVTs_bvt042$
 384        |BVTs_bvt054$
 385        |BVTs_bvt058$
 386        |Import__
 387        |Include__
 388        )"))
 389
 390 (defparameter *known-failures*
 391   '(
 392     ;; uses EBCDIC-CP-IT (whatever that is), but Babel's only got EBCDIC-US.
 393     ;; Doesn't actually test any differences between the two, so it's
 394     ;; probably just there to annoy us.
 395     "output_output22"
 396
 397     ;; uses KOI, which Babel doesn't support
 398     "BVTs_bvt019"
 399
 400     ;; shift_jis
 401     "Include__77515"
 402
 403     ;; FIXME?
 404     ;;
 405     ;; This is an HTML output method issue.  The spec says the HTML
 406     ;; output method should output elements with a null namespace URI as
 407     ;; HTML, and if their name isn't recognized, as an inline element.
 408     ;; <xml> here is such an element.  It has an attribute with a
 409     ;; namespace though, and the spec doesn't say what we should do with that
 410     ;; attribute.  We currently output it using Closure HTML, and
 411     ;; lose its namespace.  This test wants the attribute and its
 412     ;; namespace to survive.
 413     "BVTs_bvt054"))
 414
 415 (defun run-tests (&key filter (directory *tests-directory*))
 416   (when (typep filter '(or string cons))
 417     (setf filter (cl-ppcre:create-scanner filter)))
 418   (klacks:with-open-source
 419       (source (klacks:make-tapping-source
 420                (cxml:make-source (merge-pathnames "katalog.xml" directory))))
 421     (let ((*default-pathname-defaults* (merge-pathnames directory)))
 422       (map-tests #'run-test
 423                  source
 424                  :test (lambda (test)
 425                          (and (or (null filter)
 426                                   (cl-ppcre:all-matches
 427                                    filter
 428                                    (format nil "~A/~A"
 429                                            (test-category test)
 430                                            (test-id test))))
 431                               (not (find (test-id test)
 432                                          *bad-tests*
 433                                          :test #'equal))))))))
 434
 435 (defun run-named-test (name &optional (d *tests-directory*))
 436   (let ((*break-on-signals*
 437          '(and error (not babel-encodings:character-encoding-error))))
 438     (run-tests :filter (format nil "/~A$" name) :directory d)))
 439
 440 (defun copy-file (p q)
 441   (with-open-file (in p :element-type '(unsigned-byte 8))
 442     (with-open-file (out q
 443                          :element-type '(unsigned-byte 8)
 444                          :direction :output
 445                          :if-exists :rename-and-delete)
 446       (let ((buf (make-array 8192 :element-type '(unsigned-byte 8))))
 447         (loop for pos = (read-sequence buf in)
 448            until (zerop pos)
 449            do (write-sequence buf out :end pos))))))
 450
 451 (defun find-named-test (name &optional (d *tests-directory*))
 452   (klacks:with-open-source
 453       (source (klacks:make-tapping-source
 454                (cxml:make-source (merge-pathnames "katalog.xml" d))))
 455     (block nil
 456       (map-tests (lambda (test)
 457                    (return test))
 458                  source
 459                  :test (lambda (test) (equal (test-id test) name))))))
 460
 461 (defun copy-test-files (name &optional (d *tests-directory*))
 462   (let* ((test (find-named-test name d))
 463          (*default-pathname-defaults* (merge-pathnames d))
 464          (*break-on-signals*
 465           '(and error (not babel-encodings:character-encoding-error)))
 466          (target-dir (merge-pathnames "copied-test/"
 467                                       (asdf:component-pathname
 468                                        (asdf:find-system :xuriella))))
 469          (xsl (merge-pathnames "test.xsl" target-dir))
 470          (xml (merge-pathnames "test.xml" target-dir))
 471          (txt (merge-pathnames "official-output.txt" target-dir))
 472          (expected (merge-pathnames "expected.xml" target-dir))
 473          (actual (merge-pathnames "actual.xml" target-dir)))
 474     (ensure-directories-exist target-dir)
 475     (copy-file (test-stylesheet-pathname test) xsl)
 476     (copy-file (test-data-pathname test) xml)
 477     (when (test-official-output-pathname test)
 478       (copy-file (test-official-output-pathname test) txt))
 479     (format t "Test stylesheet copied to:~%  ~A~%~%" xsl)
 480     (format t "Test data copied to:~%  ~A~%~%" xml)
 481     (when (test-official-output-pathname test)
 482       (format t "Official output file:~%  ~A~%~%" txt))
 483     (format t "Run xsltproc like this:~%  cd ~A~%  xsltproc ~A ~A >~A~%~%"
 484             (namestring target-dir)
 485             (enough-namestring xsl target-dir)
 486             (enough-namestring xml target-dir)
 487             (enough-namestring expected target-dir))
 488     (format t "Run saxon like this:~%  cd ~A~%  java -jar /usr/share/java/saxon.jar ~A ~A >~A~%~%"
 489             (namestring target-dir)
 490             (enough-namestring xml target-dir)
 491             (enough-namestring xsl target-dir)
 492             (enough-namestring expected target-dir))
 493     (format t "Run MSXSL like this:~%  cd ~A~%  wine msxsl.exe ~A ~A >~A~%~%"
 494             (namestring target-dir)
 495             (enough-namestring xml target-dir)
 496             (enough-namestring xsl target-dir)
 497             (enough-namestring expected target-dir))
 498     (format t "Run xuriella like this:~%")
 499     `(apply-stylesheet ,xsl ,xml :output ,actual)))
 500
 501 (defun map-tests (run-test source &key (test (constantly t)))
 502   (let ((total 0)
 503         (pass 0)
 504         (known 0))
 505     (loop
 506        while (klacks:find-event source :start-element)
 507        for lname = (klacks:current-lname source)
 508        do
 509        (cond
 510          ((equal lname "test-case")
 511           (let* ((<test-case>
 512                   (stp:document-element
 513                    (klacks:serialize-element source (stp:make-builder))))
 514                  (test-case (parse-test <test-case>)))
 515             (when (funcall test test-case)
 516               (incf total)
 517               (ecase (funcall run-test test-case)
 518                 ((nil))
 519                 ((t)
 520                  (incf pass))
 521                 (:known-failure
 522                  (incf known))))))
 523          (t
 524           (klacks:skip source :start-element))))
 525     (format t "~&Passed ~D/~D tests (~D expected failures, ~D unexpected failures).~%"
 526             pass total known (- total pass known))))
 527
 528 (defun parse-test (<test-case>)
 529   (stp:with-attributes (id category operation
 530                            data stylesheet data-2 stylesheet-2
 531                            output compare)
 532       <test-case>
 533     (make-instance 'test-case
 534                    :id id
 535                    :category category
 536                    :operation operation
 537                    :data-pathname data
 538                    :stylesheet-pathname stylesheet
 539                    :data-pathname-2 data-2
 540                    :stylesheet-pathname-2 stylesheet-2
 541                    :output-pathname output
 542                    :output-compare compare)))
 543
 544 ;; read from file P, skipping the XMLDecl or TextDecl and Doctype at the
 545 ;; beginning, if any.
 546 (defun slurp-for-comparison (p)
 547   (with-open-file (s p :element-type '(unsigned-byte 8))
 548     (unless (and (eql (read-byte s nil) #xef)
 549                  (eql (read-byte s nil) #xbb)
 550                  (eql (read-byte s nil) #xbf))
 551       (file-position s 0))
 552     (if (plusp (file-length s))
 553         (slurp-for-comparison-1 p s t)
 554         "<wrapper/>")))
 555
 556 (defun slurp-for-comparison-1 (p s junk-info)
 557   (let ((pos (file-position s))         ;for UTF-8 "BOM"
 558         (xstream (runes:make-xstream s :speed 1))
 559         (prev-pos 0))
 560     (setf (runes:xstream-name xstream)
 561           (cxml::make-stream-name
 562            :entity-name "main document"
 563            :entity-kind :main
 564            :uri (cxml::pathname-to-uri (merge-pathnames p))))
 565     (let ((source
 566            (flet ((er (pub sys)
 567                     pub sys
 568                     (flexi-streams:make-in-memory-input-stream
 569                      #())))
 570              (cxml:make-source xstream
 571                                :pathname p
 572                                :entity-resolver #'er))))
 573       (unless (eq junk-info :nada)
 574         (loop
 575            for key = (progn
 576                        (setf prev-pos (runes:xstream-position xstream))
 577                        (klacks:peek-next source))
 578            until (eq key :start-document))
 579         (cxml::with-source (source cxml::context)
 580           (when (eq (cxml::zstream-token-category
 581                      (cxml::main-zstream cxml::context))
 582                     :NMTOKEN)
 583             ;; oops, doesn't look like XML at all
 584             (file-position s pos)
 585             (return-from slurp-for-comparison-1
 586               (slurp-for-comparison-1 p s :nada)))))
 587       (etypecase junk-info
 588         (integer
 589          (dotimes (x junk-info)
 590            (setf prev-pos (runes:xstream-position xstream))
 591            (klacks:peek-next source)))
 592         ((eql t)
 593          (let ((nskip 0))
 594            (handler-case
 595                (loop
 596                   (case (klacks:peek-next source)
 597                     (:start-element (return))
 598                     (:characters
 599                      (if (whitespacep (klacks:current-characters source))
 600                          (incf nskip)
 601                          (return)))
 602                     (t
 603                      (incf nskip))))
 604              ((or file-error cxml:xml-parse-error) ()
 605                (when (zerop nskip)
 606                  (setf nskip nil))))
 607            ;; retry
 608            (with-open-file (u p :element-type '(unsigned-byte 8))
 609              (file-position u pos)
 610              (return-from slurp-for-comparison-1
 611                (slurp-for-comparison-1 p u nskip)))))
 612         ((member nil :nada)))
 613       (with-output-to-string (r)
 614         (let* ((seen-char
 615                 (cxml::with-source (source cxml::context)
 616                   (ecase (cxml::zstream-token-category
 617                           (cxml::main-zstream cxml::context))
 618                     (:seen-< #\<)
 619                     (:? #\?)
 620                     ((nil :s)
 621                      (setf prev-pos (runes:xstream-position xstream))
 622                      nil))))
 623                (off-by-one-p (or seen-char (eq junk-info :nada)))
 624                (new-pos (- prev-pos (if off-by-one-p 1 0))))
 625           ;; copy doctype over
 626           (with-open-file (u p :element-type '(unsigned-byte 8))
 627             (file-position u pos)
 628             (let ((y (runes:make-xstream u :speed 1)))
 629               (loop
 630                  while (< (runes:xstream-position y) new-pos)
 631                  do (write-char (runes:read-rune y) r))))
 632           (write-line "<wrapper>" r)
 633           (when seen-char
 634             (write-char seen-char r)))
 635         (loop
 636            for char = (runes:read-rune xstream)
 637            until (eq char :eof)
 638            do (write-char char r))
 639         (write-line "</wrapper>" r)))))
 640
 641 (defun parse-for-comparison (p)
 642   (let* ((d (flet ((er (pub sys)
 643                     pub sys
 644                     (flexi-streams:make-in-memory-input-stream
 645                      #())))
 646               (cxml:parse (slurp-for-comparison p)
 647                           (make-text-normalizer (stp:make-builder))
 648                           :entity-resolver #'er)))
 649          (de (stp:document-element d)))
 650     (let ((first (stp:first-child de)))
 651       (when (typep first 'stp:text)
 652         (cond
 653           ((whitespacep (stp:data first))
 654            (stp:delete-child first de))
 655           (t
 656            (setf (stp:data first)
 657                  (cl-ppcre:regex-replace #.(format nil "^[~A]+" *whitespace*)
 658                                          (stp:data first)
 659                                          ""))))))
 660     (let ((last (stp:last-child de)))
 661       (when (typep last 'stp:text)
 662         (cond
 663           ((whitespacep (stp:data last))
 664            (stp:delete-child last de))
 665           (t
 666            (setf (stp:data last)
 667                  (cl-ppcre:regex-replace #.(format nil "[~A]+$" *whitespace*)
 668                                          (stp:data last)
 669                                          ""))))))
 670     d))
 671
 672 (defun output-equal-p (compare p q &key normalize)
 673   (handler-case
 674       (ecase compare
 675         (:xml (xml-output-equal-p p q normalize))
 676         (:html (html-output-equal-p p q))
 677         (:text (text-output-equal-p p q)))
 678     ((or error parse-number::invalid-number) (c)
 679       (warn "comparison failed: ~A" c)
 680       nil)))
 681
 682 ;; Workaround for namespace_namespace23 and other tests:
 683 ;;  - For these tests, saxon and msxsl output a declaration for the XSL
 684 ;;    namespace without using that declaration.
 685 ;;  - I think saxon and msxsl are both wrong.
 686 ;;  - The official test output agrees with my assessment.
 687 ;;    (So does libxslt, but that's not to be trusted. :-))
 688 ;;  - Here's the catch: The official test output is broken in its whitespace
 689 ;;    handling.
 690 ;; So let's normalize spaces in test output that looks like an XSLT
 691 ;; stylesheet, allowing us to pass these tests using the official test output.
 692 (defun maybe-normalize-test-spaces (wrapper force)
 693   (let ((i 0))
 694     (loop while (< i (length (cxml-stp-impl::%children wrapper))) do
 695          (let ((wrapper-child (stp:nth-child i wrapper)))
 696            (cond
 697              ((not (typep wrapper-child 'stp:element))
 698               (if force
 699                   (stp:delete-nth-child i wrapper)
 700                   (incf i)))
 701              ((or (equal (stp:namespace-uri wrapper-child) *xsl*)
 702                   force)
 703               (strip-stylesheet wrapper-child)
 704               (labels ((recurse (e &optional preserve)
 705                          (stp:do-children (child e)
 706                            (typecase child
 707                              (stp:text
 708                               (setf (stp:data child)
 709                                     (normalize-whitespace (stp:data child))))
 710                              (stp:element
 711                                  (stp:with-attributes ((space "space" *xml*))
 712                                      child
 713                                    (let ((new-preserve
 714                                           (cond
 715                                             ((namep child "text") t)
 716                                             ((not space) preserve)
 717                                             ((equal space "preserve") t)
 718                                             (t nil))))
 719                                      (recurse child new-preserve))))))))
 720                 (recurse wrapper-child))
 721               (incf i))
 722              (t
 723               (incf i)))))))
 724
 725 (defun xml-output-equal-p (p q normalize)
 726   (let ((r (parse-for-comparison p))
 727         (s (parse-for-comparison q)))
 728     (maybe-normalize-test-spaces (stp:document-element r) normalize)
 729     (maybe-normalize-test-spaces (stp:document-element s) normalize)
 730     (and (let ((u (stp:document-type r))
 731                (v (stp:document-type s)))
 732            (if u
 733                (and v (node= u v))
 734                (null v)))
 735          (node= (stp:document-element r) (stp:document-element s)))))
 736
 737 ;; FIXME: don't do this in <pre> etc.
 738 (defun normalize-html-whitespace (node)
 739   (when (typep node 'stp:parent-node)
 740     ;; ignore newlines after start tags completely
 741     (let ((first (stp:first-child node)))
 742       (when (and (typep first 'stp:text)
 743                  (alexandria:starts-with #\newline (stp:data first)))
 744         (setf (stp:data first) (subseq (stp:data first) 1))))
 745     ;; ignore newlines before end tags completely
 746     (let ((last (stp:last-child node)))
 747       (when (and (typep last 'stp:text)
 748                  (alexandria:ends-with #\newline (stp:data last)))
 749         (setf (stp:data last)
 750               (subseq (stp:data last) 0 (length (stp:data last))))))
 751     ;; normalize sequences of whitespace
 752     (stp:do-children (child node)
 753       (if (typep child 'stp:text)
 754           (setf (stp:data child)
 755                 (let ((str (normalize-whitespace (stp:data child))))
 756                   (when
 757                       ;; FIXME!  Here we remove whitespace entirely.
 758                       ;; Totally incorrect, but I don't see how we could
 759                       ;; watch Saxon's output otherwise.
 760                       (equal str " ")
 761                     (setf str ""))
 762                   str))
 763           (normalize-html-whitespace child)))
 764     ;; just to be sure, join adjacent nodes
 765     (cxml-stp-impl::normalize-text-nodes! node)))
 766
 767 ;; FIXME: this check is too lenient, because chtml is an error-correcting
 768 ;; parser.
 769 (defun html-output-equal-p (p q)
 770   (let ((r (chtml:parse (pathname p) (stp:make-builder)))
 771         (s (chtml:parse (pathname q) (stp:make-builder))))
 772     (normalize-html-whitespace r)
 773     (normalize-html-whitespace s)
 774     (flet ((fix-case (node)
 775              (xpath:with-namespaces (("xhtml" "http://www.w3.org/1999/xhtml"))
 776                (xpath:do-node-set
 777                    (content (xpath:evaluate "//xhtml:meta/@content" node))
 778                  (setf (stp:value content)
 779                        (string-downcase (stp:value content)))))))
 780       (fix-case r)
 781       (fix-case s))
 782     (node= (stp:document-element r) (stp:document-element s))))
 783
 784 (defun text-output-equal-p (p q)
 785   (with-open-file (a p :element-type '(unsigned-byte 8))
 786     (with-open-file (b q :element-type '(unsigned-byte 8))
 787       (let ((len (file-length a)))
 788         (and (eql len (file-length b))
 789              (let ((d (make-array len :element-type '(unsigned-byte 8)))
 790                    (e (make-array len :element-type '(unsigned-byte 8))))
 791                (read-sequence d a)
 792                (read-sequence e b)
 793                (equalp d e)))))))
 794
 795 (defun strip-addresses (str)
 796   (cl-ppcre:regex-replace-all "{[0-9a-fA-F]+}\\>" str "{xxxxxxxx}>"))
 797
 798 (defun slurp-output-method (p)
 799   (xpath:with-namespaces ((nil #.*xsl*))
 800     (let* ((d (handler-bind
 801                   ((warning #'muffle-warning))
 802                 (cxml:parse (pathname p) (stp:make-builder))))
 803            (output (xpath:first-node (xpath:evaluate "//output" d))))
 804       (if output
 805           (let ((method (stp:attribute-value output "method")))
 806             (if method
 807                 (intern (string-upcase method) :keyword)
 808                 :xml))
 809           :xml))))
 810
 811 (defun replace-junk (str)
 812   (cl-ppcre:regex-replace-all
 813    `(:group ,(namestring *tests-directory*))
 814    (map 'string
 815         (lambda (c)
 816           (if (or (eql c #\newline) (<= 32 (char-code c) 126))
 817               c
 818               #\?))
 819         str)
 820    "..."))
 821
 822 (defun run-test (test)
 823   (let ((expected-saxon (test-output-pathname test "saxon"))
 824         #+xuriella::xsltproc
 825         (expected-xsltproc (test-output-pathname test "xsltproc"))
 826         (actual (test-output-pathname test "xuriella"))
 827         (official (test-official-output-pathname test))
 828         (force-normalization
 829          (cl-ppcre:all-matches *whitespace-issues* (test-id test)))
 830         (output-method nil))
 831     (handler-bind ((|hey test suite, this is an HTML document|
 832                     (lambda (c)
 833                       (declare (ignore c))
 834                       (setf output-method :html))))
 835       (labels ((uri-resolver (uri)
 836                  (let ((str (puri:render-uri uri nil)))
 837                    (cond
 838                      ((search "%5c%5c%5c%5cwebxtest%5c%5cmanagedshadow%5c%5cmanaged_b2%5c%5ctestdata%5c%5cxslt%5c%5celement%5c%5cxslt_element_NSShared.xml"
 839                               str)
 840                       (cxml::pathname-to-uri
 841                        (merge-pathnames
 842                         "MSFT_Conformance_Tests/Elements/xslt_element_NSShared.xml"
 843                         *tests-directory*)))
 844                      ((search "webxtest/testcases/91156a.xsl" str)
 845                       (cxml::pathname-to-uri
 846                        (merge-pathnames
 847                         "MSFT_Conformance_Tests/Import/91156a.xsl"
 848                         *tests-directory*)))
 849                      (t
 850                       uri))))
 851                (doit ()
 852                  (with-open-file (s actual
 853                                     :if-exists :rename-and-delete
 854                                     :direction :output
 855                                     :element-type '(unsigned-byte 8))
 856                    (handler-bind ((xslt-error
 857                                    (lambda (c)
 858                                      (declare (ignore c))
 859                                      (when (find-restart 'recover)
 860                                        (invoke-restart 'recover)))))
 861                      (apply-stylesheet (pathname (test-stylesheet-pathname test))
 862                                        (let ((p (test-data-pathname test)))
 863                                          (if (search "Elements/Plants.xml" p)
 864                                              (merge-pathnames
 865                                               "MSFT_Conformance_Tests/Elements/plants.xml"
 866                                               *tests-directory*)
 867                                              (pathname p)))
 868                                        :output s
 869                                        :uri-resolver #'uri-resolver))))
 870                (pp (label pathname)
 871                  (when pathname
 872                    (format t "  ~A: ~A~%"
 873                            label
 874                            (enough-namestring pathname *tests-directory*))))
 875                (report (ok &optional (fmt "") &rest args)
 876                  (write-string
 877                   (replace-junk
 878                    (strip-addresses
 879                     (format nil "~&~A ~A [~A]~?~%"
 880                             (cond
 881                               (ok "PASS")
 882                               ((find (test-id test)
 883                                      *known-failures*
 884                                      :test #'equal)
 885                                (setf ok :known-failure)
 886                                "KNOWNFAIL")
 887                               (t
 888                                "FAIL"))
 889                             (test-id test)
 890                             (test-category test)
 891                             fmt
 892                             args))))
 893                  (pp "Stylesheet" (test-stylesheet-pathname test))
 894                  (pp "Data" (test-data-pathname test))
 895                  (pp "Supplemental stylesheet"
 896                      (test-stylesheet-pathname-2 test))
 897                  (pp "Supplemental data" (test-data-pathname-2 test))
 898                  (pp "Expected output (1)" expected-saxon)
 899                  #+xuriella::xsltproc
 900                  (pp "Expected output (2)" expected-xsltproc)
 901                  (pp "Actual output" actual)
 902                  (terpri)
 903                  ok))
 904         (cond
 905           ((equal (test-operation test) "standard")
 906            (handler-case
 907                (progn
 908                  (when (find (test-id test)
 909                              nil ;;'("axes_axes47" "attribset_attribset20")
 910                              :test #'equal)
 911                    (error "skipping problematic test"))
 912                  (doit)
 913                  (let* ((output-method
 914                          (or output-method
 915                              (slurp-output-method
 916                               (test-stylesheet-pathname test))))
 917                         (saxon-matches-p
 918                          (output-equal-p output-method
 919                                          expected-saxon
 920                                          actual
 921                                          :normalize force-normalization))
 922                         #+xuriella::xsltproc
 923                         (xsltproc-matches-p
 924                          (output-equal-p output-method
 925                                          expected-xsltproc
 926                                          actual))
 927                         (official-matches-p
 928                          (output-equal-p output-method
 929                                          official
 930                                          actual
 931                                          :normalize force-normalization)))
 932                    (cond
 933                      ((or saxon-matches-p
 934                           #+xuriella::xsltproc xsltproc-matches-p
 935                           official-matches-p)
 936                       (report t)
 937                       #+xuriella::xsltproc
 938                       (report t ": saxon ~A, xsltproc ~A~:[~; (MISMATCH)~]"
 939                               saxon-matches-p
 940                               xsltproc-matches-p
 941                               (if saxon-matches-p
 942                                   (not xsltproc-matches-p)
 943                                   xsltproc-matches-p)))
 944                      (t
 945                       (report nil ": output doesn't match")))))
 946              ((or error parse-number::invalid-number) (c)
 947                (report nil ": ~A" c))))
 948           (t
 949            (handler-case
 950                (doit)
 951              (xslt-error (c)
 952                (report t ": raised an xslt-error as expected" c))
 953              ((or error parse-number::invalid-number) (c)
 954                (report nil ": condition of incorrect type: ~%~A" c))
 955              (:no-error (result)
 956                (cond
 957                  ((not (and official (probe-file official)))
 958                   (report nil ": expected error not signalled: " result))
 959                  ((output-equal-p
 960                    (or output-method
 961                        (slurp-output-method (test-stylesheet-pathname test)))
 962                    official
 963                    actual
 964                    :normalize force-normalization)
 965                   (report t))
 966                  (t
 967                   (report nil ": saxon error not signalled and official output not a match")))))))))))
 968
 969 (defun run-xpath-tests ()
 970   (run-tests :filter "XPath-Expression/|XSLT-Data-Model/"))
 971
 972
 973 ;;;; from cxml-stp-test
 974
 975 (defun assert-node= (a b)
 976   (unless (node= a b)
 977     (error "assertion failed: ~S and ~S are not NODE=" a b)))
 978
 979 (defun child-count (node)
 980   (stp:count-children-if (constantly t) node))
 981
 982 (defun named-node-= (a b)
 983   (and (equal (stp:namespace-uri a) (stp:namespace-uri b))
 984        ;; (equal (stp:namespace-prefix a) (stp:namespace-prefix b))
 985        (equal (stp:local-name a) (stp:local-name b))))
 986
 987 (defun parent-node-= (e f)
 988   (and (eql (child-count e)
 989             (child-count f))
 990        (every #'node= (stp:list-children e) (stp:list-children f))))
 991
 992 (defmethod node= ((e stp:element) (f stp:element))
 993   (and (named-node-= e f)
 994        (parent-node-= e f)
 995        (null
 996         (set-exclusive-or (stp:list-attributes e) (stp:list-attributes f)
 997                           :test #'node=))
 998        (block nil
 999          (flet ((check-namespaces (a b)
1000                   (let ((result ()))
1001                     (stp:map-extra-namespaces
1002                      (lambda (k v)
1003                        (unless (equal v (stp:find-namespace k b))
1004                          (return nil)))
1005                      a)
1006                     result)))
1007            (check-namespaces e f)
1008            (check-namespaces f e))
1009          t)))
1010
1011 (defmethod node= ((a stp:node) (b stp:node))
1012   nil)
1013
1014 (defmethod node= ((e stp:document) (f stp:document))
1015   (parent-node-= e f))
1016
1017 (defmethod node= ((a stp:attribute) (b stp:attribute))
1018   (and (named-node-= a b)
1019        (equal (stp:value a) (stp:value b))))
1020
1021 (defmethod node= ((a stp:comment) (b stp:comment))
1022   (equal (stp:data a) (stp:data b)))
1023
1024 (defmethod node= ((a stp:text) (b stp:text))
1025   (equal (stp:data a) (stp:data b)))
1026
1027 (defmethod node= ((a stp:processing-instruction)
1028                   (b stp:processing-instruction))
1029   (and (equal (stp:data a) (stp:data b))
1030        (equal (stp:target a) (stp:target b))))
1031
1032 (defmethod node= ((a stp:document-type) (b stp:document-type))
1033   (and (equal (stp:root-element-name a) (stp:root-element-name b))
1034        (equal (stp:public-id a) (stp:public-id b))
1035        (equal (stp:system-id a) (stp:system-id b))
1036        (equal (stp:internal-subset a) (stp:internal-subset b))))
1037
1038 (xpath-sys:define-xpath-function/eager
1039     xslt :print
1040     (thing)
1041   (if (xpath:node-set-p thing)
1042       (loop
1043          initially (format t ";;; node set:~%")
1044          for i from 0
1045          for node in (xpath:all-nodes thing)
1046          do
1047            (format t ";;;   ~D: ~A~%" i (type-of node)))
1048       (format t ";;; ~A~%" thing))
1049   thing)