config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         AM_COND_IF([BUILD_LINUX], [
   6                 dnl # Setup the kernel build environment.
   7                 ZFS_AC_KERNEL
   8                 ZFS_AC_QAT
   9
  10                 dnl # Sanity checks for module building and CONFIG_* defines
  11                 ZFS_AC_KERNEL_TEST_MODULE
  12                 ZFS_AC_KERNEL_CONFIG_DEFINED
  13
  14                 dnl # Sequential ZFS_LINUX_TRY_COMPILE tests
  15                 ZFS_AC_KERNEL_FPU_HEADER
  16                 ZFS_AC_KERNEL_OBJTOOL_HEADER
  17                 ZFS_AC_KERNEL_WAIT_QUEUE_ENTRY_T
  18                 ZFS_AC_KERNEL_MISC_MINOR
  19                 ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  20
  21                 dnl # Parallel ZFS_LINUX_TEST_SRC / ZFS_LINUX_TEST_RESULT tests
  22                 ZFS_AC_KERNEL_TEST_SRC
  23                 ZFS_AC_KERNEL_TEST_RESULT
  24
  25                 AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  26                         KERNEL_MAKE="$KERNEL_MAKE O=$LINUX_OBJ"
  27                 ])
  28
  29                 AC_SUBST(KERNEL_MAKE)
  30         ])
  31 ])
  32
  33 dnl #
  34 dnl # Generate and compile all of the kernel API test cases to determine
  35 dnl # which interfaces are available.  By invoking the kernel build system
  36 dnl # only once the compilation can be done in parallel significantly
  37 dnl # speeding up the process.
  38 dnl #
  39 AC_DEFUN([ZFS_AC_KERNEL_TEST_SRC], [
  40         ZFS_AC_KERNEL_SRC_OBJTOOL
  41         ZFS_AC_KERNEL_SRC_GLOBAL_PAGE_STATE
  42         ZFS_AC_KERNEL_SRC_ACCESS_OK_TYPE
  43         ZFS_AC_KERNEL_SRC_PDE_DATA
  44         ZFS_AC_KERNEL_SRC_FALLOCATE
  45         ZFS_AC_KERNEL_SRC_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE
  46         ZFS_AC_KERNEL_SRC_RWSEM
  47         ZFS_AC_KERNEL_SRC_SCHED
  48         ZFS_AC_KERNEL_SRC_USLEEP_RANGE
  49         ZFS_AC_KERNEL_SRC_KMEM_CACHE
  50         ZFS_AC_KERNEL_SRC_KVMALLOC
  51         ZFS_AC_KERNEL_SRC_VMALLOC_PAGE_KERNEL
  52         ZFS_AC_KERNEL_SRC_WAIT
  53         ZFS_AC_KERNEL_SRC_INODE_TIMES
  54         ZFS_AC_KERNEL_SRC_INODE_LOCK
  55         ZFS_AC_KERNEL_SRC_GROUP_INFO_GID
  56         ZFS_AC_KERNEL_SRC_RW
  57         ZFS_AC_KERNEL_SRC_TIMER_SETUP
  58         ZFS_AC_KERNEL_SRC_SUPER_USER_NS
  59         ZFS_AC_KERNEL_SRC_PROC_OPERATIONS
  60         ZFS_AC_KERNEL_SRC_BLOCK_DEVICE_OPERATIONS
  61         ZFS_AC_KERNEL_SRC_BIO
  62         ZFS_AC_KERNEL_SRC_BLKDEV
  63         ZFS_AC_KERNEL_SRC_BLK_QUEUE
  64         ZFS_AC_KERNEL_SRC_GET_DISK_AND_MODULE
  65         ZFS_AC_KERNEL_SRC_REVALIDATE_DISK
  66         ZFS_AC_KERNEL_SRC_GET_DISK_RO
  67         ZFS_AC_KERNEL_SRC_GENERIC_READLINK_GLOBAL
  68         ZFS_AC_KERNEL_SRC_DISCARD_GRANULARITY
  69         ZFS_AC_KERNEL_SRC_INODE_OWNER_OR_CAPABLE
  70         ZFS_AC_KERNEL_SRC_XATTR
  71         ZFS_AC_KERNEL_SRC_ACL
  72         ZFS_AC_KERNEL_SRC_INODE_GETATTR
  73         ZFS_AC_KERNEL_SRC_INODE_SET_FLAGS
  74         ZFS_AC_KERNEL_SRC_INODE_SET_IVERSION
  75         ZFS_AC_KERNEL_SRC_SHOW_OPTIONS
  76         ZFS_AC_KERNEL_SRC_FILE_INODE
  77         ZFS_AC_KERNEL_SRC_FILE_DENTRY
  78         ZFS_AC_KERNEL_SRC_FSYNC
  79         ZFS_AC_KERNEL_SRC_AIO_FSYNC
  80         ZFS_AC_KERNEL_SRC_EVICT_INODE
  81         ZFS_AC_KERNEL_SRC_DIRTY_INODE
  82         ZFS_AC_KERNEL_SRC_SHRINKER
  83         ZFS_AC_KERNEL_SRC_MKDIR_UMODE_T
  84         ZFS_AC_KERNEL_SRC_LOOKUP_FLAGS
  85         ZFS_AC_KERNEL_SRC_CREATE_FLAGS
  86         ZFS_AC_KERNEL_SRC_GET_LINK
  87         ZFS_AC_KERNEL_SRC_PUT_LINK
  88         ZFS_AC_KERNEL_SRC_TMPFILE
  89         ZFS_AC_KERNEL_SRC_AUTOMOUNT
  90         ZFS_AC_KERNEL_SRC_ENCODE_FH_WITH_INODE
  91         ZFS_AC_KERNEL_SRC_COMMIT_METADATA
  92         ZFS_AC_KERNEL_SRC_CLEAR_INODE
  93         ZFS_AC_KERNEL_SRC_SETATTR_PREPARE
  94         ZFS_AC_KERNEL_SRC_INSERT_INODE_LOCKED
  95         ZFS_AC_KERNEL_SRC_DENTRY
  96         ZFS_AC_KERNEL_SRC_TRUNCATE_SETSIZE
  97         ZFS_AC_KERNEL_SRC_SECURITY_INODE
  98         ZFS_AC_KERNEL_SRC_FST_MOUNT
  99         ZFS_AC_KERNEL_SRC_BDI
 100         ZFS_AC_KERNEL_SRC_SET_NLINK
 101         ZFS_AC_KERNEL_SRC_SGET
 102         ZFS_AC_KERNEL_SRC_LSEEK_EXECUTE
 103         ZFS_AC_KERNEL_SRC_VFS_GETATTR
 104         ZFS_AC_KERNEL_SRC_VFS_FSYNC_2ARGS
 105         ZFS_AC_KERNEL_SRC_VFS_ITERATE
 106         ZFS_AC_KERNEL_SRC_VFS_DIRECT_IO
 107         ZFS_AC_KERNEL_SRC_VFS_RW_ITERATE
 108         ZFS_AC_KERNEL_SRC_VFS_GENERIC_WRITE_CHECKS
 109         ZFS_AC_KERNEL_SRC_VFS_IOV_ITER
 110         ZFS_AC_KERNEL_SRC_KMAP_ATOMIC_ARGS
 111         ZFS_AC_KERNEL_SRC_FOLLOW_DOWN_ONE
 112         ZFS_AC_KERNEL_SRC_MAKE_REQUEST_FN
 113         ZFS_AC_KERNEL_SRC_GENERIC_IO_ACCT
 114         ZFS_AC_KERNEL_SRC_FPU
 115         ZFS_AC_KERNEL_SRC_FMODE_T
 116         ZFS_AC_KERNEL_SRC_KUIDGID_T
 117         ZFS_AC_KERNEL_SRC_KUID_HELPERS
 118         ZFS_AC_KERNEL_SRC_MODULE_PARAM_CALL_CONST
 119         ZFS_AC_KERNEL_SRC_RENAME_WANTS_FLAGS
 120         ZFS_AC_KERNEL_SRC_CURRENT_TIME
 121         ZFS_AC_KERNEL_SRC_USERNS_CAPABILITIES
 122         ZFS_AC_KERNEL_SRC_IN_COMPAT_SYSCALL
 123         ZFS_AC_KERNEL_SRC_KTIME
 124         ZFS_AC_KERNEL_SRC_TOTALRAM_PAGES_FUNC
 125         ZFS_AC_KERNEL_SRC_TOTALHIGH_PAGES
 126         ZFS_AC_KERNEL_SRC_KSTRTOUL
 127         ZFS_AC_KERNEL_SRC_PERCPU
 128         ZFS_AC_KERNEL_SRC_CPU_HOTPLUG
 129
 130         AC_MSG_CHECKING([for available kernel interfaces])
 131         ZFS_LINUX_TEST_COMPILE_ALL([kabi])
 132         AC_MSG_RESULT([done])
 133 ])
 134
 135 dnl #
 136 dnl # Check results of kernel interface tests.
 137 dnl #
 138 AC_DEFUN([ZFS_AC_KERNEL_TEST_RESULT], [
 139         ZFS_AC_KERNEL_ACCESS_OK_TYPE
 140         ZFS_AC_KERNEL_GLOBAL_PAGE_STATE
 141         ZFS_AC_KERNEL_OBJTOOL
 142         ZFS_AC_KERNEL_PDE_DATA
 143         ZFS_AC_KERNEL_FALLOCATE
 144         ZFS_AC_KERNEL_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE
 145         ZFS_AC_KERNEL_RWSEM
 146         ZFS_AC_KERNEL_SCHED
 147         ZFS_AC_KERNEL_USLEEP_RANGE
 148         ZFS_AC_KERNEL_KMEM_CACHE
 149         ZFS_AC_KERNEL_KVMALLOC
 150         ZFS_AC_KERNEL_VMALLOC_PAGE_KERNEL
 151         ZFS_AC_KERNEL_WAIT
 152         ZFS_AC_KERNEL_INODE_TIMES
 153         ZFS_AC_KERNEL_INODE_LOCK
 154         ZFS_AC_KERNEL_GROUP_INFO_GID
 155         ZFS_AC_KERNEL_RW
 156         ZFS_AC_KERNEL_TIMER_SETUP
 157         ZFS_AC_KERNEL_SUPER_USER_NS
 158         ZFS_AC_KERNEL_PROC_OPERATIONS
 159         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS
 160         ZFS_AC_KERNEL_BIO
 161         ZFS_AC_KERNEL_BLKDEV
 162         ZFS_AC_KERNEL_BLK_QUEUE
 163         ZFS_AC_KERNEL_GET_DISK_AND_MODULE
 164         ZFS_AC_KERNEL_REVALIDATE_DISK
 165         ZFS_AC_KERNEL_GET_DISK_RO
 166         ZFS_AC_KERNEL_GENERIC_READLINK_GLOBAL
 167         ZFS_AC_KERNEL_DISCARD_GRANULARITY
 168         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
 169         ZFS_AC_KERNEL_XATTR
 170         ZFS_AC_KERNEL_ACL
 171         ZFS_AC_KERNEL_INODE_GETATTR
 172         ZFS_AC_KERNEL_INODE_SET_FLAGS
 173         ZFS_AC_KERNEL_INODE_SET_IVERSION
 174         ZFS_AC_KERNEL_SHOW_OPTIONS
 175         ZFS_AC_KERNEL_FILE_INODE
 176         ZFS_AC_KERNEL_FILE_DENTRY
 177         ZFS_AC_KERNEL_FSYNC
 178         ZFS_AC_KERNEL_AIO_FSYNC
 179         ZFS_AC_KERNEL_EVICT_INODE
 180         ZFS_AC_KERNEL_DIRTY_INODE
 181         ZFS_AC_KERNEL_SHRINKER
 182         ZFS_AC_KERNEL_MKDIR_UMODE_T
 183         ZFS_AC_KERNEL_LOOKUP_FLAGS
 184         ZFS_AC_KERNEL_CREATE_FLAGS
 185         ZFS_AC_KERNEL_GET_LINK
 186         ZFS_AC_KERNEL_PUT_LINK
 187         ZFS_AC_KERNEL_TMPFILE
 188         ZFS_AC_KERNEL_AUTOMOUNT
 189         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
 190         ZFS_AC_KERNEL_COMMIT_METADATA
 191         ZFS_AC_KERNEL_CLEAR_INODE
 192         ZFS_AC_KERNEL_SETATTR_PREPARE
 193         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
 194         ZFS_AC_KERNEL_DENTRY
 195         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
 196         ZFS_AC_KERNEL_SECURITY_INODE
 197         ZFS_AC_KERNEL_FST_MOUNT
 198         ZFS_AC_KERNEL_BDI
 199         ZFS_AC_KERNEL_SET_NLINK
 200         ZFS_AC_KERNEL_SGET
 201         ZFS_AC_KERNEL_LSEEK_EXECUTE
 202         ZFS_AC_KERNEL_VFS_GETATTR
 203         ZFS_AC_KERNEL_VFS_FSYNC_2ARGS
 204         ZFS_AC_KERNEL_VFS_ITERATE
 205         ZFS_AC_KERNEL_VFS_DIRECT_IO
 206         ZFS_AC_KERNEL_VFS_RW_ITERATE
 207         ZFS_AC_KERNEL_VFS_GENERIC_WRITE_CHECKS
 208         ZFS_AC_KERNEL_VFS_IOV_ITER
 209         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
 210         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
 211         ZFS_AC_KERNEL_MAKE_REQUEST_FN
 212         ZFS_AC_KERNEL_GENERIC_IO_ACCT
 213         ZFS_AC_KERNEL_FPU
 214         ZFS_AC_KERNEL_FMODE_T
 215         ZFS_AC_KERNEL_KUIDGID_T
 216         ZFS_AC_KERNEL_KUID_HELPERS
 217         ZFS_AC_KERNEL_MODULE_PARAM_CALL_CONST
 218         ZFS_AC_KERNEL_RENAME_WANTS_FLAGS
 219         ZFS_AC_KERNEL_CURRENT_TIME
 220         ZFS_AC_KERNEL_USERNS_CAPABILITIES
 221         ZFS_AC_KERNEL_IN_COMPAT_SYSCALL
 222         ZFS_AC_KERNEL_KTIME
 223         ZFS_AC_KERNEL_TOTALRAM_PAGES_FUNC
 224         ZFS_AC_KERNEL_TOTALHIGH_PAGES
 225         ZFS_AC_KERNEL_KSTRTOUL
 226         ZFS_AC_KERNEL_PERCPU
 227         ZFS_AC_KERNEL_CPU_HOTPLUG
 228 ])
 229
 230 dnl #
 231 dnl # Detect name used for Module.symvers file in kernel
 232 dnl #
 233 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 234         modpost=$LINUX/scripts/Makefile.modpost
 235         AC_MSG_CHECKING([kernel file name for module symbols])
 236         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 237                 AS_IF([grep -q Modules.symvers $modpost], [
 238                         LINUX_SYMBOLS=Modules.symvers
 239                 ], [
 240                         LINUX_SYMBOLS=Module.symvers
 241                 ])
 242
 243                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 244                         AC_MSG_ERROR([
 245         *** Please make sure the kernel devel package for your distribution
 246         *** is installed.  If you are building with a custom kernel, make sure
 247         *** the kernel is configured, built, and the '--with-linux=PATH'
 248         *** configure option refers to the location of the kernel source.
 249                         ])
 250                 ])
 251         ], [
 252                 LINUX_SYMBOLS=NONE
 253         ])
 254         AC_MSG_RESULT($LINUX_SYMBOLS)
 255         AC_SUBST(LINUX_SYMBOLS)
 256 ])
 257
 258 dnl #
 259 dnl # Detect the kernel to be built against
 260 dnl #
 261 AC_DEFUN([ZFS_AC_KERNEL], [
 262         AC_ARG_WITH([linux],
 263                 AS_HELP_STRING([--with-linux=PATH],
 264                 [Path to kernel source]),
 265                 [kernelsrc="$withval"])
 266
 267         AC_ARG_WITH(linux-obj,
 268                 AS_HELP_STRING([--with-linux-obj=PATH],
 269                 [Path to kernel build objects]),
 270                 [kernelbuild="$withval"])
 271
 272         AC_MSG_CHECKING([kernel source directory])
 273         AS_IF([test -z "$kernelsrc"], [
 274                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 275                         headersdir="/lib/modules/$(uname -r)/source"
 276                         sourcelink=$(readlink -f "$headersdir")
 277                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 278                         headersdir="/lib/modules/$(uname -r)/build"
 279                         sourcelink=$(readlink -f "$headersdir")
 280                 ], [
 281                         sourcelink=$(ls -1d /usr/src/kernels/* \
 282                                      /usr/src/linux-* \
 283                                      2>/dev/null | grep -v obj | tail -1)
 284                 ])
 285
 286                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 287                         kernelsrc=`readlink -f ${sourcelink}`
 288                 ], [
 289                         kernelsrc="[Not found]"
 290                 ])
 291         ], [
 292                 AS_IF([test "$kernelsrc" = "NONE"], [
 293                         kernsrcver=NONE
 294                 ])
 295                 withlinux=yes
 296         ])
 297
 298         AC_MSG_RESULT([$kernelsrc])
 299         AS_IF([test ! -d "$kernelsrc"], [
 300                 AC_MSG_ERROR([
 301         *** Please make sure the kernel devel package for your distribution
 302         *** is installed and then try again.  If that fails, you can specify the
 303         *** location of the kernel source with the '--with-linux=PATH' option.])
 304         ])
 305
 306         AC_MSG_CHECKING([kernel build directory])
 307         AS_IF([test -z "$kernelbuild"], [
 308                 AS_IF([test x$withlinux != xyes -a -e "/lib/modules/$(uname -r)/build"], [
 309                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 310                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 311                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 312                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 313                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 314                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 315                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 316                 ], [
 317                         kernelbuild=${kernelsrc}
 318                 ])
 319         ])
 320         AC_MSG_RESULT([$kernelbuild])
 321
 322         AC_MSG_CHECKING([kernel source version])
 323         utsrelease1=$kernelbuild/include/linux/version.h
 324         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 325         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 326         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 327                 utsrelease=linux/version.h
 328         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 329                 utsrelease=linux/utsrelease.h
 330         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 331                 utsrelease=generated/utsrelease.h
 332         ])
 333
 334         AS_IF([test "$utsrelease"], [
 335                 kernsrcver=`(echo "#include <$utsrelease>";
 336                              echo "kernsrcver=UTS_RELEASE") |
 337                              ${CPP} -I $kernelbuild/include - |
 338                              grep "^kernsrcver=" | cut -d \" -f 2`
 339
 340                 AS_IF([test -z "$kernsrcver"], [
 341                         AC_MSG_RESULT([Not found])
 342                         AC_MSG_ERROR([
 343         *** Cannot determine kernel version.
 344                         ])
 345                 ])
 346         ], [
 347                 AC_MSG_RESULT([Not found])
 348                 if test "x$enable_linux_builtin" != xyes; then
 349                         AC_MSG_ERROR([
 350         *** Cannot find UTS_RELEASE definition.
 351                         ])
 352                 else
 353                         AC_MSG_ERROR([
 354         *** Cannot find UTS_RELEASE definition.
 355         *** Please run 'make prepare' inside the kernel source tree.])
 356                 fi
 357         ])
 358
 359         AC_MSG_RESULT([$kernsrcver])
 360
 361         AS_VERSION_COMPARE([$kernsrcver], [$ZFS_META_KVER_MIN], [
 362                  AC_MSG_ERROR([
 363         *** Cannot build against kernel version $kernsrcver.
 364         *** The minimum supported kernel version is $ZFS_META_KVER_MIN.
 365                 ])
 366         ])
 367
 368         LINUX=${kernelsrc}
 369         LINUX_OBJ=${kernelbuild}
 370         LINUX_VERSION=${kernsrcver}
 371
 372         AC_SUBST(LINUX)
 373         AC_SUBST(LINUX_OBJ)
 374         AC_SUBST(LINUX_VERSION)
 375
 376         ZFS_AC_MODULE_SYMVERS
 377 ])
 378
 379 dnl #
 380 dnl # Detect the QAT module to be built against, QAT provides hardware
 381 dnl # acceleration for data compression:
 382 dnl #
 383 dnl # https://01.org/intel-quickassist-technology
 384 dnl #
 385 dnl # 1) Download and install QAT driver from the above link
 386 dnl # 2) Start QAT driver in your system:
 387 dnl #    service qat_service start
 388 dnl # 3) Enable QAT in ZFS, e.g.:
 389 dnl #    ./configure --with-qat=<qat-driver-path>/QAT1.6
 390 dnl #    make
 391 dnl # 4) Set GZIP compression in ZFS dataset:
 392 dnl #    zfs set compression = gzip <dataset>
 393 dnl #
 394 dnl # Then the data written to this ZFS pool is compressed by QAT accelerator
 395 dnl # automatically, and de-compressed by QAT when read from the pool.
 396 dnl #
 397 dnl # 1) Get QAT hardware statistics with:
 398 dnl #    cat /proc/icp_dh895xcc_dev/qat
 399 dnl # 2) To disable QAT:
 400 dnl #    insmod zfs.ko zfs_qat_disable=1
 401 dnl #
 402 AC_DEFUN([ZFS_AC_QAT], [
 403         AC_ARG_WITH([qat],
 404                 AS_HELP_STRING([--with-qat=PATH],
 405                 [Path to qat source]),
 406                 AS_IF([test "$withval" = "yes"],
 407                         AC_MSG_ERROR([--with-qat=PATH requires a PATH]),
 408                         [qatsrc="$withval"]))
 409
 410         AC_ARG_WITH([qat-obj],
 411                 AS_HELP_STRING([--with-qat-obj=PATH],
 412                 [Path to qat build objects]),
 413                 [qatbuild="$withval"])
 414
 415         AS_IF([test ! -z "${qatsrc}"], [
 416                 AC_MSG_CHECKING([qat source directory])
 417                 AC_MSG_RESULT([$qatsrc])
 418                 QAT_SRC="${qatsrc}/quickassist"
 419                 AS_IF([ test ! -e "$QAT_SRC/include/cpa.h"], [
 420                         AC_MSG_ERROR([
 421         *** Please make sure the qat driver package is installed
 422         *** and specify the location of the qat source with the
 423         *** '--with-qat=PATH' option then try again. Failed to
 424         *** find cpa.h in:
 425         ${QAT_SRC}/include])
 426                 ])
 427         ])
 428
 429         AS_IF([test ! -z "${qatsrc}"], [
 430                 AC_MSG_CHECKING([qat build directory])
 431                 AS_IF([test -z "$qatbuild"], [
 432                         qatbuild="${qatsrc}/build"
 433                 ])
 434
 435                 AC_MSG_RESULT([$qatbuild])
 436                 QAT_OBJ=${qatbuild}
 437                 AS_IF([ ! test -e "$QAT_OBJ/icp_qa_al.ko" && ! test -e "$QAT_OBJ/qat_api.ko"], [
 438                         AC_MSG_ERROR([
 439         *** Please make sure the qat driver is installed then try again.
 440         *** Failed to find icp_qa_al.ko or qat_api.ko in:
 441         $QAT_OBJ])
 442                 ])
 443
 444                 AC_SUBST(QAT_SRC)
 445                 AC_SUBST(QAT_OBJ)
 446
 447                 AC_DEFINE(HAVE_QAT, 1,
 448                 [qat is enabled and existed])
 449         ])
 450
 451         dnl #
 452         dnl # Detect the name used for the QAT Module.symvers file.
 453         dnl #
 454         AS_IF([test ! -z "${qatsrc}"], [
 455                 AC_MSG_CHECKING([qat file for module symbols])
 456                 QAT_SYMBOLS=$QAT_SRC/lookaside/access_layer/src/Module.symvers
 457
 458                 AS_IF([test -r $QAT_SYMBOLS], [
 459                         AC_MSG_RESULT([$QAT_SYMBOLS])
 460                         AC_SUBST(QAT_SYMBOLS)
 461                 ],[
 462                         AC_MSG_ERROR([
 463         *** Please make sure the qat driver is installed then try again.
 464         *** Failed to find Module.symvers in:
 465         $QAT_SYMBOLS
 466                         ])
 467                 ])
 468         ])
 469 ])
 470
 471 dnl #
 472 dnl # Basic toolchain sanity check.
 473 dnl #
 474 AC_DEFUN([ZFS_AC_KERNEL_TEST_MODULE], [
 475         AC_MSG_CHECKING([whether modules can be built])
 476         ZFS_LINUX_TRY_COMPILE([], [], [
 477                 AC_MSG_RESULT([yes])
 478         ],[
 479                 AC_MSG_RESULT([no])
 480                 if test "x$enable_linux_builtin" != xyes; then
 481                         AC_MSG_ERROR([
 482         *** Unable to build an empty module.
 483                         ])
 484                 else
 485                         AC_MSG_ERROR([
 486         *** Unable to build an empty module.
 487         *** Please run 'make scripts' inside the kernel source tree.])
 488                 fi
 489         ])
 490 ])
 491
 492 dnl #
 493 dnl # ZFS_LINUX_CONFTEST_H
 494 dnl #
 495 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 496 test -d build/$2 || mkdir -p build/$2
 497 cat - <<_ACEOF >build/$2/$2.h
 498 $1
 499 _ACEOF
 500 ])
 501
 502 dnl #
 503 dnl # ZFS_LINUX_CONFTEST_C
 504 dnl #
 505 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 506 test -d build/$2 || mkdir -p build/$2
 507 cat confdefs.h - <<_ACEOF >build/$2/$2.c
 508 $1
 509 _ACEOF
 510 ])
 511
 512 dnl #
 513 dnl # ZFS_LINUX_CONFTEST_MAKEFILE
 514 dnl #
 515 dnl # $1 - test case name
 516 dnl # $2 - add to top-level Makefile
 517 dnl # $3 - additional build flags
 518 dnl #
 519 AC_DEFUN([ZFS_LINUX_CONFTEST_MAKEFILE], [
 520         test -d build || mkdir -p build
 521         test -d build/$1 || mkdir -p build/$1
 522
 523         file=build/$1/Makefile
 524
 525         dnl # Example command line to manually build source.
 526         cat - <<_ACEOF >$file
 527 # Example command line to manually build source
 528 # make modules -C $LINUX_OBJ $ARCH_UM M=$PWD/build/$1
 529
 530 ccflags-y := -Werror $FRAME_LARGER_THAN
 531 _ACEOF
 532
 533         dnl # Additional custom CFLAGS as requested.
 534         m4_ifval($3, [echo "ccflags-y += $3" >>$file], [])
 535
 536         dnl # Test case source
 537         echo "obj-m := $1.o" >>$file
 538
 539         AS_IF([test "x$2" = "xyes"], [echo "obj-m += $1/" >>build/Makefile], [])
 540 ])
 541
 542 dnl #
 543 dnl # ZFS_LINUX_TEST_PROGRAM(C)([PROLOGUE], [BODY])
 544 dnl #
 545 m4_define([ZFS_LINUX_TEST_PROGRAM], [
 546 #include <linux/module.h>
 547 $1
 548
 549 int
 550 main (void)
 551 {
 552 $2
 553         ;
 554         return 0;
 555 }
 556
 557 MODULE_DESCRIPTION("conftest");
 558 MODULE_AUTHOR(ZFS_META_AUTHOR);
 559 MODULE_VERSION(ZFS_META_VERSION "-" ZFS_META_RELEASE);
 560 MODULE_LICENSE($3);
 561 ])
 562
 563 dnl #
 564 dnl # ZFS_LINUX_TEST_REMOVE
 565 dnl #
 566 dnl # Removes the specified test source and results.
 567 dnl #
 568 AC_DEFUN([ZFS_LINUX_TEST_REMOVE], [
 569         test -d build/$1 && rm -Rf build/$1
 570         test -f build/Makefile && sed '/$1/d' build/Makefile
 571 ])
 572
 573 dnl #
 574 dnl # ZFS_LINUX_COMPILE
 575 dnl #
 576 dnl # $1 - build dir
 577 dnl # $2 - test command
 578 dnl # $3 - pass command
 579 dnl # $4 - fail command
 580 dnl # $5 - set KBUILD_MODPOST_NOFINAL='yes'
 581 dnl # $6 - set KBUILD_MODPOST_WARN='yes'
 582 dnl #
 583 dnl # Used internally by ZFS_LINUX_TEST_{COMPILE,MODPOST}
 584 dnl #
 585 AC_DEFUN([ZFS_LINUX_COMPILE], [
 586         AC_TRY_COMMAND([
 587             KBUILD_MODPOST_NOFINAL="$5" KBUILD_MODPOST_WARN="$6"
 588             make modules -k -j$TEST_JOBS -C $LINUX_OBJ $ARCH_UM
 589             M=$PWD/$1 >$1/build.log 2>&1])
 590         AS_IF([AC_TRY_COMMAND([$2])], [$3], [$4])
 591 ])
 592
 593 dnl #
 594 dnl # ZFS_LINUX_TEST_COMPILE
 595 dnl #
 596 dnl # Perform a full compile excluding the final modpost phase.
 597 dnl #
 598 AC_DEFUN([ZFS_LINUX_TEST_COMPILE], [
 599         ZFS_LINUX_COMPILE([$2], [test -f $2/build.log], [
 600                 mv $2/Makefile $2/Makefile.compile.$1
 601                 mv $2/build.log $2/build.log.$1
 602         ],[
 603                 AC_MSG_ERROR([
 604         *** Unable to compile test source to determine kernel interfaces.])
 605         ], [yes], [])
 606 ])
 607
 608 dnl #
 609 dnl # ZFS_LINUX_TEST_MODPOST
 610 dnl #
 611 dnl # Perform a full compile including the modpost phase.  This may
 612 dnl # be an incremental build if the objects have already been built.
 613 dnl #
 614 AC_DEFUN([ZFS_LINUX_TEST_MODPOST], [
 615         ZFS_LINUX_COMPILE([$2], [test -f $2/build.log], [
 616                 mv $2/Makefile $2/Makefile.modpost.$1
 617                 cat $2/build.log >>build/build.log.$1
 618         ],[
 619                 AC_MSG_ERROR([
 620         *** Unable to modpost test source to determine kernel interfaces.])
 621         ], [], [yes])
 622 ])
 623
 624 dnl #
 625 dnl # Perform the compilation of the test cases in two phases.
 626 dnl #
 627 dnl # Phase 1) attempt to build the object files for all of the tests
 628 dnl #          defined by the ZFS_LINUX_TEST_SRC macro.  But do not
 629 dnl #          perform the final modpost stage.
 630 dnl #
 631 dnl # Phase 2) disable all tests which failed the initial compilation,
 632 dnl #          then invoke the final modpost step for the remaining tests.
 633 dnl #
 634 dnl # This allows us efficiently build the test cases in parallel while
 635 dnl # remaining resilient to build failures which are expected when
 636 dnl # detecting the available kernel interfaces.
 637 dnl #
 638 dnl # The maximum allowed parallelism can be controlled by setting the
 639 dnl # TEST_JOBS environment variable.  Otherwise, it default to $(nproc).
 640 dnl #
 641 AC_DEFUN([ZFS_LINUX_TEST_COMPILE_ALL], [
 642         dnl # Phase 1 - Compilation only, final linking is skipped.
 643         ZFS_LINUX_TEST_COMPILE([$1], [build])
 644
 645         dnl #
 646         dnl # Phase 2 - When building external modules disable test cases
 647         dnl # which failed to compile and invoke modpost to verify the
 648         dnl # final linking.
 649         dnl #
 650         dnl # Test names suffixed with '_license' call modpost independently
 651         dnl # to ensure that a single incompatibility does not result in the
 652         dnl # modpost phase exiting early.  This check is not performed on
 653         dnl # every symbol since the majority are compatible and doing so
 654         dnl # would significantly slow down this phase.
 655         dnl #
 656         dnl # When configuring for builtin (--enable-linux-builtin)
 657         dnl # fake the linking step artificially create the expected .ko
 658         dnl # files for tests which did compile.  This is required for
 659         dnl # kernels which do not have loadable module support or have
 660         dnl # not yet been built.
 661         dnl #
 662         AS_IF([test "x$enable_linux_builtin" = "xno"], [
 663                 for dir in $(awk '/^obj-m/ { print [$]3 }' \
 664                     build/Makefile.compile.$1); do
 665                         name=${dir%/}
 666                         AS_IF([test -f build/$name/$name.o], [
 667                                 AS_IF([test "${name##*_}" = "license"], [
 668                                         ZFS_LINUX_TEST_MODPOST([$1],
 669                                             [build/$name])
 670                                         echo "obj-n += $dir" >>build/Makefile
 671                                 ], [
 672                                         echo "obj-m += $dir" >>build/Makefile
 673                                 ])
 674                         ], [
 675                                 echo "obj-n += $dir" >>build/Makefile
 676                         ])
 677                 done
 678
 679                 ZFS_LINUX_TEST_MODPOST([$1], [build])
 680         ], [
 681                 for dir in $(awk '/^obj-m/ { print [$]3 }' \
 682                     build/Makefile.compile.$1); do
 683                         name=${dir%/}
 684                         AS_IF([test -f build/$name/$name.o], [
 685                                 touch build/$name/$name.ko
 686                         ])
 687                 done
 688         ])
 689 ])
 690
 691 dnl #
 692 dnl # ZFS_LINUX_TEST_SRC
 693 dnl #
 694 dnl # $1 - name
 695 dnl # $2 - global
 696 dnl # $3 - source
 697 dnl # $4 - extra cflags
 698 dnl # $5 - check license-compatibility
 699 dnl #
 700 dnl # Check if the test source is buildable at all and then if it is
 701 dnl # license compatible.
 702 dnl #
 703 dnl # N.B because all of the test cases are compiled in parallel they
 704 dnl # must never depend on the results of previous tests.  Each test
 705 dnl # needs to be entirely independent.
 706 dnl #
 707 AC_DEFUN([ZFS_LINUX_TEST_SRC], [
 708         ZFS_LINUX_CONFTEST_C([ZFS_LINUX_TEST_PROGRAM([[$2]], [[$3]],
 709             [["Dual BSD/GPL"]])], [$1])
 710         ZFS_LINUX_CONFTEST_MAKEFILE([$1], [yes], [$4])
 711
 712         AS_IF([ test -n "$5" ], [
 713                 ZFS_LINUX_CONFTEST_C([ZFS_LINUX_TEST_PROGRAM(
 714                     [[$2]], [[$3]], [[$5]])], [$1_license])
 715                 ZFS_LINUX_CONFTEST_MAKEFILE([$1_license], [yes], [$4])
 716         ])
 717 ])
 718
 719 dnl #
 720 dnl # ZFS_LINUX_TEST_RESULT
 721 dnl #
 722 dnl # $1 - name of a test source (ZFS_LINUX_TEST_SRC)
 723 dnl # $2 - run on success (valid .ko generated)
 724 dnl # $3 - run on failure (unable to compile)
 725 dnl #
 726 AC_DEFUN([ZFS_LINUX_TEST_RESULT], [
 727         AS_IF([test -d build/$1], [
 728                 AS_IF([test -f build/$1/$1.ko], [$2], [$3])
 729         ], [
 730                 AC_MSG_ERROR([
 731         *** No matching source for the "$1" test, check that
 732         *** both the test source and result macros refer to the same name.
 733                 ])
 734         ])
 735 ])
 736
 737 dnl #
 738 dnl # ZFS_LINUX_TEST_ERROR
 739 dnl #
 740 dnl # Generic error message which can be used when none of the expected
 741 dnl # kernel interfaces were detected.
 742 dnl #
 743 AC_DEFUN([ZFS_LINUX_TEST_ERROR], [
 744         AC_MSG_ERROR([
 745         *** None of the expected "$1" interfaces were detected.
 746         *** This may be because your kernel version is newer than what is
 747         *** supported, or you are using a patched custom kernel with
 748         *** incompatible modifications.
 749         ***
 750         *** ZFS Version: $ZFS_META_ALIAS
 751         *** Compatible Kernels: $ZFS_META_KVER_MIN - $ZFS_META_KVER_MAX
 752         ])
 753 ])
 754
 755 dnl #
 756 dnl # ZFS_LINUX_TEST_RESULT_SYMBOL
 757 dnl #
 758 dnl # Like ZFS_LINUX_TEST_RESULT except ZFS_CHECK_SYMBOL_EXPORT is called to
 759 dnl # verify symbol exports, unless --enable-linux-builtin was provided to
 760 dnl # configure.
 761 dnl #
 762 AC_DEFUN([ZFS_LINUX_TEST_RESULT_SYMBOL], [
 763         AS_IF([ ! test -f build/$1/$1.ko], [
 764                 $5
 765         ], [
 766                 AS_IF([test "x$enable_linux_builtin" != "xyes"], [
 767                         ZFS_CHECK_SYMBOL_EXPORT([$2], [$3], [$4], [$5])
 768                 ], [
 769                         $4
 770                 ])
 771         ])
 772 ])
 773
 774 dnl #
 775 dnl # ZFS_LINUX_COMPILE_IFELSE
 776 dnl #
 777 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 778         ZFS_LINUX_TEST_REMOVE([conftest])
 779
 780         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1], [conftest])])
 781         m4_ifvaln([$5], [ZFS_LINUX_CONFTEST_H([$5], [conftest])],
 782             [ZFS_LINUX_CONFTEST_H([], [conftest])])
 783
 784         ZFS_LINUX_CONFTEST_MAKEFILE([conftest], [no],
 785             [m4_ifvaln([$5], [-I$PWD/build/conftest], [])])
 786         ZFS_LINUX_COMPILE([build/conftest], [$2], [$3], [$4], [], [])
 787 ])
 788
 789 dnl #
 790 dnl # ZFS_LINUX_TRY_COMPILE
 791 dnl #
 792 dnl # $1 - global
 793 dnl # $2 - source
 794 dnl # $3 - run on success (valid .ko generated)
 795 dnl # $4 - run on failure (unable to compile)
 796 dnl #
 797 dnl # When configuring as builtin (--enable-linux-builtin) for kernels
 798 dnl # without loadable module support (CONFIG_MODULES=n) only the object
 799 dnl # file is created.  See ZFS_LINUX_TEST_COMPILE_ALL for details.
 800 dnl #
 801 AC_DEFUN([ZFS_LINUX_TRY_COMPILE], [
 802         AS_IF([test "x$enable_linux_builtin" = "xyes"], [
 803                 ZFS_LINUX_COMPILE_IFELSE(
 804                     [ZFS_LINUX_TEST_PROGRAM([[$1]], [[$2]],
 805                     [[ZFS_META_LICENSE]])],
 806                     [test -f build/conftest/conftest.o], [$3], [$4])
 807         ], [
 808                 ZFS_LINUX_COMPILE_IFELSE(
 809                     [ZFS_LINUX_TEST_PROGRAM([[$1]], [[$2]],
 810                     [[ZFS_META_LICENSE]])],
 811                     [test -f build/conftest/conftest.ko], [$3], [$4])
 812         ])
 813 ])
 814
 815 dnl #
 816 dnl # ZFS_CHECK_SYMBOL_EXPORT
 817 dnl #
 818 dnl # Check if a symbol is exported on not by consulting the symbols
 819 dnl # file, or optionally the source code.
 820 dnl #
 821 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 822         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 823                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 824         rc=$?
 825         if test $rc -ne 0; then
 826                 export=0
 827                 for file in $2; do
 828                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 829                                 "$LINUX/$file" 2>/dev/null
 830                         rc=$?
 831                         if test $rc -eq 0; then
 832                                 export=1
 833                                 break;
 834                         fi
 835                 done
 836                 if test $export -eq 0; then :
 837                         $4
 838                 else :
 839                         $3
 840                 fi
 841         else :
 842                 $3
 843         fi
 844 ])
 845
 846 dnl #
 847 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 848 dnl #
 849 dnl # Like ZFS_LINUX_TRY_COMPILER except ZFS_CHECK_SYMBOL_EXPORT is called
 850 dnl # to verify symbol exports, unless --enable-linux-builtin was provided
 851 dnl # to configure.
 852 dnl #
 853 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 854         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 855         if test $rc -ne 0; then :
 856                 $6
 857         else
 858                 if test "x$enable_linux_builtin" != xyes; then
 859                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 860                 fi
 861                 if test $rc -ne 0; then :
 862                         $6
 863                 else :
 864                         $5
 865                 fi
 866         fi
 867 ])
 868
 869 dnl #
 870 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 871 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 872 dnl # provided via the fifth parameter
 873 dnl #
 874 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER], [
 875         ZFS_LINUX_COMPILE_IFELSE(
 876             [ZFS_LINUX_TEST_PROGRAM([[$1]], [[$2]], [[ZFS_META_LICENSE]])],
 877             [test -f build/conftest/conftest.ko],
 878             [$3], [$4], [$5])
 879 ])