| blob | 2e3320f0ec1a700e734c314b03088700a929927b |
1 # -*- Autoconf -*-
2 # SPDX-License-Identifier: 0BSD
4 ###############################################################################
5 #
6 # Process this file with autoconf to produce a configure script.
7 #
8 # Author: Lasse Collin
9 #
10 ###############################################################################
12 # NOTE: Don't add useless checks. autoscan detects this and that, but don't
13 # let it confuse you. For example, we don't care about checking for behavior
14 # of malloc(), stat(), or lstat(), since we don't use those functions in
15 # a way that would cause the problems the autoconf macros check.
17 AC_PREREQ([2.69])
19 AC_INIT([XZ Utils], m4_esyscmd([/bin/sh build-aux/version.sh]),
20 [xz@tukaani.org], [xz], [https://tukaani.org/xz/])
21 AC_CONFIG_SRCDIR([src/liblzma/common/common.h])
22 AC_CONFIG_AUX_DIR([build-aux])
23 AC_CONFIG_MACRO_DIR([m4])
24 AC_CONFIG_HEADERS([config.h])
26 echo
27 echo "$PACKAGE_STRING"
29 echo
30 echo "System type:"
31 # This is needed to know if assembler optimizations can be used.
32 AC_CANONICAL_HOST
34 # We do some special things on Windows (32-bit or 64-bit) builds.
35 case $host_os in
36 mingw* | cygwin | msys) is_w32=yes ;;
37 *) is_w32=no ;;
38 esac
39 AM_CONDITIONAL([COND_W32], [test "$is_w32" = yes])
41 # We need to use $EXEEXT with $(LN_S) when creating symlinks to
42 # executables. Cygwin is an exception to this, since it is recommended
43 # that symlinks don't have the .exe suffix. To make this work, we
44 # define LN_EXEEXT.
45 #
46 # MSYS2 is treated the same way as Cygwin. It uses plain "msys" like
47 # the original MSYS when building MSYS/MSYS2-binaries. Hopefully this
48 # doesn't break things for the original MSYS developers. Note that this
49 # doesn't affect normal MSYS/MSYS2 users building non-MSYS/MSYS2 binaries
50 # since in that case the $host_os is usually mingw32.
51 case $host_os in
52 cygwin | msys) LN_EXEEXT= ;;
53 *) LN_EXEEXT='$(EXEEXT)' ;;
54 esac
55 AC_SUBST([LN_EXEEXT])
57 echo
58 echo "Configure options:"
59 AM_CFLAGS=
62 #############
63 # Debugging #
64 #############
66 AC_MSG_CHECKING([if debugging code should be compiled])
67 AC_ARG_ENABLE([debug], AS_HELP_STRING([--enable-debug], [Enable debugging code.]),
68 [], enable_debug=no)
69 if test "x$enable_debug" = xyes; then
70 AC_MSG_RESULT([yes])
71 else
72 AC_DEFINE([NDEBUG], [1], [Define to 1 to disable debugging code.])
73 AC_MSG_RESULT([no])
74 fi
77 ###########
78 # Filters #
79 ###########
81 m4_define([SUPPORTED_FILTERS], [lzma1,lzma2,delta,x86,powerpc,ia64,arm,armthumb,arm64,sparc,riscv])dnl
82 m4_define([SIMPLE_FILTERS], [x86,powerpc,ia64,arm,armthumb,arm64,sparc,riscv])
83 m4_define([LZ_FILTERS], [lzma1,lzma2])
85 m4_foreach([NAME], [SUPPORTED_FILTERS],
86 [enable_filter_[]NAME=no
87 enable_encoder_[]NAME=no
88 enable_decoder_[]NAME=no
89 ])dnl
91 AC_MSG_CHECKING([which encoders to build])
92 AC_ARG_ENABLE([encoders], AS_HELP_STRING([--enable-encoders=LIST],
93 [Comma-separated list of encoders to build. Default=all.
94 Available encoders:]
95 m4_translit(m4_defn([SUPPORTED_FILTERS]), [,], [ ])),
96 [], [enable_encoders=SUPPORTED_FILTERS])
97 enable_encoders=`echo "$enable_encoders" | sed 's/,/ /g'`
98 if test "x$enable_encoders" = xno || test "x$enable_encoders" = x; then
99 enable_encoders=no
100 AC_MSG_RESULT([(none)])
101 else
102 for arg in $enable_encoders
103 do
104 case $arg in m4_foreach([NAME], [SUPPORTED_FILTERS], [
105 NAME)
106 enable_filter_[]NAME=yes
107 enable_encoder_[]NAME=yes
108 AC_DEFINE(HAVE_ENCODER_[]m4_toupper(NAME), [1],
109 [Define to 1 if] NAME [encoder is enabled.])
110 ;;])
111 *)
112 AC_MSG_RESULT([])
113 AC_MSG_ERROR([unknown filter: $arg])
114 ;;
115 esac
116 done
117 AC_DEFINE([HAVE_ENCODERS], [1],
118 [Define to 1 if any of HAVE_ENCODER_foo have been defined.])
119 AC_MSG_RESULT([$enable_encoders])
120 fi
122 AC_MSG_CHECKING([which decoders to build])
123 AC_ARG_ENABLE([decoders], AS_HELP_STRING([--enable-decoders=LIST],
124 [Comma-separated list of decoders to build. Default=all.
125 Available decoders are the same as available encoders.]),
126 [], [enable_decoders=SUPPORTED_FILTERS])
127 enable_decoders=`echo "$enable_decoders" | sed 's/,/ /g'`
128 if test "x$enable_decoders" = xno || test "x$enable_decoders" = x; then
129 enable_decoders=no
130 AC_MSG_RESULT([(none)])
131 else
132 for arg in $enable_decoders
133 do
134 case $arg in m4_foreach([NAME], [SUPPORTED_FILTERS], [
135 NAME)
136 enable_filter_[]NAME=yes
137 enable_decoder_[]NAME=yes
138 AC_DEFINE(HAVE_DECODER_[]m4_toupper(NAME), [1],
139 [Define to 1 if] NAME [decoder is enabled.])
140 ;;])
141 *)
142 AC_MSG_RESULT([])
143 AC_MSG_ERROR([unknown filter: $arg])
144 ;;
145 esac
146 done
147 AC_DEFINE([HAVE_DECODERS], [1],
148 [Define to 1 if any of HAVE_DECODER_foo have been defined.])
149 AC_MSG_RESULT([$enable_decoders])
150 fi
152 if test "x$enable_encoder_lzma2$enable_encoder_lzma1" = xyesno \
153 || test "x$enable_decoder_lzma2$enable_decoder_lzma1" = xyesno; then
154 AC_MSG_ERROR([LZMA2 requires that LZMA1 is also enabled.])
155 fi
157 AM_CONDITIONAL(COND_MAIN_ENCODER, test "x$enable_encoders" != xno)
158 AM_CONDITIONAL(COND_MAIN_DECODER, test "x$enable_decoders" != xno)
160 m4_foreach([NAME], [SUPPORTED_FILTERS],
161 [AM_CONDITIONAL(COND_FILTER_[]m4_toupper(NAME), test "x$enable_filter_[]NAME" = xyes)
162 AM_CONDITIONAL(COND_ENCODER_[]m4_toupper(NAME), test "x$enable_encoder_[]NAME" = xyes)
163 AM_CONDITIONAL(COND_DECODER_[]m4_toupper(NAME), test "x$enable_decoder_[]NAME" = xyes)
164 ])dnl
166 # The so called "simple filters" share common code.
167 enable_filter_simple=no
168 enable_encoder_simple=no
169 enable_decoder_simple=no
170 m4_foreach([NAME], [SIMPLE_FILTERS],
171 [test "x$enable_filter_[]NAME" = xyes && enable_filter_simple=yes
172 test "x$enable_encoder_[]NAME" = xyes && enable_encoder_simple=yes
173 test "x$enable_decoder_[]NAME" = xyes && enable_decoder_simple=yes
174 ])dnl
175 AM_CONDITIONAL(COND_FILTER_SIMPLE, test "x$enable_filter_simple" = xyes)
176 AM_CONDITIONAL(COND_ENCODER_SIMPLE, test "x$enable_encoder_simple" = xyes)
177 AM_CONDITIONAL(COND_DECODER_SIMPLE, test "x$enable_decoder_simple" = xyes)
179 # LZ-based filters share common code.
180 enable_filter_lz=no
181 enable_encoder_lz=no
182 enable_decoder_lz=no
183 m4_foreach([NAME], [LZ_FILTERS],
184 [test "x$enable_filter_[]NAME" = xyes && enable_filter_lz=yes
185 test "x$enable_encoder_[]NAME" = xyes && enable_encoder_lz=yes
186 test "x$enable_decoder_[]NAME" = xyes && enable_decoder_lz=yes
187 ])dnl
188 AM_CONDITIONAL(COND_FILTER_LZ, test "x$enable_filter_lz" = xyes)
189 AM_CONDITIONAL(COND_ENCODER_LZ, test "x$enable_encoder_lz" = xyes)
190 AM_CONDITIONAL(COND_DECODER_LZ, test "x$enable_decoder_lz" = xyes)
193 #################
194 # Match finders #
195 #################
197 m4_define([SUPPORTED_MATCH_FINDERS], [hc3,hc4,bt2,bt3,bt4])
199 m4_foreach([NAME], [SUPPORTED_MATCH_FINDERS],
200 [enable_match_finder_[]NAME=no
201 ])
203 AC_MSG_CHECKING([which match finders to build])
204 AC_ARG_ENABLE([match-finders], AS_HELP_STRING([--enable-match-finders=LIST],
205 [Comma-separated list of match finders to build. Default=all.
206 At least one match finder is required for encoding with
207 the LZMA1 and LZMA2 filters. Available match finders:]
208 m4_translit(m4_defn([SUPPORTED_MATCH_FINDERS]), [,], [ ])), [],
209 [enable_match_finders=SUPPORTED_MATCH_FINDERS])
210 enable_match_finders=`echo "$enable_match_finders" | sed 's/,/ /g'`
211 if test "x$enable_encoder_lz" = xyes ; then
212 if test -z "$enable_match_finders"; then
213 AC_MSG_ERROR([At least one match finder is required for an LZ-based encoder.])
214 fi
216 for arg in $enable_match_finders
217 do
218 case $arg in m4_foreach([NAME], [SUPPORTED_MATCH_FINDERS], [
219 NAME)
220 enable_match_finder_[]NAME=yes
221 AC_DEFINE(HAVE_MF_[]m4_toupper(NAME), [1],
222 [Define to 1 to enable] NAME [match finder.])
223 ;;])
224 *)
225 AC_MSG_RESULT([])
226 AC_MSG_ERROR([unknown match finder: $arg])
227 ;;
228 esac
229 done
230 AC_MSG_RESULT([$enable_match_finders])
231 else
232 AC_MSG_RESULT([(none because not building any LZ-based encoder)])
233 fi
236 ####################
237 # Integrity checks #
238 ####################
240 m4_define([SUPPORTED_CHECKS], [crc32,crc64,sha256])
242 m4_foreach([NAME], [SUPPORTED_CHECKS],
243 [enable_check_[]NAME=no
244 ])dnl
246 AC_MSG_CHECKING([which integrity checks to build])
247 AC_ARG_ENABLE([checks], AS_HELP_STRING([--enable-checks=LIST],
248 [Comma-separated list of integrity checks to build.
249 Default=all. Available integrity checks:]
250 m4_translit(m4_defn([SUPPORTED_CHECKS]), [,], [ ])),
251 [], [enable_checks=SUPPORTED_CHECKS])
252 enable_checks=`echo "$enable_checks" | sed 's/,/ /g'`
253 if test "x$enable_checks" = xno || test "x$enable_checks" = x; then
254 AC_MSG_RESULT([(none)])
255 else
256 for arg in $enable_checks
257 do
258 case $arg in m4_foreach([NAME], [SUPPORTED_CHECKS], [
259 NAME)
260 enable_check_[]NAME=yes
261 AC_DEFINE(HAVE_CHECK_[]m4_toupper(NAME), [1],
262 [Define to 1 if] NAME
263 [integrity check is enabled.])
264 ;;])
265 *)
266 AC_MSG_RESULT([])
267 AC_MSG_ERROR([unknown integrity check: $arg])
268 ;;
269 esac
270 done
271 AC_MSG_RESULT([$enable_checks])
272 fi
273 if test "x$enable_check_crc32" = xno ; then
274 AC_MSG_ERROR([For now, the CRC32 check must always be enabled.])
275 fi
277 m4_foreach([NAME], [SUPPORTED_CHECKS],
278 [AM_CONDITIONAL(COND_CHECK_[]m4_toupper(NAME), test "x$enable_check_[]NAME" = xyes)
279 ])dnl
281 AC_MSG_CHECKING([if external SHA-256 should be used])
282 AC_ARG_ENABLE([external-sha256], AS_HELP_STRING([--enable-external-sha256],
283 [Use SHA-256 code from the operating system.
284 See INSTALL for possible subtle problems.]),
285 [], [enable_external_sha256=no])
286 if test "x$enable_check_sha256" != "xyes"; then
287 enable_external_sha256=no
288 fi
289 if test "x$enable_external_sha256" = xyes; then
290 AC_MSG_RESULT([yes])
291 else
292 AC_MSG_RESULT([no])
293 fi
296 #############
297 # MicroLZMA #
298 #############
300 AC_MSG_CHECKING([if MicroLZMA support should be built])
301 AC_ARG_ENABLE([microlzma], AS_HELP_STRING([--disable-microlzma],
302 [Do not build MicroLZMA encoder and decoder.
303 It is needed by specific applications only,
304 for example, erofs-utils.]),
305 [], [enable_microlzma=yes])
306 case $enable_microlzma in
307 yes | no)
308 AC_MSG_RESULT([$enable_microlzma])
309 ;;
310 *)
311 AC_MSG_RESULT([])
312 AC_MSG_ERROR([--enable-microlzma accepts only 'yes' or 'no'.])
313 ;;
314 esac
315 AM_CONDITIONAL(COND_MICROLZMA, test "x$enable_microlzma" = xyes)
318 #############################
319 # .lz (lzip) format support #
320 #############################
322 AC_MSG_CHECKING([if .lz (lzip) decompression support should be built])
323 AC_ARG_ENABLE([lzip-decoder], AS_HELP_STRING([--disable-lzip-decoder],
324 [Disable decompression support for .lz (lzip) files.]),
325 [], [enable_lzip_decoder=yes])
326 if test "x$enable_decoder_lzma1" != xyes; then
327 enable_lzip_decoder=no
328 AC_MSG_RESULT([no because LZMA1 decoder is disabled])
329 elif test "x$enable_lzip_decoder" = xyes; then
330 AC_DEFINE([HAVE_LZIP_DECODER], [1],
331 [Define to 1 if .lz (lzip) decompression support is enabled.])
332 AC_MSG_RESULT([yes])
333 else
334 AC_MSG_RESULT([no])
335 fi
336 AM_CONDITIONAL(COND_LZIP_DECODER, test "x$enable_lzip_decoder" = xyes)
339 ###########################
340 # Assembler optimizations #
341 ###########################
343 AC_MSG_CHECKING([if assembler optimizations should be used])
344 AC_ARG_ENABLE([assembler], AS_HELP_STRING([--disable-assembler],
345 [Do not use assembler optimizations even if such exist
346 for the architecture.]),
347 [], [enable_assembler=yes])
348 if test "x$enable_assembler" = xyes; then
349 enable_assembler=no
350 case $host_os in
351 # Darwin should work too but only if not creating universal
352 # binaries. Solaris x86 could work too but I cannot test.
353 linux* | *bsd* | mingw* | cygwin | msys | *djgpp*)
354 case $host_cpu in
355 i?86) enable_assembler=x86 ;;
356 esac
357 ;;
358 esac
359 fi
360 case $enable_assembler in
361 x86 | no)
362 AC_MSG_RESULT([$enable_assembler])
363 ;;
364 *)
365 AC_MSG_RESULT([])
366 AC_MSG_ERROR([--enable-assembler accepts only 'yes', 'no', or 'x86' (32-bit).])
367 ;;
368 esac
369 AM_CONDITIONAL(COND_ASM_X86, test "x$enable_assembler" = xx86)
372 #############
373 # CLMUL CRC #
374 #############
376 AC_ARG_ENABLE([clmul-crc], AS_HELP_STRING([--disable-clmul-crc],
377 [Do not use carryless multiplication for CRC calculation
378 even if support for it is detected.]),
379 [], [enable_clmul_crc=yes])
382 ############################
383 # ARM64 CRC32 Instructions #
384 ############################
386 AC_ARG_ENABLE([arm64-crc32], AS_HELP_STRING([--disable-arm64-crc32],
387 [Do not use ARM64 CRC32 instructions even if support for it
388 is detected.]),
389 [], [enable_arm64_crc32=yes])
392 #####################
393 # Size optimization #
394 #####################
396 AC_MSG_CHECKING([if small size is preferred over speed])
397 AC_ARG_ENABLE([small], AS_HELP_STRING([--enable-small],
398 [Make liblzma smaller and a little slower.
399 This is disabled by default to optimize for speed.]),
400 [], [enable_small=no])
401 if test "x$enable_small" = xyes; then
402 AC_DEFINE([HAVE_SMALL], [1], [Define to 1 if optimizing for size.])
403 elif test "x$enable_small" != xno; then
404 AC_MSG_RESULT([])
405 AC_MSG_ERROR([--enable-small accepts only 'yes' or 'no'])
406 fi
407 AC_MSG_RESULT([$enable_small])
408 AM_CONDITIONAL(COND_SMALL, test "x$enable_small" = xyes)
411 #############
412 # Threading #
413 #############
415 AC_MSG_CHECKING([if threading support is wanted])
416 AC_ARG_ENABLE([threads], AS_HELP_STRING([--enable-threads=METHOD],
417 [Supported METHODS are 'yes', 'no', 'posix', 'win95', and
418 'vista'. The default is 'yes'. Using 'no' together with
419 --enable-small makes liblzma thread unsafe.]),
420 [], [enable_threads=yes])
422 if test "x$enable_threads" = xyes; then
423 case $host_os in
424 mingw*)
425 case $host_cpu in
426 i?86) enable_threads=win95 ;;
427 *) enable_threads=vista ;;
428 esac
429 ;;
430 *)
431 enable_threads=posix
432 ;;
433 esac
434 fi
436 case $enable_threads in
437 posix | win95 | vista)
438 AC_MSG_RESULT([yes, $enable_threads])
439 ;;
440 no)
441 AC_MSG_RESULT([no])
442 ;;
443 *)
444 AC_MSG_RESULT([])
445 AC_MSG_ERROR([--enable-threads only accepts 'yes', 'no', 'posix', 'win95', or 'vista'])
446 ;;
447 esac
449 # We use the actual result a little later.
452 #########################
453 # Assumed amount of RAM #
454 #########################
456 # We use 128 MiB as default, because it will allow decompressing files
457 # created with "xz -9". It would be slightly safer to guess a lower value,
458 # but most systems, on which we don't have any way to determine the amount
459 # of RAM, will probably have at least 128 MiB of RAM.
460 AC_MSG_CHECKING([how much RAM to assume if the real amount is unknown])
461 AC_ARG_ENABLE([assume-ram], AS_HELP_STRING([--enable-assume-ram=SIZE],
462 [If and only if the real amount of RAM cannot be determined,
463 assume SIZE MiB. The default is 128 MiB. This affects the
464 default memory usage limit.]),
465 [], [enable_assume_ram=128])
466 assume_ram_check=`echo "$enable_assume_ram" | tr -d 0123456789`
467 if test -z "$enable_assume_ram" || test -n "$assume_ram_check"; then
468 AC_MSG_RESULT([])
469 AC_MSG_ERROR([--enable-assume-ram accepts only an integer argument])
470 fi
471 AC_MSG_RESULT([$enable_assume_ram MiB])
472 AC_DEFINE_UNQUOTED([ASSUME_RAM], [$enable_assume_ram],
473 [How many MiB of RAM to assume if the real amount cannot
474 be determined.])
477 #########################
478 # Components to install #
479 #########################
481 AC_ARG_ENABLE([xz], [AS_HELP_STRING([--disable-xz],
482 [do not build the xz tool])],
483 [], [enable_xz=yes])
484 AM_CONDITIONAL([COND_XZ], [test x$enable_xz != xno])
486 AC_ARG_ENABLE([xzdec], [AS_HELP_STRING([--disable-xzdec],
487 [do not build xzdec])],
488 [], [enable_xzdec=yes])
489 test "x$enable_decoders" = xno && enable_xzdec=no
490 AM_CONDITIONAL([COND_XZDEC], [test x$enable_xzdec != xno])
492 AC_ARG_ENABLE([lzmadec], [AS_HELP_STRING([--disable-lzmadec],
493 [do not build lzmadec
494 (it exists primarily for LZMA Utils compatibility)])],
495 [], [enable_lzmadec=yes])
496 test "x$enable_decoder_lzma1" = xno && enable_lzmadec=no
497 AM_CONDITIONAL([COND_LZMADEC], [test x$enable_lzmadec != xno])
499 AC_ARG_ENABLE([lzmainfo], [AS_HELP_STRING([--disable-lzmainfo],
500 [do not build lzmainfo
501 (it exists primarily for LZMA Utils compatibility)])],
502 [], [enable_lzmainfo=yes])
503 test "x$enable_decoder_lzma1" = xno && enable_lzmainfo=no
504 AM_CONDITIONAL([COND_LZMAINFO], [test x$enable_lzmainfo != xno])
506 AC_ARG_ENABLE([lzma-links], [AS_HELP_STRING([--disable-lzma-links],
507 [do not create symlinks for LZMA Utils compatibility])],
508 [], [enable_lzma_links=yes])
509 AM_CONDITIONAL([COND_LZMALINKS], [test x$enable_lzma_links != xno])
511 AC_ARG_ENABLE([scripts], [AS_HELP_STRING([--disable-scripts],
512 [do not install the scripts xzdiff, xzgrep, xzless, xzmore,
513 and their symlinks])],
514 [], [enable_scripts=yes])
515 AM_CONDITIONAL([COND_SCRIPTS], [test x$enable_scripts != xno])
517 AC_ARG_ENABLE([doc], [AS_HELP_STRING([--disable-doc],
518 [do not install documentation files to docdir
519 (man pages are still installed and,
520 if --enable-doxygen is used,
521 liblzma API documentation is installed too)])],
522 [], [enable_doc=yes])
523 AM_CONDITIONAL([COND_DOC], [test x$enable_doc != xno])
525 AC_ARG_ENABLE([doxygen], [AS_HELP_STRING([--enable-doxygen],
526 [generate HTML version of the liblzma API documentation
527 using Doxygen and install the result to docdir])],
528 [], [enable_doxygen=no])
529 AM_CONDITIONAL([COND_DOXYGEN], [test x$enable_doxygen != xno])
532 ##############
533 # Sandboxing #
534 ##############
536 AC_MSG_CHECKING([if sandboxing should be used])
537 AC_ARG_ENABLE([sandbox], [AS_HELP_STRING([--enable-sandbox=METHOD],
538 [Sandboxing METHOD can be
539 'auto', 'no', 'capsicum', 'pledge', or 'landlock'.
540 The default is 'auto' which enables sandboxing if
541 a supported sandboxing method is found.])],
542 [], [enable_sandbox=auto])
543 case $enable_xzdec-$enable_xz-$enable_sandbox in
544 no-no-*)
545 enable_sandbox=no
546 AC_MSG_RESULT([no, --disable-xz and --disable-xzdec was used])
547 ;;
548 *-*-auto)
549 AC_MSG_RESULT([maybe (autodetect)])
550 ;;
551 *-*-no | *-*-capsicum | *-*-pledge | *-*-landlock)
552 AC_MSG_RESULT([$enable_sandbox])
553 ;;
554 *)
555 AC_MSG_RESULT([])
556 AC_MSG_ERROR([--enable-sandbox only accepts 'auto', 'no', 'capsicum', 'pledge', or 'landlock'.])
557 ;;
558 esac
561 ###########################
562 # PATH prefix for scripts #
563 ###########################
565 # The scripts can add a prefix to the search PATH so that POSIX tools
566 # or the xz binary is always in the PATH.
567 AC_ARG_ENABLE([path-for-scripts],
568 [AS_HELP_STRING([--enable-path-for-scripts=PREFIX],
569 [If PREFIX isn't empty, PATH=PREFIX:$PATH will be set in
570 the beginning of the scripts (xzgrep and others).
571 The default is empty except on Solaris the default is
572 /usr/xpg4/bin.])],
573 [], [
574 case $host_os in
575 solaris*) enable_path_for_scripts=/usr/xpg4/bin ;;
576 *) enable_path_for_scripts= ;;
577 esac
578 ])
579 if test -n "$enable_path_for_scripts" && test "x$enable_path_for_scripts" != xno ; then
580 enable_path_for_scripts="PATH=$enable_path_for_scripts:\$PATH"
581 else
582 enable_path_for_scripts=
583 fi
584 AC_SUBST([enable_path_for_scripts])
587 ###############################################################################
588 # Checks for programs.
589 ###############################################################################
591 echo
592 case $host_os in
593 solaris*)
594 # The gnulib POSIX shell macro below may pick a shell that
595 # doesn't work with xzgrep. Workaround by picking a shell
596 # that is known to work.
597 if test -z "$gl_cv_posix_shell" && test -x /usr/xpg4/bin/sh; then
598 gl_cv_posix_shell=/usr/xpg4/bin/sh
599 fi
600 ;;
601 esac
602 gl_POSIX_SHELL
603 if test -z "$POSIX_SHELL" && test "x$enable_scripts" = xyes ; then
604 AC_MSG_ERROR([No POSIX conforming shell (sh) was found.])
605 fi
607 echo
608 echo "Initializing Automake:"
610 # We don't use "subdir-objects" yet because it breaks "make distclean" when
611 # dependencies are enabled (as of Automake 1.14.1) due to this bug:
612 # https://debbugs.gnu.org/cgi/bugreport.cgi?bug=17354
613 # The -Wno-unsupported is used to silence warnings about missing
614 # "subdir-objects".
615 AM_INIT_AUTOMAKE([1.12 foreign tar-v7 filename-length-max=99 -Wno-unsupported])
616 AC_PROG_LN_S
618 dnl # Autoconf >= 2.70 warns that AC_PROG_CC_C99 is obsolete. However,
619 dnl # we have to keep using AC_PROG_CC_C99 instead of AC_PROG_CC
620 dnl # as long as we try to be compatible with Autoconf 2.69.
621 AC_PROG_CC_C99
622 if test x$ac_cv_prog_cc_c99 = xno ; then
623 AC_MSG_ERROR([No C99 compiler was found.])
624 fi
626 AM_PROG_CC_C_O
627 AM_PROG_AS
628 AC_USE_SYSTEM_EXTENSIONS
630 AS_CASE([$enable_threads],
631 [posix], [
632 echo
633 echo "POSIX threading support:"
634 AX_PTHREAD([:]) dnl We don't need the HAVE_PTHREAD macro.
635 LIBS="$LIBS $PTHREAD_LIBS"
636 AM_CFLAGS="$AM_CFLAGS $PTHREAD_CFLAGS"
638 dnl NOTE: PTHREAD_CC is ignored. It would be useful on AIX,
639 dnl but it's tricky to get it right together with
640 dnl AC_PROG_CC_C99. Thus, this is handled by telling the
641 dnl user in INSTALL to set the correct CC manually.
643 AC_DEFINE([MYTHREAD_POSIX], [1],
644 [Define to 1 when using POSIX threads (pthreads).])
646 # This is nice to have but not mandatory.
647 OLD_CFLAGS=$CFLAGS
648 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
649 AC_CHECK_FUNCS([pthread_condattr_setclock])
650 CFLAGS=$OLD_CFLAGS
651 ],
652 [win95], [
653 AC_DEFINE([MYTHREAD_WIN95], [1], [Define to 1 when using
654 Windows 95 (and thus XP) compatible threads.
655 This avoids use of features that were added in
656 Windows Vista.])
657 ],
658 [vista], [
659 AC_DEFINE([MYTHREAD_VISTA], [1], [Define to 1 when using
660 Windows Vista compatible threads. This uses
661 features that are not available on Windows XP.])
662 ]
663 )
664 AM_CONDITIONAL([COND_THREADS], [test "x$enable_threads" != xno])
666 echo
667 echo "Initializing Libtool:"
668 LT_PREREQ([2.4])
669 LT_INIT([win32-dll])
670 LT_LANG([Windows Resource])
672 # This is a bit wrong since it is possible to request that only some libs
673 # are built as shared. Using that feature isn't so common though, and this
674 # breaks only on Windows (at least for now) if the user enables only some
675 # libs as shared.
676 AM_CONDITIONAL([COND_SHARED], [test "x$enable_shared" != xno])
678 #####################
679 # Symbol versioning #
680 #####################
682 # NOTE: This checks if we are building shared or static library
683 # and if --with-pic or --without-pic was used. Thus this check
684 # must be after Libtool initialization.
685 AC_MSG_CHECKING([if library symbol versioning should be used])
686 AC_ARG_ENABLE([symbol-versions], [AS_HELP_STRING([--enable-symbol-versions],
687 [Use symbol versioning for liblzma. Enabled by default on
688 GNU/Linux, other GNU-based systems, and FreeBSD.])],
689 [], [enable_symbol_versions=auto])
690 if test "x$enable_symbol_versions" = xauto; then
691 case $host_os in
692 # NOTE: Even if one omits -gnu on GNU/Linux (e.g.
693 # i486-slackware-linux), configure will (via config.sub)
694 # append -gnu (e.g. i486-slackware-linux-gnu), and this
695 # test will work correctly.
696 gnu* | *-gnu* | freebsd*)
697 enable_symbol_versions=yes
698 ;;
699 *)
700 enable_symbol_versions=no
701 ;;
702 esac
703 fi
705 # There are two variants for symbol versioning.
706 # See src/liblzma/validate_map.sh for details.
707 #
708 # On GNU/Linux, extra symbols are added in the C code. These extra symbols
709 # must not be put into a static library as they can cause problems (and
710 # even if they didn't cause problems, they would be useless). On other
711 # systems symbol versioning may be used too but there is no problem as only
712 # a linker script is specified in src/liblzma/Makefile.am and that isn't
713 # used when creating a static library.
714 #
715 # Libtool always uses -DPIC when building shared libraries by default and
716 # doesn't use it for static libs by default. This can be overridden with
717 # --with-pic and --without-pic though. As long as neither --with-pic nor
718 # --without-pic is used then we can use #ifdef PIC to detect if the file is
719 # being built for a shared library.
720 AS_IF([test "x$enable_symbol_versions" = xno], [
721 enable_symbol_versions=no
722 AC_MSG_RESULT([no])
723 ], [test "x$enable_shared" = xno], [
724 enable_symbol_versions=no
725 AC_MSG_RESULT([no (not building a shared library)])
726 ], [
727 # "yes" means that symbol version are to be used but we need to
728 # autodetect which variant to use.
729 if test "x$enable_symbol_versions" = xyes ; then
730 case "$host_cpu-$host_os" in
731 microblaze*)
732 # GCC 12 on MicroBlaze doesn't support
733 # __symver__ attribute. It's simplest and
734 # safest to use the generic version on that
735 # platform since then only the linker script
736 # is needed. The RHEL/CentOS 7 compatibility
737 # symbols don't matter on MicroBlaze.
738 enable_symbol_versions=generic
739 ;;
740 *-linux*)
741 # NVIDIA HPC Compiler doesn't support symbol
742 # versioning but the linker script can still
743 # be used.
744 AC_EGREP_CPP([use_generic_symbol_versioning],
745 [#ifdef __NVCOMPILER
746 use_generic_symbol_versioning
747 #endif],
748 [enable_symbol_versions=generic],
749 [enable_symbol_versions=linux])
750 ;;
751 *)
752 enable_symbol_versions=generic
753 ;;
754 esac
755 fi
757 if test "x$enable_symbol_versions" = xlinux ; then
758 case "$pic_mode-$enable_static" in
759 default-*)
760 # Use symvers if PIC is defined.
761 have_symbol_versions_linux=2
762 ;;
763 *-no)
764 # Not building static library.
765 # Use symvers unconditionally.
766 have_symbol_versions_linux=1
767 ;;
768 *)
769 AC_MSG_RESULT([])
770 AC_MSG_ERROR([
771 On GNU/Linux, building both shared and static library at the same time
772 is not supported if --with-pic or --without-pic is used.
773 Use either --disable-shared or --disable-static to build one type
774 of library at a time. If both types are needed, build one at a time,
775 possibly picking only src/liblzma/.libs/liblzma.a from the static build.])
776 ;;
777 esac
778 AC_DEFINE_UNQUOTED([HAVE_SYMBOL_VERSIONS_LINUX],
779 [$have_symbol_versions_linux],
780 [Define to 1 to if GNU/Linux-specific details
781 are unconditionally wanted for symbol
782 versioning. Define to 2 to if these are wanted
783 only if also PIC is defined (allows building
784 both shared and static liblzma at the same
785 time with Libtool if neither --with-pic nor
786 --without-pic is used). This define must be
787 used together with liblzma_linux.map.])
788 elif test "x$enable_symbol_versions" != xgeneric ; then
789 AC_MSG_RESULT([])
790 AC_MSG_ERROR([unknown symbol versioning variant '$enable_symbol_versions'])
791 fi
792 AC_MSG_RESULT([yes ($enable_symbol_versions)])
793 ])
795 AM_CONDITIONAL([COND_SYMVERS_LINUX],
796 [test "x$enable_symbol_versions" = xlinux])
797 AM_CONDITIONAL([COND_SYMVERS_GENERIC],
798 [test "x$enable_symbol_versions" = xgeneric])
801 ###############################################################################
802 # Checks for libraries.
803 ###############################################################################
805 dnl Support for _REQUIRE_VERSION was added in gettext 0.19.6. If both
806 dnl _REQUIRE_VERSION and _VERSION are present, the _VERSION is ignored.
807 dnl We use both for compatibility with other programs in the Autotools family.
808 echo
809 echo "Initializing gettext:"
810 AM_GNU_GETTEXT_REQUIRE_VERSION([0.19.6])
811 AM_GNU_GETTEXT_VERSION([0.19.6])
812 AM_GNU_GETTEXT([external])
815 ###############################################################################
816 # Checks for header files.
817 ###############################################################################
819 echo
820 echo "System headers and functions:"
822 # immintrin.h allows the use of the intrinsic functions if they are available.
823 # cpuid.h may be used for detecting x86 processor features at runtime.
824 AC_CHECK_HEADERS([immintrin.h cpuid.h])
827 ###############################################################################
828 # Checks for typedefs, structures, and compiler characteristics.
829 ###############################################################################
831 AC_HEADER_STDBOOL
833 AC_TYPE_UINT8_T
834 AC_TYPE_UINT16_T
835 AC_TYPE_INT32_T
836 AC_TYPE_UINT32_T
837 AC_TYPE_INT64_T
838 AC_TYPE_UINT64_T
839 AC_TYPE_UINTPTR_T
841 AC_CHECK_SIZEOF([size_t])
843 # The command line tool can copy high resolution timestamps if such
844 # information is available in struct stat. Otherwise one second accuracy
845 # is used.
846 AC_CHECK_MEMBERS([
847 struct stat.st_atim.tv_nsec,
848 struct stat.st_atimespec.tv_nsec,
849 struct stat.st_atimensec,
850 struct stat.st_uatime,
851 struct stat.st_atim.st__tim.tv_nsec])
853 AC_SYS_LARGEFILE
854 AC_C_BIGENDIAN
856 # __attribute__((__constructor__)) can be used for one-time initializations.
857 # Use -Werror because some compilers accept unknown attributes and just
858 # give a warning.
859 #
860 # FIXME? Unfortunately -Werror can cause trouble if CFLAGS contains options
861 # that produce warnings for unrelated reasons. For example, GCC and Clang
862 # support -Wunused-macros which will warn about "#define _GNU_SOURCE 1"
863 # which will be among the #defines that Autoconf inserts to the beginning of
864 # the test program. There seems to be no nice way to prevent Autoconf from
865 # inserting the any defines to the test program.
866 AC_MSG_CHECKING([if __attribute__((__constructor__)) can be used])
867 have_func_attribute_constructor=no
868 OLD_CFLAGS="$CFLAGS"
869 CFLAGS="$CFLAGS -Werror"
870 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
871 __attribute__((__constructor__))
872 static void my_constructor_func(void) { return; }
873 ]])], [
874 AC_DEFINE([HAVE_FUNC_ATTRIBUTE_CONSTRUCTOR], [1],
875 [Define to 1 if __attribute__((__constructor__))
876 is supported for functions.])
877 have_func_attribute_constructor=yes
878 AC_MSG_RESULT([yes])
879 ], [
880 AC_MSG_RESULT([no])
881 ])
882 CFLAGS="$OLD_CFLAGS"
884 # The Win95 threading lacks a thread-safe one-time initialization function.
885 # The one-time initialization is needed for crc32_small.c and crc64_small.c
886 # create the CRC tables. So if small mode is enabled, the threading mode is
887 # win95, and the compiler does not support attribute constructor, then we
888 # would end up with a multithreaded build that is thread-unsafe. As a
889 # result this configuration is not allowed.
890 if test "x$enable_small$enable_threads$have_func_attribute_constructor" \
891 = xyeswin95no; then
892 AC_MSG_ERROR([
893 --enable-threads=win95 and --enable-small cannot be used
894 at the same time with a compiler that doesn't support
895 __attribute__((__constructor__))])
896 fi
899 ###############################################################################
900 # Checks for library functions.
901 ###############################################################################
903 # Gnulib replacements as needed
904 gl_GETOPT
906 # If clock_gettime() is available, liblzma with pthreads may use it, and
907 # xz may use it even when threading support is disabled. In XZ Utils 5.4.x
908 # and older, configure checked for clock_gettime() only when using pthreads.
909 # This way non-threaded builds of liblzma didn't get a useless dependency on
910 # librt which further had a dependency on libpthread. Avoiding these was
911 # useful when a small build was needed, for example, for initramfs use.
912 #
913 # The above reasoning is thoroughly obsolete: On GNU/Linux, librt hasn't
914 # been needed for clock_gettime() since glibc 2.17 (2012-12-25).
915 # Solaris 10 needs librt but Solaris 11 doesn't anymore.
916 AC_SEARCH_LIBS([clock_gettime], [rt])
917 AC_CHECK_FUNCS([clock_gettime])
918 AC_CHECK_DECL([CLOCK_MONOTONIC], [AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1],
919 [Define to 1 if 'CLOCK_MONOTONIC' is declared in <time.h>.])], [],
920 [[#include <time.h>]])
922 # Find the best function to set timestamps.
923 AC_CHECK_FUNCS([futimens futimes futimesat utimes _futime utime], [break])
925 # This is nice to have but not mandatory.
926 AC_CHECK_FUNCS([posix_fadvise])
928 TUKLIB_PROGNAME
929 TUKLIB_INTEGER
930 TUKLIB_PHYSMEM
931 TUKLIB_CPUCORES
932 TUKLIB_MBSTR
934 # If requested, check for system-provided SHA-256. At least the following
935 # implementations are supported:
936 #
937 # OS Headers Library Type Function
938 # FreeBSD sys/types.h + sha256.h libmd SHA256_CTX SHA256_Init
939 # NetBSD sys/types.h + sha2.h SHA256_CTX SHA256_Init
940 # OpenBSD sys/types.h + sha2.h SHA2_CTX SHA256Init
941 # Solaris sys/types.h + sha2.h libmd SHA256_CTX SHA256Init
942 # MINIX 3 sys/types.h + sha2.h SHA256_CTX SHA256_Init
943 # Darwin CommonCrypto/CommonDigest.h CC_SHA256_CTX CC_SHA256_Init
944 #
945 # Note that Darwin's CC_SHA256_Update takes buffer size as uint32_t instead
946 # of size_t.
947 #
948 sha256_header_found=no
949 sha256_type_found=no
950 sha256_func_found=no
951 AS_IF([test "x$enable_external_sha256" = "xyes"], [
952 # Test for Common Crypto before others, because Darwin has sha256.h
953 # too and we don't want to use that, because on older versions it
954 # uses OpenSSL functions, whose SHA256_Init is not guaranteed to
955 # succeed.
956 AC_CHECK_HEADERS(
957 [CommonCrypto/CommonDigest.h sha256.h sha2.h],
958 [sha256_header_found=yes ; break])
959 if test "x$sha256_header_found" = xyes; then
960 AC_CHECK_TYPES([CC_SHA256_CTX, SHA256_CTX, SHA2_CTX],
961 [sha256_type_found=yes], [],
962 [[#ifdef HAVE_SYS_TYPES_H
963 # include <sys/types.h>
964 #endif
965 #ifdef HAVE_COMMONCRYPTO_COMMONDIGEST_H
966 # include <CommonCrypto/CommonDigest.h>
967 #endif
968 #ifdef HAVE_SHA256_H
969 # include <sha256.h>
970 #endif
971 #ifdef HAVE_SHA2_H
972 # include <sha2.h>
973 #endif]])
974 if test "x$sha256_type_found" = xyes ; then
975 AC_SEARCH_LIBS([SHA256Init], [md])
976 AC_SEARCH_LIBS([SHA256_Init], [md])
977 AC_CHECK_FUNCS([CC_SHA256_Init SHA256Init SHA256_Init],
978 [sha256_func_found=yes ; break])
979 fi
980 fi
981 ])
982 AM_CONDITIONAL([COND_INTERNAL_SHA256], [test "x$sha256_func_found" = xno])
983 if test "x$enable_external_sha256$sha256_func_found" = xyesno; then
984 AC_MSG_ERROR([--enable-external-sha256 was specified but no supported external SHA-256 implementation was found])
985 fi
987 # Check for SSE2 intrinsics. There is no run-time detection for SSE2 so if
988 # compiler options enable SSE2 then SSE2 support is required by the binaries.
989 # The compile-time check for SSE2 is done with #ifdefs because some compilers
990 # (ICC, MSVC) allow SSE2 intrinsics even when SSE2 isn't enabled.
991 AC_CHECK_DECL([_mm_movemask_epi8],
992 [AC_DEFINE([HAVE__MM_MOVEMASK_EPI8], [1],
993 [Define to 1 if _mm_movemask_epi8 is available.])],
994 [],
995 [#ifdef HAVE_IMMINTRIN_H
996 #include <immintrin.h>
997 #endif])
999 # For faster CRC on 32/64-bit x86 and E2K (see also crc64_fast.c):
1000 #
1001 # - Check for the CLMUL intrinsic _mm_clmulepi64_si128 in <immintrin.h>.
1002 # Check also for _mm_set_epi64x for consistency with CMake build
1003 # where it's needed to disable CLMUL with VS2013.
1004 #
1005 # - Check that __attribute__((__target__("ssse3,sse4.1,pclmul"))) works
1006 # together with _mm_clmulepi64_si128 from <immintrin.h>. The attribute
1007 # was added in GCC 4.4 but some GCC 4.x versions don't allow intrinsics
1008 # with it. Exception: it must be not be used with EDG-based compilers
1009 # like ICC and the compiler on E2K.
1010 #
1011 # If everything above is supported, runtime detection will be used to keep the
1012 # binaries working on systems that don't support the required extensions.
1013 AC_MSG_CHECKING([if _mm_clmulepi64_si128 is usable])
1014 AS_IF([test "x$enable_clmul_crc" = xno], [
1015 AC_MSG_RESULT([no, --disable-clmul-crc was used])
1016 ], [
1017 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1018 #include <immintrin.h>
1020 // CLMUL works on older E2K instruction set but it is slow due to emulation.
1021 #if defined(__e2k__) && __iset__ < 6
1022 # error
1023 #endif
1025 // Intel's old compiler (ICC) can define __GNUC__ but the attribute must not
1026 // be used with it. The new Clang-based ICX needs the attribute.
1027 // Checking for !defined(__EDG__) catches ICC and other EDG-based compilers.
1028 #if (defined(__GNUC__) || defined(__clang__)) && !defined(__EDG__)
1029 __attribute__((__target__("ssse3,sse4.1,pclmul")))
1030 #endif
1031 __m128i my_clmul(__m128i a)
1032 {
1033 const __m128i b = _mm_set_epi64x(1, 2);
1034 return _mm_clmulepi64_si128(a, b, 0);
1035 }
1036 ]])], [
1037 AC_DEFINE([HAVE_USABLE_CLMUL], [1],
1038 [Define to 1 if _mm_set_epi64x and
1039 _mm_clmulepi64_si128 are usable.
1040 See configure.ac for details.])
1041 enable_clmul_crc=yes
1042 ], [
1043 enable_clmul_crc=no
1044 ])
1045 AC_MSG_RESULT([$enable_clmul_crc])
1046 ])
1048 # ARM64 C Language Extensions define CRC32 functions in arm_acle.h.
1049 # These are supported by at least GCC and Clang which both need
1050 # __attribute__((__target__("+crc"))), unless the needed compiler flags
1051 # are used to support the CRC instruction.
1052 AC_MSG_CHECKING([if ARM64 CRC32 instruction is usable])
1053 AS_IF([test "x$enable_arm64_crc32" = xno], [
1054 AC_MSG_RESULT([no, --disable-arm64-crc32 was used])
1055 ], [
1056 # Set -Werror here because some versions of Clang (14 and older)
1057 # do not report the unsupported __attribute__((__target__("+crc")))
1058 # or __crc32d() as an error, only as a warning. This does not need
1059 # to be done with CMake because tests will attempt to link and the
1060 # error will be reported then.
1061 OLD_CFLAGS="$CFLAGS"
1062 CFLAGS="$CFLAGS -Werror"
1064 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1065 #include <arm_acle.h>
1066 #include <stdint.h>
1068 #if (defined(__GNUC__) || defined(__clang__)) && !defined(__EDG__)
1069 __attribute__((__target__("+crc")))
1070 #endif
1071 uint32_t my_crc(uint32_t a, uint64_t b)
1072 {
1073 return __crc32d(a, b);
1074 }
1075 ]])], [
1076 AC_DEFINE([HAVE_ARM64_CRC32], [1],
1077 [Define to 1 if ARM64 CRC32 instruction is supported.
1078 See configure.ac for details.])
1079 enable_arm64_crc32=yes
1080 ], [
1081 enable_arm64_crc32=no
1082 ])
1083 AC_MSG_RESULT([$enable_arm64_crc32])
1085 CFLAGS="$OLD_CFLAGS"
1086 ])
1088 # Check for ARM64 CRC32 instruction runtime detection.
1089 # getauxval() is supported on Linux, elf_aux_info() on FreeBSD, and
1090 # sysctlbyname("hw.optional.armv8_crc32", ...) is supported on Darwin
1091 # (macOS, iOS, etc.). Note that sysctlbyname() is supported on FreeBSD,
1092 # NetBSD, and possibly others too but the string is specific to Apple OSes.
1093 # The C code is responsible for checking defined(__APPLE__) before using
1094 # sysctlbyname("hw.optional.armv8_crc32", ...).
1095 AS_IF([test "x$enable_arm64_crc32" = xyes], [
1096 AC_CHECK_FUNCS([getauxval elf_aux_info sysctlbyname], [break])
1097 ])
1100 # Check for sandbox support. If one is found, set enable_sandbox=found.
1101 #
1102 # About -fsanitize: Of our three sandbox methods, only Landlock is
1103 # incompatible with -fsanitize. FreeBSD 13.2 with Capsicum was tested with
1104 # -fsanitize=address,undefined and had no issues. OpenBSD (as of version
1105 # 7.4) has minimal support for process instrumentation. OpenBSD does not
1106 # distribute the additional libraries needed (libasan, libubsan, etc.) with
1107 # GCC or Clang needed for runtime sanitization support and instead only
1108 # support -fsanitize-minimal-runtime for minimal undefined behavior
1109 # sanitization. This minimal support is compatible with our use of the
1110 # Pledge sandbox. So only Landlock will result in a build that cannot
1111 # compress or decompress a single file to standard out.
1112 AS_CASE([$enable_sandbox],
1113 [auto | capsicum], [
1114 AC_CHECK_FUNCS([cap_rights_limit], [enable_sandbox=found])
1115 ]
1116 )
1117 AS_CASE([$enable_sandbox],
1118 [auto | pledge], [
1119 AC_CHECK_FUNCS([pledge], [enable_sandbox=found])
1120 ]
1121 )
1122 AS_CASE([$enable_sandbox],
1123 [auto | landlock], [
1124 AC_MSG_CHECKING([if Linux Landlock is usable])
1126 # A compile check is done here because some systems have
1127 # linux/landlock.h, but do not have the syscalls defined
1128 # in order to actually use Linux Landlock.
1129 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1130 #include <linux/landlock.h>
1131 #include <sys/syscall.h>
1132 #include <sys/prctl.h>
1134 void my_sandbox(void)
1135 {
1136 (void)prctl(PR_SET_NO_NEW_PRIVS, 1, 0, 0, 0);
1137 (void)SYS_landlock_create_ruleset;
1138 (void)SYS_landlock_restrict_self;
1139 (void)LANDLOCK_CREATE_RULESET_VERSION;
1140 return;
1141 }
1142 ]])], [
1143 enable_sandbox=found
1145 AS_CASE([$CFLAGS], [*-fsanitize=*], [AC_MSG_ERROR([
1146 CFLAGS contains '-fsanitize=' which is incompatible with the Landlock
1147 sandboxing. Use --disable-sandbox when using '-fsanitize'.])])
1149 AC_DEFINE([HAVE_LINUX_LANDLOCK], [1],
1150 [Define to 1 if Linux Landlock is supported.
1151 See configure.ac for details.])
1152 AC_MSG_RESULT([yes])
1153 ], [
1154 AC_MSG_RESULT([no])
1155 ])
1156 ]
1157 )
1159 # If a specific sandboxing method was explicitly requested and it wasn't
1160 # found, give an error.
1161 case $enable_sandbox in
1162 auto | no | found)
1163 ;;
1164 *)
1165 AC_MSG_ERROR([$enable_sandbox support not found])
1166 ;;
1167 esac
1170 ###############################################################################
1171 # If using GCC, set some additional AM_CFLAGS:
1172 ###############################################################################
1174 if test "$GCC" = yes ; then
1175 echo
1176 echo "GCC extensions:"
1177 fi
1179 # Always do the visibility check but don't set AM_CFLAGS on Windows.
1180 # This way things get set properly even on Windows.
1181 gl_VISIBILITY
1182 if test -n "$CFLAG_VISIBILITY" && test "$is_w32" = no; then
1183 AM_CFLAGS="$AM_CFLAGS $CFLAG_VISIBILITY"
1184 fi
1186 AS_IF([test "$GCC" = yes], [
1187 # Enable as much warnings as possible. These commented warnings won't
1188 # work for this package though:
1189 # * -Wunreachable-code breaks several assert(0) cases, which are
1190 # backed up with "return LZMA_PROG_ERROR".
1191 # * -Wcast-qual would break various things where we need a non-const
1192 # pointer although we don't modify anything through it.
1193 # * -Winline, -Wdisabled-optimization, -Wunsafe-loop-optimizations
1194 # don't seem so useful here; at least the last one gives some
1195 # warnings which are not bugs.
1196 # * -Wconversion still shows too many warnings.
1197 #
1198 # The flags before the empty line are for GCC and many of them
1199 # are supported by Clang too. The flags after the empty line are
1200 # for Clang.
1201 for NEW_FLAG in \
1202 -Wall \
1203 -Wextra \
1204 -Wvla \
1205 -Wformat=2 \
1206 -Winit-self \
1207 -Wmissing-include-dirs \
1208 -Wshift-overflow=2 \
1209 -Wstrict-overflow=3 \
1210 -Walloc-zero \
1211 -Wduplicated-cond \
1212 -Wfloat-equal \
1213 -Wundef \
1214 -Wshadow \
1215 -Wpointer-arith \
1216 -Wbad-function-cast \
1217 -Wwrite-strings \
1218 -Wdate-time \
1219 -Wsign-conversion \
1220 -Wfloat-conversion \
1221 -Wlogical-op \
1222 -Waggregate-return \
1223 -Wstrict-prototypes \
1224 -Wold-style-definition \
1225 -Wmissing-prototypes \
1226 -Wmissing-declarations \
1227 -Wredundant-decls \
1228 \
1229 -Wc99-compat \
1230 -Wc11-extensions \
1231 -Wc2x-compat \
1232 -Wc2x-extensions \
1233 -Wpre-c2x-compat \
1234 -Warray-bounds-pointer-arithmetic \
1235 -Wassign-enum \
1236 -Wconditional-uninitialized \
1237 -Wdocumentation \
1238 -Wduplicate-enum \
1239 -Wempty-translation-unit \
1240 -Wflexible-array-extensions \
1241 -Wmissing-variable-declarations \
1242 -Wnewline-eof \
1243 -Wshift-sign-overflow \
1244 -Wstring-conversion
1245 do
1246 AC_MSG_CHECKING([if $CC accepts $NEW_FLAG])
1247 OLD_CFLAGS="$CFLAGS"
1248 CFLAGS="$CFLAGS $NEW_FLAG -Werror"
1249 AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1250 [[void foo(void); void foo(void) { }]])], [
1251 AM_CFLAGS="$AM_CFLAGS $NEW_FLAG"
1252 AC_MSG_RESULT([yes])
1253 ], [
1254 AC_MSG_RESULT([no])
1255 ])
1256 CFLAGS="$OLD_CFLAGS"
1257 done
1259 AC_ARG_ENABLE([werror],
1260 AS_HELP_STRING([--enable-werror], [Enable -Werror to abort
1261 compilation on all compiler warnings.]),
1262 [], [enable_werror=no])
1263 if test "x$enable_werror" = "xyes"; then
1264 AM_CFLAGS="$AM_CFLAGS -Werror"
1265 fi
1266 ])
1269 ###############################################################################
1270 # Create the makefiles and config.h
1271 ###############################################################################
1273 echo
1275 # Don't build the lib directory at all if we don't need any replacement
1276 # functions.
1277 AM_CONDITIONAL([COND_GNULIB], test -n "$LIBOBJS")
1279 # Add default AM_CFLAGS.
1280 AC_SUBST([AM_CFLAGS])
1282 # This is needed for src/scripts.
1283 xz=`echo xz | sed "$program_transform_name"`
1284 AC_SUBST([xz])
1286 AC_CONFIG_FILES([
1287 Makefile
1288 po/Makefile.in
1289 lib/Makefile
1290 src/Makefile
1291 src/liblzma/Makefile
1292 src/liblzma/api/Makefile
1293 src/xz/Makefile
1294 src/xzdec/Makefile
1295 src/lzmainfo/Makefile
1296 src/scripts/Makefile
1297 tests/Makefile
1298 debug/Makefile
1299 ])
1300 AC_CONFIG_FILES([src/scripts/xzdiff], [chmod +x src/scripts/xzdiff])
1301 AC_CONFIG_FILES([src/scripts/xzgrep], [chmod +x src/scripts/xzgrep])
1302 AC_CONFIG_FILES([src/scripts/xzmore], [chmod +x src/scripts/xzmore])
1303 AC_CONFIG_FILES([src/scripts/xzless], [chmod +x src/scripts/xzless])
1305 AC_OUTPUT
1307 # Some warnings
1308 if test x$tuklib_cv_physmem_method = xunknown; then
1309 echo
1310 echo "WARNING:"
1311 echo "No supported method to detect the amount of RAM."
1312 echo "Consider using --enable-assume-ram (if you didn't already)"
1313 echo "or make a patch to add support for this operating system."
1314 fi
1316 if test x$tuklib_cv_cpucores_method = xunknown; then
1317 echo
1318 echo "WARNING:"
1319 echo "No supported method to detect the number of CPU cores."
1320 fi
1322 if test "x$enable_threads$enable_small$have_func_attribute_constructor" \
1323 = xnoyesno; then
1324 echo
1325 echo "NOTE:"
1326 echo "liblzma will be thread-unsafe due to the combination"
1327 echo "of --disable-threads --enable-small when using a compiler"
1328 echo "that doesn't support __attribute__((__constructor__))."
1329 fi