arch/arm/kernel/vmlinux.lds.S

   1 /* ld script to make ARM Linux kernel
   2  * taken from the i386 version by Russell King
   3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   4  */
   5
   6 #include <asm-generic/vmlinux.lds.h>
   7 #include <asm/cache.h>
   8 #include <asm/thread_info.h>
   9 #include <asm/memory.h>
  10 #include <asm/page.h>
  11
  12 #define PROC_INFO                                                       \
  13         . = ALIGN(4);                                                   \
  14         VMLINUX_SYMBOL(__proc_info_begin) = .;                          \
  15         *(.proc.info.init)                                              \
  16         VMLINUX_SYMBOL(__proc_info_end) = .;
  17
  18 #define IDMAP_TEXT                                                      \
  19         ALIGN_FUNCTION();                                               \
  20         VMLINUX_SYMBOL(__idmap_text_start) = .;                         \
  21         *(.idmap.text)                                                  \
  22         VMLINUX_SYMBOL(__idmap_text_end) = .;
  23
  24 #ifdef CONFIG_HOTPLUG_CPU
  25 #define ARM_CPU_DISCARD(x)
  26 #define ARM_CPU_KEEP(x)         x
  27 #else
  28 #define ARM_CPU_DISCARD(x)      x
  29 #define ARM_CPU_KEEP(x)
  30 #endif
  31
  32 #if (defined(CONFIG_SMP_ON_UP) && !defined(CONFIG_DEBUG_SPINLOCK)) || \
  33         defined(CONFIG_GENERIC_BUG)
  34 #define ARM_EXIT_KEEP(x)        x
  35 #define ARM_EXIT_DISCARD(x)
  36 #else
  37 #define ARM_EXIT_KEEP(x)
  38 #define ARM_EXIT_DISCARD(x)     x
  39 #endif
  40
  41 OUTPUT_ARCH(arm)
  42 ENTRY(stext)
  43
  44 #ifndef __ARMEB__
  45 jiffies = jiffies_64;
  46 #else
  47 jiffies = jiffies_64 + 4;
  48 #endif
  49
  50 SECTIONS
  51 {
  52         /*
  53          * XXX: The linker does not define how output sections are
  54          * assigned to input sections when there are multiple statements
  55          * matching the same input section name.  There is no documented
  56          * order of matching.
  57          *
  58          * unwind exit sections must be discarded before the rest of the
  59          * unwind sections get included.
  60          */
  61         /DISCARD/ : {
  62                 *(.ARM.exidx.exit.text)
  63                 *(.ARM.extab.exit.text)
  64                 ARM_CPU_DISCARD(*(.ARM.exidx.cpuexit.text))
  65                 ARM_CPU_DISCARD(*(.ARM.extab.cpuexit.text))
  66                 ARM_EXIT_DISCARD(EXIT_TEXT)
  67                 ARM_EXIT_DISCARD(EXIT_DATA)
  68                 EXIT_CALL
  69 #ifndef CONFIG_HOTPLUG
  70                 *(.ARM.exidx.devexit.text)
  71                 *(.ARM.extab.devexit.text)
  72 #endif
  73 #ifndef CONFIG_MMU
  74                 *(.fixup)
  75                 *(__ex_table)
  76 #endif
  77 #ifndef CONFIG_SMP_ON_UP
  78                 *(.alt.smp.init)
  79 #endif
  80                 *(.discard)
  81                 *(.discard.*)
  82         }
  83
  84 #ifdef CONFIG_XIP_KERNEL
  85         . = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
  86 #else
  87         . = PAGE_OFFSET + TEXT_OFFSET;
  88 #endif
  89         .head.text : {
  90                 _text = .;
  91                 HEAD_TEXT
  92         }
  93         .text : {                       /* Real text segment            */
  94                 _stext = .;             /* Text and read-only data      */
  95                         __exception_text_start = .;
  96                         *(.exception.text)
  97                         __exception_text_end = .;
  98                         IRQENTRY_TEXT
  99                         TEXT_TEXT
 100                         SCHED_TEXT
 101                         LOCK_TEXT
 102                         KPROBES_TEXT
 103                         IDMAP_TEXT
 104 #ifdef CONFIG_MMU
 105                         *(.fixup)
 106 #endif
 107                         *(.gnu.warning)
 108                         *(.glue_7)
 109                         *(.glue_7t)
 110                 . = ALIGN(4);
 111                 *(.got)                 /* Global offset table          */
 112                         ARM_CPU_KEEP(PROC_INFO)
 113         }
 114
 115         RO_DATA(PAGE_SIZE)
 116
 117 #ifdef CONFIG_ARM_UNWIND
 118         /*
 119          * Stack unwinding tables
 120          */
 121         . = ALIGN(8);
 122         .ARM.unwind_idx : {
 123                 __start_unwind_idx = .;
 124                 *(.ARM.exidx*)
 125                 __stop_unwind_idx = .;
 126         }
 127         .ARM.unwind_tab : {
 128                 __start_unwind_tab = .;
 129                 *(.ARM.extab*)
 130                 __stop_unwind_tab = .;
 131         }
 132 #endif
 133
 134         _etext = .;                     /* End of text and rodata section */
 135
 136 #ifndef CONFIG_XIP_KERNEL
 137         . = ALIGN(PAGE_SIZE);
 138         __init_begin = .;
 139 #endif
 140
 141         INIT_TEXT_SECTION(8)
 142         .exit.text : {
 143                 ARM_EXIT_KEEP(EXIT_TEXT)
 144         }
 145         .init.proc.info : {
 146                 ARM_CPU_DISCARD(PROC_INFO)
 147         }
 148         .init.arch.info : {
 149                 __arch_info_begin = .;
 150                 *(.arch.info.init)
 151                 __arch_info_end = .;
 152         }
 153         .init.tagtable : {
 154                 __tagtable_begin = .;
 155                 *(.taglist.init)
 156                 __tagtable_end = .;
 157         }
 158 #ifdef CONFIG_SMP_ON_UP
 159         .init.smpalt : {
 160                 __smpalt_begin = .;
 161                 *(.alt.smp.init)
 162                 __smpalt_end = .;
 163         }
 164 #endif
 165         .init.pv_table : {
 166                 __pv_table_begin = .;
 167                 *(.pv_table)
 168                 __pv_table_end = .;
 169         }
 170         .init.data : {
 171 #ifndef CONFIG_XIP_KERNEL
 172                 INIT_DATA
 173 #endif
 174                 INIT_SETUP(16)
 175                 INIT_CALLS
 176                 CON_INITCALL
 177                 SECURITY_INITCALL
 178                 INIT_RAM_FS
 179         }
 180 #ifndef CONFIG_XIP_KERNEL
 181         .exit.data : {
 182                 ARM_EXIT_KEEP(EXIT_DATA)
 183         }
 184 #endif
 185
 186         PERCPU_SECTION(L1_CACHE_BYTES)
 187
 188 #ifdef CONFIG_XIP_KERNEL
 189         __data_loc = ALIGN(4);          /* location in binary */
 190         . = PAGE_OFFSET + TEXT_OFFSET;
 191 #else
 192         __init_end = .;
 193         . = ALIGN(THREAD_SIZE);
 194         __data_loc = .;
 195 #endif
 196
 197         .data : AT(__data_loc) {
 198                 _data = .;              /* address in memory */
 199                 _sdata = .;
 200
 201                 /*
 202                  * first, the init task union, aligned
 203                  * to an 8192 byte boundary.
 204                  */
 205                 INIT_TASK_DATA(THREAD_SIZE)
 206
 207 #ifdef CONFIG_XIP_KERNEL
 208                 . = ALIGN(PAGE_SIZE);
 209                 __init_begin = .;
 210                 INIT_DATA
 211                 ARM_EXIT_KEEP(EXIT_DATA)
 212                 . = ALIGN(PAGE_SIZE);
 213                 __init_end = .;
 214 #endif
 215
 216                 NOSAVE_DATA
 217                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 218                 READ_MOSTLY_DATA(L1_CACHE_BYTES)
 219
 220                 /*
 221                  * The exception fixup table (might need resorting at runtime)
 222                  */
 223                 . = ALIGN(4);
 224                 __start___ex_table = .;
 225 #ifdef CONFIG_MMU
 226                 *(__ex_table)
 227 #endif
 228                 __stop___ex_table = .;
 229
 230                 /*
 231                  * and the usual data section
 232                  */
 233                 DATA_DATA
 234                 CONSTRUCTORS
 235
 236                 _edata = .;
 237         }
 238         _edata_loc = __data_loc + SIZEOF(.data);
 239
 240 #ifdef CONFIG_HAVE_TCM
 241         /*
 242          * We align everything to a page boundary so we can
 243          * free it after init has commenced and TCM contents have
 244          * been copied to its destination.
 245          */
 246         .tcm_start : {
 247                 . = ALIGN(PAGE_SIZE);
 248                 __tcm_start = .;
 249                 __itcm_start = .;
 250         }
 251
 252         /*
 253          * Link these to the ITCM RAM
 254          * Put VMA to the TCM address and LMA to the common RAM
 255          * and we'll upload the contents from RAM to TCM and free
 256          * the used RAM after that.
 257          */
 258         .text_itcm ITCM_OFFSET : AT(__itcm_start)
 259         {
 260                 __sitcm_text = .;
 261                 *(.tcm.text)
 262                 *(.tcm.rodata)
 263                 . = ALIGN(4);
 264                 __eitcm_text = .;
 265         }
 266
 267         /*
 268          * Reset the dot pointer, this is needed to create the
 269          * relative __dtcm_start below (to be used as extern in code).
 270          */
 271         . = ADDR(.tcm_start) + SIZEOF(.tcm_start) + SIZEOF(.text_itcm);
 272
 273         .dtcm_start : {
 274                 __dtcm_start = .;
 275         }
 276
 277         /* TODO: add remainder of ITCM as well, that can be used for data! */
 278         .data_dtcm DTCM_OFFSET : AT(__dtcm_start)
 279         {
 280                 . = ALIGN(4);
 281                 __sdtcm_data = .;
 282                 *(.tcm.data)
 283                 . = ALIGN(4);
 284                 __edtcm_data = .;
 285         }
 286
 287         /* Reset the dot pointer or the linker gets confused */
 288         . = ADDR(.dtcm_start) + SIZEOF(.data_dtcm);
 289
 290         /* End marker for freeing TCM copy in linked object */
 291         .tcm_end : AT(ADDR(.dtcm_start) + SIZEOF(.data_dtcm)){
 292                 . = ALIGN(PAGE_SIZE);
 293                 __tcm_end = .;
 294         }
 295 #endif
 296
 297         NOTES
 298
 299         BSS_SECTION(0, 0, 0)
 300         _end = .;
 301
 302         STABS_DEBUG
 303         .comment 0 : { *(.comment) }
 304 }
 305
 306 /*
 307  * These must never be empty
 308  * If you have to comment these two assert statements out, your
 309  * binutils is too old (for other reasons as well)
 310  */
 311 ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
 312 ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")