documentation/manual/en/pdf-manual.xsl.in

   1 <?xml version="1.0" encoding="UTF-8"?>
   2 <xsl:stylesheet
   3     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   4     xmlns:fo="http://www.w3.org/1999/XSL/Format"
   5     version="1.0">
   6
   7 <!-- path to original XSL used to do transforms -->
   8 <xsl:import href="@DOCBOOK_FO_XSL@"/>
   9
  10 <!-- DIRECTIVES FOR CUSTOMIZATION -->
  11
  12 <xsl:param name="fop1.extensions" select="1"></xsl:param>
  13
  14 <!-- Hyphenation -->
  15 <xsl:template name="set.flow.properties">
  16   <xsl:param name="element" select="local-name(.)"/>
  17   <xsl:param name="master-reference" select="''"/>
  18
  19   <xsl:choose>
  20     <xsl:when test="starts-with($master-reference, 'index') or
  21                     starts-with($master-reference, 'titlepage') or
  22                     starts-with($master-reference, 'lot') or
  23                     starts-with($master-reference, 'front')">
  24       <xsl:attribute name="hyphenate">false</xsl:attribute>
  25     </xsl:when>
  26     <xsl:otherwise>
  27       <xsl:attribute name="hyphenate">
  28         <xsl:value-of select="$hyphenate"/>
  29       </xsl:attribute>
  30     </xsl:otherwise>
  31   </xsl:choose>
  32 </xsl:template>
  33
  34 <!-- pages always start on odd -->
  35 <xsl:template match="chapter">
  36   <xsl:variable name="id">
  37     <xsl:call-template name="object.id"/>
  38   </xsl:variable>
  39
  40   <xsl:variable name="master-reference">
  41     <xsl:call-template name="select.pagemaster"/>
  42   </xsl:variable>
  43
  44   <fo:page-sequence hyphenate="{$hyphenate}"
  45       master-reference="{$master-reference}"
  46       force-page-count="end-on-even">
  47     <xsl:attribute name="language">
  48       <xsl:call-template name="l10n.language"/>
  49     </xsl:attribute>
  50     <xsl:attribute name="format">
  51       <xsl:call-template name="page.number.format">
  52         <xsl:with-param name="master-reference" select="$master-reference"/>
  53       </xsl:call-template>
  54     </xsl:attribute>
  55     <xsl:attribute name="initial-page-number">
  56       <xsl:call-template name="initial.page.number">
  57         <xsl:with-param name="master-reference" select="$master-reference"/>
  58       </xsl:call-template>
  59     </xsl:attribute>
  60
  61     <!--
  62     <xsl:attribute name="force-page-count">
  63       <xsl:call-template name="force.page.count">
  64         <xsl:with-param name="master-reference" select="$master-reference"/>
  65       </xsl:call-template>
  66     </xsl:attribute>
  67     -->
  68
  69     <xsl:attribute name="hyphenation-character">
  70       <xsl:call-template name="gentext">
  71         <xsl:with-param name="key" select="'hyphenation-character'"/>
  72       </xsl:call-template>
  73     </xsl:attribute>
  74     <xsl:attribute name="hyphenation-push-character-count">
  75       <xsl:call-template name="gentext">
  76         <xsl:with-param name="key" select="'hyphenation-push-character-count'"/>
  77       </xsl:call-template>
  78     </xsl:attribute>
  79     <xsl:attribute name="hyphenation-remain-character-count">
  80       <xsl:call-template name="gentext">
  81         <xsl:with-param name="key" select="'hyphenation-remain-character-count'"/>
  82       </xsl:call-template>
  83     </xsl:attribute>
  84
  85     <xsl:apply-templates select="." mode="running.head.mode">
  86       <xsl:with-param name="master-reference" select="$master-reference"/>
  87     </xsl:apply-templates>
  88
  89     <xsl:apply-templates select="." mode="running.foot.mode">
  90       <xsl:with-param name="master-reference" select="$master-reference"/>
  91     </xsl:apply-templates>
  92
  93     <fo:flow flow-name="xsl-region-body">
  94       <xsl:call-template name="set.flow.properties">
  95         <xsl:with-param name="element" select="local-name(.)"/>
  96         <xsl:with-param name="master-reference" select="$master-reference"/>
  97       </xsl:call-template>
  98
  99       <fo:block id="{$id}"
 100                 xsl:use-attribute-sets="component.titlepage.properties">
 101         <xsl:call-template name="chapter.titlepage"/>
 102       </fo:block>
 103
 104       <xsl:variable name="toc.params">
 105         <xsl:call-template name="find.path.params">
 106           <xsl:with-param name="table" select="normalize-space($generate.toc)"/>
 107         </xsl:call-template>
 108       </xsl:variable>
 109       <xsl:if test="contains($toc.params, 'toc')">
 110         <xsl:call-template name="component.toc">
 111           <xsl:with-param name="toc.title.p"
 112                           select="contains($toc.params, 'title')"/>
 113         </xsl:call-template>
 114         <xsl:call-template name="component.toc.separator"/>
 115       </xsl:if>
 116       <xsl:apply-templates/>
 117     </fo:flow>
 118   </fo:page-sequence>
 119 </xsl:template>
 120
 121
 122 </xsl:stylesheet>