yosql-examples/yosql-examples-gradle/yosql-examples-gradle-jdbc-java16/build.gradle.kts

   1 /*
   2  * This file is part of yosql. It is subject to the license terms in the LICENSE file found in the top-level
   3  * directory of this distribution and at https://creativecommons.org/publicdomain/zero/1.0/. No part of yosql,
   4  * including this file, may be copied, modified, propagated, or distributed except according to the terms contained
   5  * in the LICENSE file.
   6  */
   7
   8 plugins {
   9     java
  10     application
  11     id("wtf.metio.yosql")
  12 }
  13
  14 java {
  15     toolchain {
  16         languageVersion.set(JavaLanguageVersion.of(16))
  17     }
  18 }
  19
  20 application {
  21     mainClass.set("${group}.ExampleApp")
  22 }
  23
  24 yosql {
  25     files {
  26         skipLines.set(6)
  27         inputBaseDirectory.set(project.file("../../yosql-examples-common/src/main/yosql"))
  28     }
  29     repositories {
  30         basePackageName.set("${group}.persistence")
  31     }
  32     java {
  33         apiVersion.set(16)
  34     }
  35     converter {
  36         mapConverterClass.set("${group}.converter.ToMapConverter")
  37         rowConverters {
  38             register("itemConverter") {
  39                 converterType.set("${group}.converter.ToItemConverter")
  40                 methodName.set("asUserType")
  41                 resultType.set("${group}.model.Item")
  42             }
  43         }
  44     }
  45 }
  46
  47 dependencies {
  48     implementation(libs.bundles.database) {
  49         because("we need database access")
  50     }
  51     implementation("wtf.metio.yosql.examples:yosql-examples-common:${version}") {
  52         because("we want to re-use the same example app across all example projects")
  53     }
  54 }