arch/sparc/kernel/sys32.S

   1 /*
   2  * sys32.S: I-cache tricks for 32-bit compatibility layer simple
   3  *          conversions.
   4  *
   5  * Copyright (C) 1997 David S. Miller (davem@caip.rutgers.edu)
   6  * Copyright (C) 1998 Jakub Jelinek   (jj@ultra.linux.cz)
   7  */
   8
   9 #include <asm/errno.h>
  10
  11 /* NOTE: call as jump breaks return stack, we have to avoid that */
  12
  13         .text
  14
  15 #define SIGN1(STUB,SYSCALL,REG1) \
  16         .align  32; \
  17         .globl  STUB; \
  18 STUB:   sethi   %hi(SYSCALL), %g1; \
  19         jmpl    %g1 + %lo(SYSCALL), %g0; \
  20         sra     REG1, 0, REG1
  21
  22 #define SIGN2(STUB,SYSCALL,REG1,REG2) \
  23         .align  32; \
  24         .globl  STUB; \
  25 STUB:   sethi   %hi(SYSCALL), %g1; \
  26         sra     REG1, 0, REG1; \
  27         jmpl    %g1 + %lo(SYSCALL), %g0; \
  28         sra     REG2, 0, REG2
  29
  30 #define SIGN3(STUB,SYSCALL,REG1,REG2,REG3) \
  31         .align  32; \
  32         .globl  STUB; \
  33 STUB:   sra     REG1, 0, REG1; \
  34         sethi   %hi(SYSCALL), %g1; \
  35         sra     REG2, 0, REG2; \
  36         jmpl    %g1 + %lo(SYSCALL), %g0; \
  37         sra     REG3, 0, REG3
  38
  39 #define SIGN4(STUB,SYSCALL,REG1,REG2,REG3,REG4) \
  40         .align  32; \
  41         .globl  STUB; \
  42 STUB:   sra     REG1, 0, REG1; \
  43         sethi   %hi(SYSCALL), %g1; \
  44         sra     REG2, 0, REG2; \
  45         sra     REG3, 0, REG3; \
  46         jmpl    %g1 + %lo(SYSCALL), %g0; \
  47         sra     REG4, 0, REG4
  48
  49 SIGN1(sys32_exit, sparc_exit, %o0)
  50 SIGN1(sys32_exit_group, sys_exit_group, %o0)
  51 SIGN1(sys32_wait4, compat_sys_wait4, %o2)
  52 SIGN1(sys32_creat, sys_creat, %o1)
  53 SIGN1(sys32_mknod, sys_mknod, %o1)
  54 SIGN1(sys32_umount, sys_umount, %o1)
  55 SIGN1(sys32_signal, sys_signal, %o0)
  56 SIGN1(sys32_access, sys_access, %o1)
  57 SIGN1(sys32_msync, sys_msync, %o2)
  58 SIGN2(sys32_reboot, sys_reboot, %o0, %o1)
  59 SIGN1(sys32_setitimer, compat_sys_setitimer, %o0)
  60 SIGN1(sys32_getitimer, compat_sys_getitimer, %o0)
  61 SIGN1(sys32_sethostname, sys_sethostname, %o1)
  62 SIGN1(sys32_swapon, sys_swapon, %o1)
  63 SIGN1(sys32_sigaction, compat_sys_sigaction, %o0)
  64 SIGN1(sys32_rt_sigaction, compat_sys_rt_sigaction, %o0)
  65 SIGN1(sys32_sigprocmask, compat_sys_sigprocmask, %o0)
  66 SIGN1(sys32_rt_sigprocmask, compat_sys_rt_sigprocmask, %o0)
  67 SIGN2(sys32_rt_sigqueueinfo, compat_sys_rt_sigqueueinfo, %o0, %o1)
  68 SIGN1(sys32_getrusage, compat_sys_getrusage, %o0)
  69 SIGN1(sys32_setxattr, sys_setxattr, %o4)
  70 SIGN1(sys32_lsetxattr, sys_lsetxattr, %o4)
  71 SIGN1(sys32_fsetxattr, sys_fsetxattr, %o4)
  72 SIGN1(sys32_fgetxattr, sys_fgetxattr, %o0)
  73 SIGN1(sys32_flistxattr, sys_flistxattr, %o0)
  74 SIGN1(sys32_fremovexattr, sys_fremovexattr, %o0)
  75 SIGN2(sys32_tkill, sys_tkill, %o0, %o1)
  76 SIGN1(sys32_epoll_create, sys_epoll_create, %o0)
  77 SIGN3(sys32_epoll_ctl, sys_epoll_ctl, %o0, %o1, %o2)
  78 SIGN3(sys32_epoll_wait, sys_epoll_wait, %o0, %o2, %o3)
  79 SIGN1(sys32_readahead, compat_sys_readahead, %o0)
  80 SIGN2(sys32_fadvise64, compat_sys_fadvise64, %o0, %o4)
  81 SIGN2(sys32_fadvise64_64, compat_sys_fadvise64_64, %o0, %o5)
  82 SIGN2(sys32_bdflush, sys_bdflush, %o0, %o1)
  83 SIGN1(sys32_mlockall, sys_mlockall, %o0)
  84 SIGN1(sys32_clock_nanosleep, compat_sys_clock_nanosleep, %o1)
  85 SIGN1(sys32_timer_settime, compat_sys_timer_settime, %o1)
  86 SIGN1(sys32_io_submit, compat_sys_io_submit, %o1)
  87 SIGN1(sys32_mq_open, compat_sys_mq_open, %o1)
  88 SIGN1(sys32_select, compat_sys_select, %o0)
  89 SIGN1(sys32_mkdir, sys_mkdir, %o1)
  90 SIGN3(sys32_futex, compat_sys_futex, %o1, %o2, %o5)
  91 SIGN1(sys32_sysfs, compat_sys_sysfs, %o0)
  92 SIGN2(sys32_sendfile, compat_sys_sendfile, %o0, %o1)
  93 SIGN2(sys32_sendfile64, compat_sys_sendfile64, %o0, %o1)
  94 SIGN1(sys32_prctl, sys_prctl, %o0)
  95 SIGN1(sys32_sched_rr_get_interval, compat_sys_sched_rr_get_interval, %o0)
  96 SIGN2(sys32_waitpid, sys_waitpid, %o0, %o2)
  97 SIGN1(sys32_getgroups, sys_getgroups, %o0)
  98 SIGN1(sys32_getpgid, sys_getpgid, %o0)
  99 SIGN2(sys32_getpriority, sys_getpriority, %o0, %o1)
 100 SIGN1(sys32_getsid, sys_getsid, %o0)
 101 SIGN2(sys32_kill, sys_kill, %o0, %o1)
 102 SIGN1(sys32_nice, sys_nice, %o0)
 103 SIGN1(sys32_lseek, sys_lseek, %o1)
 104 SIGN2(sys32_open, sparc32_open, %o1, %o2)
 105 SIGN1(sys32_readlink, sys_readlink, %o2)
 106 SIGN1(sys32_sched_get_priority_max, sys_sched_get_priority_max, %o0)
 107 SIGN1(sys32_sched_get_priority_min, sys_sched_get_priority_min, %o0)
 108 SIGN1(sys32_sched_getparam, sys_sched_getparam, %o0)
 109 SIGN1(sys32_sched_getscheduler, sys_sched_getscheduler, %o0)
 110 SIGN1(sys32_sched_setparam, sys_sched_setparam, %o0)
 111 SIGN2(sys32_sched_setscheduler, sys_sched_setscheduler, %o0, %o1)
 112 SIGN1(sys32_getdomainname, sys_getdomainname, %o1)
 113 SIGN1(sys32_setdomainname, sys_setdomainname, %o1)
 114 SIGN1(sys32_setgroups, sys_setgroups, %o0)
 115 SIGN2(sys32_setpgid, sys_setpgid, %o0, %o1)
 116 SIGN3(sys32_setpriority, sys_setpriority, %o0, %o1, %o2)
 117 SIGN1(sys32_ssetmask, sys_ssetmask, %o0)
 118 SIGN2(sys32_syslog, sys_syslog, %o0, %o2)
 119 SIGN1(sys32_umask, sys_umask, %o0)
 120 SIGN3(sys32_tgkill, sys_tgkill, %o0, %o1, %o2)
 121 SIGN1(sys32_sendto, sys_sendto, %o0)
 122 SIGN1(sys32_recvfrom, compat_sys_recvfrom, %o0)
 123 SIGN3(sys32_socket, sys_socket, %o0, %o1, %o2)
 124 SIGN2(sys32_connect, sys_connect, %o0, %o2)
 125 SIGN2(sys32_bind, sys_bind, %o0, %o2)
 126 SIGN2(sys32_listen, sys_listen, %o0, %o1)
 127 SIGN1(sys32_recvmsg, compat_sys_recvmsg, %o0)
 128 SIGN1(sys32_sendmsg, compat_sys_sendmsg, %o0)
 129 SIGN2(sys32_shutdown, sys_shutdown, %o0, %o1)
 130 SIGN3(sys32_socketpair, sys_socketpair, %o0, %o1, %o2)
 131 SIGN1(sys32_getpeername, sys_getpeername, %o0)
 132 SIGN1(sys32_getsockname, sys_getsockname, %o0)
 133 SIGN2(sys32_ioprio_get, sys_ioprio_get, %o0, %o1)
 134 SIGN3(sys32_ioprio_set, sys_ioprio_set, %o0, %o1, %o2)
 135 SIGN2(sys32_splice, sys_splice, %o0, %o2)
 136 SIGN2(sys32_sync_file_range, compat_sync_file_range, %o0, %o5)
 137 SIGN2(sys32_tee, sys_tee, %o0, %o1)
 138 SIGN1(sys32_vmsplice, compat_sys_vmsplice, %o0)
 139 SIGN1(sys32_truncate, sys_truncate, %o1)
 140 SIGN1(sys32_ftruncate, sys_ftruncate, %o1)
 141
 142         .globl          sys32_mmap2
 143 sys32_mmap2:
 144         sethi           %hi(sys_mmap), %g1
 145         jmpl            %g1 + %lo(sys_mmap), %g0
 146          sllx           %o5, 12, %o5
 147
 148         .align          32
 149         .globl          sys32_socketcall
 150 sys32_socketcall:       /* %o0=call, %o1=args */
 151         cmp             %o0, 1
 152         bl,pn           %xcc, do_einval
 153          cmp            %o0, 18
 154         bg,pn           %xcc, do_einval
 155          sub            %o0, 1, %o0
 156         sllx            %o0, 5, %o0
 157         sethi           %hi(__socketcall_table_begin), %g2
 158         or              %g2, %lo(__socketcall_table_begin), %g2
 159         jmpl            %g2 + %o0, %g0
 160          nop
 161 do_einval:
 162         retl
 163          mov            -EINVAL, %o0
 164
 165         .align          32
 166 __socketcall_table_begin:
 167
 168         /* Each entry is exactly 32 bytes. */
 169 do_sys_socket: /* sys_socket(int, int, int) */
 170 1:      ldswa           [%o1 + 0x0] %asi, %o0
 171         sethi           %hi(sys_socket), %g1
 172 2:      ldswa           [%o1 + 0x8] %asi, %o2
 173         jmpl            %g1 + %lo(sys_socket), %g0
 174 3:       ldswa          [%o1 + 0x4] %asi, %o1
 175         nop
 176         nop
 177         nop
 178 do_sys_bind: /* sys_bind(int fd, struct sockaddr *, int) */
 179 4:      ldswa           [%o1 + 0x0] %asi, %o0
 180         sethi           %hi(sys_bind), %g1
 181 5:      ldswa           [%o1 + 0x8] %asi, %o2
 182         jmpl            %g1 + %lo(sys_bind), %g0
 183 6:       lduwa          [%o1 + 0x4] %asi, %o1
 184         nop
 185         nop
 186         nop
 187 do_sys_connect: /* sys_connect(int, struct sockaddr *, int) */
 188 7:      ldswa           [%o1 + 0x0] %asi, %o0
 189         sethi           %hi(sys_connect), %g1
 190 8:      ldswa           [%o1 + 0x8] %asi, %o2
 191         jmpl            %g1 + %lo(sys_connect), %g0
 192 9:       lduwa          [%o1 + 0x4] %asi, %o1
 193         nop
 194         nop
 195         nop
 196 do_sys_listen: /* sys_listen(int, int) */
 197 10:     ldswa           [%o1 + 0x0] %asi, %o0
 198         sethi           %hi(sys_listen), %g1
 199         jmpl            %g1 + %lo(sys_listen), %g0
 200 11:      ldswa          [%o1 + 0x4] %asi, %o1
 201         nop
 202         nop
 203         nop
 204         nop
 205 do_sys_accept: /* sys_accept(int, struct sockaddr *, int *) */
 206 12:     ldswa           [%o1 + 0x0] %asi, %o0
 207         sethi           %hi(sys_accept), %g1
 208 13:     lduwa           [%o1 + 0x8] %asi, %o2
 209         jmpl            %g1 + %lo(sys_accept), %g0
 210 14:      lduwa          [%o1 + 0x4] %asi, %o1
 211         nop
 212         nop
 213         nop
 214 do_sys_getsockname: /* sys_getsockname(int, struct sockaddr *, int *) */
 215 15:     ldswa           [%o1 + 0x0] %asi, %o0
 216         sethi           %hi(sys_getsockname), %g1
 217 16:     lduwa           [%o1 + 0x8] %asi, %o2
 218         jmpl            %g1 + %lo(sys_getsockname), %g0
 219 17:      lduwa          [%o1 + 0x4] %asi, %o1
 220         nop
 221         nop
 222         nop
 223 do_sys_getpeername: /* sys_getpeername(int, struct sockaddr *, int *) */
 224 18:     ldswa           [%o1 + 0x0] %asi, %o0
 225         sethi           %hi(sys_getpeername), %g1
 226 19:     lduwa           [%o1 + 0x8] %asi, %o2
 227         jmpl            %g1 + %lo(sys_getpeername), %g0
 228 20:      lduwa          [%o1 + 0x4] %asi, %o1
 229         nop
 230         nop
 231         nop
 232 do_sys_socketpair: /* sys_socketpair(int, int, int, int *) */
 233 21:     ldswa           [%o1 + 0x0] %asi, %o0
 234         sethi           %hi(sys_socketpair), %g1
 235 22:     ldswa           [%o1 + 0x8] %asi, %o2
 236 23:     lduwa           [%o1 + 0xc] %asi, %o3
 237         jmpl            %g1 + %lo(sys_socketpair), %g0
 238 24:      ldswa          [%o1 + 0x4] %asi, %o1
 239         nop
 240         nop
 241 do_sys_send: /* sys_send(int, void *, size_t, unsigned int) */
 242 25:     ldswa           [%o1 + 0x0] %asi, %o0
 243         sethi           %hi(sys_send), %g1
 244 26:     lduwa           [%o1 + 0x8] %asi, %o2
 245 27:     lduwa           [%o1 + 0xc] %asi, %o3
 246         jmpl            %g1 + %lo(sys_send), %g0
 247 28:      lduwa          [%o1 + 0x4] %asi, %o1
 248         nop
 249         nop
 250 do_sys_recv: /* sys_recv(int, void *, size_t, unsigned int) */
 251 29:     ldswa           [%o1 + 0x0] %asi, %o0
 252         sethi           %hi(sys_recv), %g1
 253 30:     lduwa           [%o1 + 0x8] %asi, %o2
 254 31:     lduwa           [%o1 + 0xc] %asi, %o3
 255         jmpl            %g1 + %lo(sys_recv), %g0
 256 32:      lduwa          [%o1 + 0x4] %asi, %o1
 257         nop
 258         nop
 259 do_sys_sendto: /* sys_sendto(int, u32, compat_size_t, unsigned int, u32, int) */
 260 33:     ldswa           [%o1 + 0x0] %asi, %o0
 261         sethi           %hi(sys_sendto), %g1
 262 34:     lduwa           [%o1 + 0x8] %asi, %o2
 263 35:     lduwa           [%o1 + 0xc] %asi, %o3
 264 36:     lduwa           [%o1 + 0x10] %asi, %o4
 265 37:     ldswa           [%o1 + 0x14] %asi, %o5
 266         jmpl            %g1 + %lo(sys_sendto), %g0
 267 38:      lduwa          [%o1 + 0x4] %asi, %o1
 268 do_sys_recvfrom: /* sys_recvfrom(int, u32, compat_size_t, unsigned int, u32, u32) */
 269 39:     ldswa           [%o1 + 0x0] %asi, %o0
 270         sethi           %hi(sys_recvfrom), %g1
 271 40:     lduwa           [%o1 + 0x8] %asi, %o2
 272 41:     lduwa           [%o1 + 0xc] %asi, %o3
 273 42:     lduwa           [%o1 + 0x10] %asi, %o4
 274 43:     lduwa           [%o1 + 0x14] %asi, %o5
 275         jmpl            %g1 + %lo(sys_recvfrom), %g0
 276 44:      lduwa          [%o1 + 0x4] %asi, %o1
 277 do_sys_shutdown: /* sys_shutdown(int, int) */
 278 45:     ldswa           [%o1 + 0x0] %asi, %o0
 279         sethi           %hi(sys_shutdown), %g1
 280         jmpl            %g1 + %lo(sys_shutdown), %g0
 281 46:      ldswa          [%o1 + 0x4] %asi, %o1
 282         nop
 283         nop
 284         nop
 285         nop
 286 do_sys_setsockopt: /* compat_sys_setsockopt(int, int, int, char *, int) */
 287 47:     ldswa           [%o1 + 0x0] %asi, %o0
 288         sethi           %hi(compat_sys_setsockopt), %g1
 289 48:     ldswa           [%o1 + 0x8] %asi, %o2
 290 49:     lduwa           [%o1 + 0xc] %asi, %o3
 291 50:     ldswa           [%o1 + 0x10] %asi, %o4
 292         jmpl            %g1 + %lo(compat_sys_setsockopt), %g0
 293 51:      ldswa          [%o1 + 0x4] %asi, %o1
 294         nop
 295 do_sys_getsockopt: /* compat_sys_getsockopt(int, int, int, u32, u32) */
 296 52:     ldswa           [%o1 + 0x0] %asi, %o0
 297         sethi           %hi(compat_sys_getsockopt), %g1
 298 53:     ldswa           [%o1 + 0x8] %asi, %o2
 299 54:     lduwa           [%o1 + 0xc] %asi, %o3
 300 55:     lduwa           [%o1 + 0x10] %asi, %o4
 301         jmpl            %g1 + %lo(compat_sys_getsockopt), %g0
 302 56:      ldswa          [%o1 + 0x4] %asi, %o1
 303         nop
 304 do_sys_sendmsg: /* compat_sys_sendmsg(int, struct compat_msghdr *, unsigned int) */
 305 57:     ldswa           [%o1 + 0x0] %asi, %o0
 306         sethi           %hi(compat_sys_sendmsg), %g1
 307 58:     lduwa           [%o1 + 0x8] %asi, %o2
 308         jmpl            %g1 + %lo(compat_sys_sendmsg), %g0
 309 59:      lduwa          [%o1 + 0x4] %asi, %o1
 310         nop
 311         nop
 312         nop
 313 do_sys_recvmsg: /* compat_sys_recvmsg(int, struct compat_msghdr *, unsigned int) */
 314 60:     ldswa           [%o1 + 0x0] %asi, %o0
 315         sethi           %hi(compat_sys_recvmsg), %g1
 316 61:     lduwa           [%o1 + 0x8] %asi, %o2
 317         jmpl            %g1 + %lo(compat_sys_recvmsg), %g0
 318 62:      lduwa          [%o1 + 0x4] %asi, %o1
 319         nop
 320         nop
 321         nop
 322 do_sys_accept4: /* sys_accept4(int, struct sockaddr *, int *, int) */
 323 63:     ldswa           [%o1 + 0x0] %asi, %o0
 324         sethi           %hi(sys_accept4), %g1
 325 64:     lduwa           [%o1 + 0x8] %asi, %o2
 326 65:     ldswa           [%o1 + 0xc] %asi, %o3
 327         jmpl            %g1 + %lo(sys_accept4), %g0
 328 66:      lduwa          [%o1 + 0x4] %asi, %o1
 329         nop
 330         nop
 331
 332         .globl          sys32_fanotify_mark
 333 sys32_fanotify_mark:
 334         sethi           %hi(sys_fanotify_mark), %g1
 335         sllx            %o2, 32, %o2
 336         or              %o2, %o3, %o2
 337         mov             %o4, %o3
 338         jmpl            %g1 + %lo(sys_fanotify_mark), %g0
 339          mov            %o5, %o4
 340
 341         .section        __ex_table,"a"
 342         .align          4
 343         .word           1b, __retl_efault, 2b, __retl_efault
 344         .word           3b, __retl_efault, 4b, __retl_efault
 345         .word           5b, __retl_efault, 6b, __retl_efault
 346         .word           7b, __retl_efault, 8b, __retl_efault
 347         .word           9b, __retl_efault, 10b, __retl_efault
 348         .word           11b, __retl_efault, 12b, __retl_efault
 349         .word           13b, __retl_efault, 14b, __retl_efault
 350         .word           15b, __retl_efault, 16b, __retl_efault
 351         .word           17b, __retl_efault, 18b, __retl_efault
 352         .word           19b, __retl_efault, 20b, __retl_efault
 353         .word           21b, __retl_efault, 22b, __retl_efault
 354         .word           23b, __retl_efault, 24b, __retl_efault
 355         .word           25b, __retl_efault, 26b, __retl_efault
 356         .word           27b, __retl_efault, 28b, __retl_efault
 357         .word           29b, __retl_efault, 30b, __retl_efault
 358         .word           31b, __retl_efault, 32b, __retl_efault
 359         .word           33b, __retl_efault, 34b, __retl_efault
 360         .word           35b, __retl_efault, 36b, __retl_efault
 361         .word           37b, __retl_efault, 38b, __retl_efault
 362         .word           39b, __retl_efault, 40b, __retl_efault
 363         .word           41b, __retl_efault, 42b, __retl_efault
 364         .word           43b, __retl_efault, 44b, __retl_efault
 365         .word           45b, __retl_efault, 46b, __retl_efault
 366         .word           47b, __retl_efault, 48b, __retl_efault
 367         .word           49b, __retl_efault, 50b, __retl_efault
 368         .word           51b, __retl_efault, 52b, __retl_efault
 369         .word           53b, __retl_efault, 54b, __retl_efault
 370         .word           55b, __retl_efault, 56b, __retl_efault
 371         .word           57b, __retl_efault, 58b, __retl_efault
 372         .word           59b, __retl_efault, 60b, __retl_efault
 373         .word           61b, __retl_efault, 62b, __retl_efault
 374         .word           63b, __retl_efault, 64b, __retl_efault
 375         .word           65b, __retl_efault, 66b, __retl_efault
 376         .previous