arch/x86/kernel/acpi/realmode/wakeup.lds.S

   1 /*
   2  * wakeup.ld
   3  *
   4  * Linker script for the real-mode wakeup code
   5  */
   6 #undef i386
   7 #include "wakeup.h"
   8
   9 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
  10 OUTPUT_ARCH(i386)
  11 ENTRY(_start)
  12
  13 SECTIONS
  14 {
  15         . = 0;
  16         .jump   : {
  17                 *(.jump)
  18         } = 0x90909090
  19
  20         . = WAKEUP_HEADER_OFFSET;
  21         .header : {
  22                 *(.header)
  23         }
  24
  25         . = ALIGN(16);
  26         .text : {
  27                  *(.text*)
  28         } = 0x90909090
  29
  30         . = ALIGN(16);
  31         .rodata : {
  32                 *(.rodata*)
  33         }
  34
  35         .videocards : {
  36                 video_cards = .;
  37                 *(.videocards)
  38                 video_cards_end = .;
  39         }
  40
  41         . = ALIGN(16);
  42         .data : {
  43                  *(.data*)
  44         }
  45
  46         . = ALIGN(16);
  47         .bss :  {
  48                 __bss_start = .;
  49                 *(.bss)
  50                 __bss_end = .;
  51         }
  52
  53         .signature : {
  54                 *(.signature)
  55         }
  56
  57         _end = .;
  58
  59         /DISCARD/ : {
  60                 *(.note*)
  61         }
  62 }