arch/m68k/kernel/vmlinux-std.lds

   1 /* ld script to make m68k Linux kernel */
   2
   3 #include <asm-generic/vmlinux.lds.h>
   4 #include <asm/page.h>
   5 #include <asm/thread_info.h>
   6
   7 OUTPUT_FORMAT("elf32-m68k", "elf32-m68k", "elf32-m68k")
   8 OUTPUT_ARCH(m68k)
   9 ENTRY(_start)
  10 jiffies = jiffies_64 + 4;
  11 SECTIONS
  12 {
  13   . = 0x1000;
  14   _text = .;                    /* Text and read-only data */
  15   .text : {
  16         HEAD_TEXT
  17         TEXT_TEXT
  18         SCHED_TEXT
  19         LOCK_TEXT
  20         *(.fixup)
  21         *(.gnu.warning)
  22         } :text = 0x4e75
  23
  24   _etext = .;                   /* End of text section */
  25
  26   EXCEPTION_TABLE(16)
  27
  28   _sdata = .;                   /* Start of data section */
  29
  30   RODATA
  31
  32   RW_DATA_SECTION(16, PAGE_SIZE, THREAD_SIZE)
  33
  34   _sbss = .;
  35   BSS_SECTION(0, 0, 0)
  36   _ebss = .;
  37
  38   _edata = .;                   /* End of data section */
  39
  40   /* will be freed after init */
  41   . = ALIGN(PAGE_SIZE);         /* Init code and data */
  42   __init_begin = .;
  43   INIT_TEXT_SECTION(PAGE_SIZE) :data
  44   INIT_DATA_SECTION(16)
  45   .m68k_fixup : {
  46         __start_fixup = .;
  47         *(.m68k_fixup)
  48         __stop_fixup = .;
  49   }
  50   NOTES
  51   .init_end : {
  52         /* This ALIGN be in a section so that _end is at the end of the
  53            load segment. */
  54         . = ALIGN(PAGE_SIZE);
  55         __init_end = .;
  56   }
  57
  58   _end = . ;
  59
  60   STABS_DEBUG
  61   .comment 0 : { *(.comment) }
  62
  63   /* Sections to be discarded */
  64   DISCARDS
  65 }