m4/ax_pthread.m4

   1 dnl SPDX-License-Identifier: GPL-3.0-or-later WITH Autoconf-exception-macro
   2
   3 # ===========================================================================
   4 #        https://www.gnu.org/software/autoconf-archive/ax_pthread.html
   5 # ===========================================================================
   6 #
   7 # SYNOPSIS
   8 #
   9 #   AX_PTHREAD([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
  10 #
  11 # DESCRIPTION
  12 #
  13 #   This macro figures out how to build C programs using POSIX threads. It
  14 #   sets the PTHREAD_LIBS output variable to the threads library and linker
  15 #   flags, and the PTHREAD_CFLAGS output variable to any special C compiler
  16 #   flags that are needed. (The user can also force certain compiler
  17 #   flags/libs to be tested by setting these environment variables.)
  18 #
  19 #   Also sets PTHREAD_CC and PTHREAD_CXX to any special C compiler that is
  20 #   needed for multi-threaded programs (defaults to the value of CC
  21 #   respectively CXX otherwise). (This is necessary on e.g. AIX to use the
  22 #   special cc_r/CC_r compiler alias.)
  23 #
  24 #   NOTE: You are assumed to not only compile your program with these flags,
  25 #   but also to link with them as well. For example, you might link with
  26 #   $PTHREAD_CC $CFLAGS $PTHREAD_CFLAGS $LDFLAGS ... $PTHREAD_LIBS $LIBS
  27 #   $PTHREAD_CXX $CXXFLAGS $PTHREAD_CFLAGS $LDFLAGS ... $PTHREAD_LIBS $LIBS
  28 #
  29 #   If you are only building threaded programs, you may wish to use these
  30 #   variables in your default LIBS, CFLAGS, and CC:
  31 #
  32 #     LIBS="$PTHREAD_LIBS $LIBS"
  33 #     CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  34 #     CXXFLAGS="$CXXFLAGS $PTHREAD_CFLAGS"
  35 #     CC="$PTHREAD_CC"
  36 #     CXX="$PTHREAD_CXX"
  37 #
  38 #   In addition, if the PTHREAD_CREATE_JOINABLE thread-attribute constant
  39 #   has a nonstandard name, this macro defines PTHREAD_CREATE_JOINABLE to
  40 #   that name (e.g. PTHREAD_CREATE_UNDETACHED on AIX).
  41 #
  42 #   Also HAVE_PTHREAD_PRIO_INHERIT is defined if pthread is found and the
  43 #   PTHREAD_PRIO_INHERIT symbol is defined when compiling with
  44 #   PTHREAD_CFLAGS.
  45 #
  46 #   ACTION-IF-FOUND is a list of shell commands to run if a threads library
  47 #   is found, and ACTION-IF-NOT-FOUND is a list of commands to run it if it
  48 #   is not found. If ACTION-IF-FOUND is not specified, the default action
  49 #   will define HAVE_PTHREAD.
  50 #
  51 #   Please let the authors know if this macro fails on any platform, or if
  52 #   you have any other suggestions or comments. This macro was based on work
  53 #   by SGJ on autoconf scripts for FFTW (http://www.fftw.org/) (with help
  54 #   from M. Frigo), as well as ac_pthread and hb_pthread macros posted by
  55 #   Alejandro Forero Cuervo to the autoconf macro repository. We are also
  56 #   grateful for the helpful feedback of numerous users.
  57 #
  58 #   Updated for Autoconf 2.68 by Daniel Richard G.
  59 #
  60 # LICENSE
  61 #
  62 #   Copyright (c) 2008 Steven G. Johnson <stevenj@alum.mit.edu>
  63 #   Copyright (c) 2011 Daniel Richard G. <skunk@iSKUNK.ORG>
  64 #   Copyright (c) 2019 Marc Stevens <marc.stevens@cwi.nl>
  65 #
  66 #   This program is free software: you can redistribute it and/or modify it
  67 #   under the terms of the GNU General Public License as published by the
  68 #   Free Software Foundation, either version 3 of the License, or (at your
  69 #   option) any later version.
  70 #
  71 #   This program is distributed in the hope that it will be useful, but
  72 #   WITHOUT ANY WARRANTY; without even the implied warranty of
  73 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
  74 #   Public License for more details.
  75 #
  76 #   You should have received a copy of the GNU General Public License along
  77 #   with this program. If not, see <https://www.gnu.org/licenses/>.
  78 #
  79 #   As a special exception, the respective Autoconf Macro's copyright owner
  80 #   gives unlimited permission to copy, distribute and modify the configure
  81 #   scripts that are the output of Autoconf when processing the Macro. You
  82 #   need not follow the terms of the GNU General Public License when using
  83 #   or distributing such scripts, even though portions of the text of the
  84 #   Macro appear in them. The GNU General Public License (GPL) does govern
  85 #   all other use of the material that constitutes the Autoconf Macro.
  86 #
  87 #   This special exception to the GPL applies to versions of the Autoconf
  88 #   Macro released by the Autoconf Archive. When you make and distribute a
  89 #   modified version of the Autoconf Macro, you may extend this special
  90 #   exception to the GPL to apply to your modified version as well.
  91
  92 #serial 31
  93
  94 AU_ALIAS([ACX_PTHREAD], [AX_PTHREAD])
  95 AC_DEFUN([AX_PTHREAD], [
  96 AC_REQUIRE([AC_CANONICAL_HOST])
  97 AC_REQUIRE([AC_PROG_CC])
  98 AC_REQUIRE([AC_PROG_SED])
  99 AC_LANG_PUSH([C])
 100 ax_pthread_ok=no
 101
 102 # We used to check for pthread.h first, but this fails if pthread.h
 103 # requires special compiler flags (e.g. on Tru64 or Sequent).
 104 # It gets checked for in the link test anyway.
 105
 106 # First of all, check if the user has set any of the PTHREAD_LIBS,
 107 # etcetera environment variables, and if threads linking works using
 108 # them:
 109 if test "x$PTHREAD_CFLAGS$PTHREAD_LIBS" != "x"; then
 110         ax_pthread_save_CC="$CC"
 111         ax_pthread_save_CFLAGS="$CFLAGS"
 112         ax_pthread_save_LIBS="$LIBS"
 113         AS_IF([test "x$PTHREAD_CC" != "x"], [CC="$PTHREAD_CC"])
 114         AS_IF([test "x$PTHREAD_CXX" != "x"], [CXX="$PTHREAD_CXX"])
 115         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 116         LIBS="$PTHREAD_LIBS $LIBS"
 117         AC_MSG_CHECKING([for pthread_join using $CC $PTHREAD_CFLAGS $PTHREAD_LIBS])
 118         AC_LINK_IFELSE([AC_LANG_CALL([], [pthread_join])], [ax_pthread_ok=yes])
 119         AC_MSG_RESULT([$ax_pthread_ok])
 120         if test "x$ax_pthread_ok" = "xno"; then
 121                 PTHREAD_LIBS=""
 122                 PTHREAD_CFLAGS=""
 123         fi
 124         CC="$ax_pthread_save_CC"
 125         CFLAGS="$ax_pthread_save_CFLAGS"
 126         LIBS="$ax_pthread_save_LIBS"
 127 fi
 128
 129 # We must check for the threads library under a number of different
 130 # names; the ordering is very important because some systems
 131 # (e.g. DEC) have both -lpthread and -lpthreads, where one of the
 132 # libraries is broken (non-POSIX).
 133
 134 # Create a list of thread flags to try. Items with a "," contain both
 135 # C compiler flags (before ",") and linker flags (after ","). Other items
 136 # starting with a "-" are C compiler flags, and remaining items are
 137 # library names, except for "none" which indicates that we try without
 138 # any flags at all, and "pthread-config" which is a program returning
 139 # the flags for the Pth emulation library.
 140
 141 ax_pthread_flags="pthreads none -Kthread -pthread -pthreads -mthreads pthread --thread-safe -mt pthread-config"
 142
 143 # The ordering *is* (sometimes) important.  Some notes on the
 144 # individual items follow:
 145
 146 # pthreads: AIX (must check this before -lpthread)
 147 # none: in case threads are in libc; should be tried before -Kthread and
 148 #       other compiler flags to prevent continual compiler warnings
 149 # -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
 150 # -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads), Tru64
 151 #           (Note: HP C rejects this with "bad form for `-t' option")
 152 # -pthreads: Solaris/gcc (Note: HP C also rejects)
 153 # -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
 154 #      doesn't hurt to check since this sometimes defines pthreads and
 155 #      -D_REENTRANT too), HP C (must be checked before -lpthread, which
 156 #      is present but should not be used directly; and before -mthreads,
 157 #      because the compiler interprets this as "-mt" + "-hreads")
 158 # -mthreads: Mingw32/gcc, Lynx/gcc
 159 # pthread: Linux, etcetera
 160 # --thread-safe: KAI C++
 161 # pthread-config: use pthread-config program (for GNU Pth library)
 162
 163 case $host_os in
 164
 165         freebsd*)
 166
 167         # -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
 168         # lthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
 169
 170         ax_pthread_flags="-kthread lthread $ax_pthread_flags"
 171         ;;
 172
 173         hpux*)
 174
 175         # From the cc(1) man page: "[-mt] Sets various -D flags to enable
 176         # multi-threading and also sets -lpthread."
 177
 178         ax_pthread_flags="-mt -pthread pthread $ax_pthread_flags"
 179         ;;
 180
 181         openedition*)
 182
 183         # IBM z/OS requires a feature-test macro to be defined in order to
 184         # enable POSIX threads at all, so give the user a hint if this is
 185         # not set. (We don't define these ourselves, as they can affect
 186         # other portions of the system API in unpredictable ways.)
 187
 188         AC_EGREP_CPP([AX_PTHREAD_ZOS_MISSING],
 189             [
 190 #            if !defined(_OPEN_THREADS) && !defined(_UNIX03_THREADS)
 191              AX_PTHREAD_ZOS_MISSING
 192 #            endif
 193             ],
 194             [AC_MSG_WARN([IBM z/OS requires -D_OPEN_THREADS or -D_UNIX03_THREADS to enable pthreads support.])])
 195         ;;
 196
 197         solaris*)
 198
 199         # On Solaris (at least, for some versions), libc contains stubbed
 200         # (non-functional) versions of the pthreads routines, so link-based
 201         # tests will erroneously succeed. (N.B.: The stubs are missing
 202         # pthread_cleanup_push, or rather a function called by this macro,
 203         # so we could check for that, but who knows whether they'll stub
 204         # that too in a future libc.)  So we'll check first for the
 205         # standard Solaris way of linking pthreads (-mt -lpthread).
 206
 207         ax_pthread_flags="-mt,-lpthread pthread $ax_pthread_flags"
 208         ;;
 209 esac
 210
 211 # Are we compiling with Clang?
 212
 213 AC_CACHE_CHECK([whether $CC is Clang],
 214     [ax_cv_PTHREAD_CLANG],
 215     [ax_cv_PTHREAD_CLANG=no
 216      # Note that Autoconf sets GCC=yes for Clang as well as GCC
 217      if test "x$GCC" = "xyes"; then
 218         AC_EGREP_CPP([AX_PTHREAD_CC_IS_CLANG],
 219             [/* Note: Clang 2.7 lacks __clang_[a-z]+__ */
 220 #            if defined(__clang__) && defined(__llvm__)
 221              AX_PTHREAD_CC_IS_CLANG
 222 #            endif
 223             ],
 224             [ax_cv_PTHREAD_CLANG=yes])
 225      fi
 226     ])
 227 ax_pthread_clang="$ax_cv_PTHREAD_CLANG"
 228
 229
 230 # GCC generally uses -pthread, or -pthreads on some platforms (e.g. SPARC)
 231
 232 # Note that for GCC and Clang -pthread generally implies -lpthread,
 233 # except when -nostdlib is passed.
 234 # This is problematic using libtool to build C++ shared libraries with pthread:
 235 # [1] https://gcc.gnu.org/bugzilla/show_bug.cgi?id=25460
 236 # [2] https://bugzilla.redhat.com/show_bug.cgi?id=661333
 237 # [3] https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=468555
 238 # To solve this, first try -pthread together with -lpthread for GCC
 239
 240 AS_IF([test "x$GCC" = "xyes"],
 241       [ax_pthread_flags="-pthread,-lpthread -pthread -pthreads $ax_pthread_flags"])
 242
 243 # Clang takes -pthread (never supported any other flag), but we'll try with -lpthread first
 244
 245 AS_IF([test "x$ax_pthread_clang" = "xyes"],
 246       [ax_pthread_flags="-pthread,-lpthread -pthread"])
 247
 248
 249 # The presence of a feature test macro requesting re-entrant function
 250 # definitions is, on some systems, a strong hint that pthreads support is
 251 # correctly enabled
 252
 253 case $host_os in
 254         darwin* | hpux* | linux* | osf* | solaris*)
 255         ax_pthread_check_macro="_REENTRANT"
 256         ;;
 257
 258         aix*)
 259         ax_pthread_check_macro="_THREAD_SAFE"
 260         ;;
 261
 262         *)
 263         ax_pthread_check_macro="--"
 264         ;;
 265 esac
 266 AS_IF([test "x$ax_pthread_check_macro" = "x--"],
 267       [ax_pthread_check_cond=0],
 268       [ax_pthread_check_cond="!defined($ax_pthread_check_macro)"])
 269
 270
 271 if test "x$ax_pthread_ok" = "xno"; then
 272 for ax_pthread_try_flag in $ax_pthread_flags; do
 273
 274         case $ax_pthread_try_flag in
 275                 none)
 276                 AC_MSG_CHECKING([whether pthreads work without any flags])
 277                 ;;
 278
 279                 *,*)
 280                 PTHREAD_CFLAGS=`echo $ax_pthread_try_flag | sed "s/^\(.*\),\(.*\)$/\1/"`
 281                 PTHREAD_LIBS=`echo $ax_pthread_try_flag | sed "s/^\(.*\),\(.*\)$/\2/"`
 282                 AC_MSG_CHECKING([whether pthreads work with "$PTHREAD_CFLAGS" and "$PTHREAD_LIBS"])
 283                 ;;
 284
 285                 -*)
 286                 AC_MSG_CHECKING([whether pthreads work with $ax_pthread_try_flag])
 287                 PTHREAD_CFLAGS="$ax_pthread_try_flag"
 288                 ;;
 289
 290                 pthread-config)
 291                 AC_CHECK_PROG([ax_pthread_config], [pthread-config], [yes], [no])
 292                 AS_IF([test "x$ax_pthread_config" = "xno"], [continue])
 293                 PTHREAD_CFLAGS="`pthread-config --cflags`"
 294                 PTHREAD_LIBS="`pthread-config --ldflags` `pthread-config --libs`"
 295                 ;;
 296
 297                 *)
 298                 AC_MSG_CHECKING([for the pthreads library -l$ax_pthread_try_flag])
 299                 PTHREAD_LIBS="-l$ax_pthread_try_flag"
 300                 ;;
 301         esac
 302
 303         ax_pthread_save_CFLAGS="$CFLAGS"
 304         ax_pthread_save_LIBS="$LIBS"
 305         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 306         LIBS="$PTHREAD_LIBS $LIBS"
 307
 308         # Check for various functions.  We must include pthread.h,
 309         # since some functions may be macros.  (On the Sequent, we
 310         # need a special flag -Kthread to make this header compile.)
 311         # We check for pthread_join because it is in -lpthread on IRIX
 312         # while pthread_create is in libc.  We check for pthread_attr_init
 313         # due to DEC craziness with -lpthreads.  We check for
 314         # pthread_cleanup_push because it is one of the few pthread
 315         # functions on Solaris that doesn't have a non-functional libc stub.
 316         # We try pthread_create on general principles.
 317
 318         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <pthread.h>
 319 #                       if $ax_pthread_check_cond
 320 #                        error "$ax_pthread_check_macro must be defined"
 321 #                       endif
 322                         static void *some_global = NULL;
 323                         static void routine(void *a)
 324                           {
 325                              /* To avoid any unused-parameter or
 326                                 unused-but-set-parameter warning.  */
 327                              some_global = a;
 328                           }
 329                         static void *start_routine(void *a) { return a; }],
 330                        [pthread_t th; pthread_attr_t attr;
 331                         pthread_create(&th, 0, start_routine, 0);
 332                         pthread_join(th, 0);
 333                         pthread_attr_init(&attr);
 334                         pthread_cleanup_push(routine, 0);
 335                         pthread_cleanup_pop(0) /* ; */])],
 336             [ax_pthread_ok=yes],
 337             [])
 338
 339         CFLAGS="$ax_pthread_save_CFLAGS"
 340         LIBS="$ax_pthread_save_LIBS"
 341
 342         AC_MSG_RESULT([$ax_pthread_ok])
 343         AS_IF([test "x$ax_pthread_ok" = "xyes"], [break])
 344
 345         PTHREAD_LIBS=""
 346         PTHREAD_CFLAGS=""
 347 done
 348 fi
 349
 350
 351 # Clang needs special handling, because older versions handle the -pthread
 352 # option in a rather... idiosyncratic way
 353
 354 if test "x$ax_pthread_clang" = "xyes"; then
 355
 356         # Clang takes -pthread; it has never supported any other flag
 357
 358         # (Note 1: This will need to be revisited if a system that Clang
 359         # supports has POSIX threads in a separate library.  This tends not
 360         # to be the way of modern systems, but it's conceivable.)
 361
 362         # (Note 2: On some systems, notably Darwin, -pthread is not needed
 363         # to get POSIX threads support; the API is always present and
 364         # active.  We could reasonably leave PTHREAD_CFLAGS empty.  But
 365         # -pthread does define _REENTRANT, and while the Darwin headers
 366         # ignore this macro, third-party headers might not.)
 367
 368         # However, older versions of Clang make a point of warning the user
 369         # that, in an invocation where only linking and no compilation is
 370         # taking place, the -pthread option has no effect ("argument unused
 371         # during compilation").  They expect -pthread to be passed in only
 372         # when source code is being compiled.
 373         #
 374         # Problem is, this is at odds with the way Automake and most other
 375         # C build frameworks function, which is that the same flags used in
 376         # compilation (CFLAGS) are also used in linking.  Many systems
 377         # supported by AX_PTHREAD require exactly this for POSIX threads
 378         # support, and in fact it is often not straightforward to specify a
 379         # flag that is used only in the compilation phase and not in
 380         # linking.  Such a scenario is extremely rare in practice.
 381         #
 382         # Even though use of the -pthread flag in linking would only print
 383         # a warning, this can be a nuisance for well-run software projects
 384         # that build with -Werror.  So if the active version of Clang has
 385         # this misfeature, we search for an option to squash it.
 386
 387         AC_CACHE_CHECK([whether Clang needs flag to prevent "argument unused" warning when linking with -pthread],
 388             [ax_cv_PTHREAD_CLANG_NO_WARN_FLAG],
 389             [ax_cv_PTHREAD_CLANG_NO_WARN_FLAG=unknown
 390              # Create an alternate version of $ac_link that compiles and
 391              # links in two steps (.c -> .o, .o -> exe) instead of one
 392              # (.c -> exe), because the warning occurs only in the second
 393              # step
 394              ax_pthread_save_ac_link="$ac_link"
 395              ax_pthread_sed='s/conftest\.\$ac_ext/conftest.$ac_objext/g'
 396              ax_pthread_link_step=`AS_ECHO(["$ac_link"]) | sed "$ax_pthread_sed"`
 397              ax_pthread_2step_ac_link="($ac_compile) && (echo ==== >&5) && ($ax_pthread_link_step)"
 398              ax_pthread_save_CFLAGS="$CFLAGS"
 399              for ax_pthread_try in '' -Qunused-arguments -Wno-unused-command-line-argument unknown; do
 400                 AS_IF([test "x$ax_pthread_try" = "xunknown"], [break])
 401                 CFLAGS="-Werror -Wunknown-warning-option $ax_pthread_try -pthread $ax_pthread_save_CFLAGS"
 402                 ac_link="$ax_pthread_save_ac_link"
 403                 AC_LINK_IFELSE([AC_LANG_SOURCE([[int main(void){return 0;}]])],
 404                     [ac_link="$ax_pthread_2step_ac_link"
 405                      AC_LINK_IFELSE([AC_LANG_SOURCE([[int main(void){return 0;}]])],
 406                          [break])
 407                     ])
 408              done
 409              ac_link="$ax_pthread_save_ac_link"
 410              CFLAGS="$ax_pthread_save_CFLAGS"
 411              AS_IF([test "x$ax_pthread_try" = "x"], [ax_pthread_try=no])
 412              ax_cv_PTHREAD_CLANG_NO_WARN_FLAG="$ax_pthread_try"
 413             ])
 414
 415         case "$ax_cv_PTHREAD_CLANG_NO_WARN_FLAG" in
 416                 no | unknown) ;;
 417                 *) PTHREAD_CFLAGS="$ax_cv_PTHREAD_CLANG_NO_WARN_FLAG $PTHREAD_CFLAGS" ;;
 418         esac
 419
 420 fi # $ax_pthread_clang = yes
 421
 422
 423
 424 # Various other checks:
 425 if test "x$ax_pthread_ok" = "xyes"; then
 426         ax_pthread_save_CFLAGS="$CFLAGS"
 427         ax_pthread_save_LIBS="$LIBS"
 428         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 429         LIBS="$PTHREAD_LIBS $LIBS"
 430
 431         # Detect AIX lossage: JOINABLE attribute is called UNDETACHED.
 432         AC_CACHE_CHECK([for joinable pthread attribute],
 433             [ax_cv_PTHREAD_JOINABLE_ATTR],
 434             [ax_cv_PTHREAD_JOINABLE_ATTR=unknown
 435              for ax_pthread_attr in PTHREAD_CREATE_JOINABLE PTHREAD_CREATE_UNDETACHED; do
 436                  AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <pthread.h>],
 437                                                  [int attr = $ax_pthread_attr; return attr /* ; */])],
 438                                 [ax_cv_PTHREAD_JOINABLE_ATTR=$ax_pthread_attr; break],
 439                                 [])
 440              done
 441             ])
 442         AS_IF([test "x$ax_cv_PTHREAD_JOINABLE_ATTR" != "xunknown" && \
 443                test "x$ax_cv_PTHREAD_JOINABLE_ATTR" != "xPTHREAD_CREATE_JOINABLE" && \
 444                test "x$ax_pthread_joinable_attr_defined" != "xyes"],
 445               [AC_DEFINE_UNQUOTED([PTHREAD_CREATE_JOINABLE],
 446                                   [$ax_cv_PTHREAD_JOINABLE_ATTR],
 447                                   [Define to necessary symbol if this constant
 448                                    uses a non-standard name on your system.])
 449                ax_pthread_joinable_attr_defined=yes
 450               ])
 451
 452         AC_CACHE_CHECK([whether more special flags are required for pthreads],
 453             [ax_cv_PTHREAD_SPECIAL_FLAGS],
 454             [ax_cv_PTHREAD_SPECIAL_FLAGS=no
 455              case $host_os in
 456              solaris*)
 457              ax_cv_PTHREAD_SPECIAL_FLAGS="-D_POSIX_PTHREAD_SEMANTICS"
 458              ;;
 459              esac
 460             ])
 461         AS_IF([test "x$ax_cv_PTHREAD_SPECIAL_FLAGS" != "xno" && \
 462                test "x$ax_pthread_special_flags_added" != "xyes"],
 463               [PTHREAD_CFLAGS="$ax_cv_PTHREAD_SPECIAL_FLAGS $PTHREAD_CFLAGS"
 464                ax_pthread_special_flags_added=yes])
 465
 466         AC_CACHE_CHECK([for PTHREAD_PRIO_INHERIT],
 467             [ax_cv_PTHREAD_PRIO_INHERIT],
 468             [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]],
 469                                              [[int i = PTHREAD_PRIO_INHERIT;
 470                                                return i;]])],
 471                             [ax_cv_PTHREAD_PRIO_INHERIT=yes],
 472                             [ax_cv_PTHREAD_PRIO_INHERIT=no])
 473             ])
 474         AS_IF([test "x$ax_cv_PTHREAD_PRIO_INHERIT" = "xyes" && \
 475                test "x$ax_pthread_prio_inherit_defined" != "xyes"],
 476               [AC_DEFINE([HAVE_PTHREAD_PRIO_INHERIT], [1], [Have PTHREAD_PRIO_INHERIT.])
 477                ax_pthread_prio_inherit_defined=yes
 478               ])
 479
 480         CFLAGS="$ax_pthread_save_CFLAGS"
 481         LIBS="$ax_pthread_save_LIBS"
 482
 483         # More AIX lossage: compile with *_r variant
 484         if test "x$GCC" != "xyes"; then
 485             case $host_os in
 486                 aix*)
 487                 AS_CASE(["x/$CC"],
 488                     [x*/c89|x*/c89_128|x*/c99|x*/c99_128|x*/cc|x*/cc128|x*/xlc|x*/xlc_v6|x*/xlc128|x*/xlc128_v6],
 489                     [#handle absolute path differently from PATH based program lookup
 490                      AS_CASE(["x$CC"],
 491                          [x/*],
 492                          [
 493                            AS_IF([AS_EXECUTABLE_P([${CC}_r])],[PTHREAD_CC="${CC}_r"])
 494                            AS_IF([test "x${CXX}" != "x"], [AS_IF([AS_EXECUTABLE_P([${CXX}_r])],[PTHREAD_CXX="${CXX}_r"])])
 495                          ],
 496                          [
 497                            AC_CHECK_PROGS([PTHREAD_CC],[${CC}_r],[$CC])
 498                            AS_IF([test "x${CXX}" != "x"], [AC_CHECK_PROGS([PTHREAD_CXX],[${CXX}_r],[$CXX])])
 499                          ]
 500                      )
 501                     ])
 502                 ;;
 503             esac
 504         fi
 505 fi
 506
 507 test -n "$PTHREAD_CC" || PTHREAD_CC="$CC"
 508 test -n "$PTHREAD_CXX" || PTHREAD_CXX="$CXX"
 509
 510 AC_SUBST([PTHREAD_LIBS])
 511 AC_SUBST([PTHREAD_CFLAGS])
 512 AC_SUBST([PTHREAD_CC])
 513 AC_SUBST([PTHREAD_CXX])
 514
 515 # Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
 516 if test "x$ax_pthread_ok" = "xyes"; then
 517         ifelse([$1],,[AC_DEFINE([HAVE_PTHREAD],[1],[Define if you have POSIX threads libraries and header files.])],[$1])
 518         :
 519 else
 520         ax_pthread_ok=no
 521         $2
 522 fi
 523 AC_LANG_POP
 524 ])dnl AX_PTHREAD