config/zfs-build.m4

   1 AC_DEFUN([ZFS_AC_LICENSE], [
   2         AC_MSG_CHECKING([zfs author])
   3         AC_MSG_RESULT([$ZFS_META_AUTHOR])
   4
   5         AC_MSG_CHECKING([zfs license])
   6         AC_MSG_RESULT([$ZFS_META_LICENSE])
   7 ])
   8
   9 AC_DEFUN([ZFS_AC_DEBUG_ENABLE], [
  10         DEBUG_CFLAGS="-Werror"
  11         DEBUG_CPPFLAGS="-DDEBUG -UNDEBUG"
  12         DEBUG_LDFLAGS=""
  13         DEBUG_ZFS="_with_debug"
  14         WITH_DEBUG="true"
  15         AC_DEFINE(ZFS_DEBUG, 1, [zfs debugging enabled])
  16
  17         KERNEL_DEBUG_CFLAGS="-Werror"
  18         KERNEL_DEBUG_CPPFLAGS="-DDEBUG -UNDEBUG"
  19 ])
  20
  21 AC_DEFUN([ZFS_AC_DEBUG_DISABLE], [
  22         DEBUG_CFLAGS=""
  23         DEBUG_CPPFLAGS="-UDEBUG -DNDEBUG"
  24         DEBUG_LDFLAGS=""
  25         DEBUG_ZFS="_without_debug"
  26         WITH_DEBUG=""
  27
  28         KERNEL_DEBUG_CFLAGS=""
  29         KERNEL_DEBUG_CPPFLAGS="-UDEBUG -DNDEBUG"
  30 ])
  31
  32 dnl #
  33 dnl # When debugging is enabled:
  34 dnl # - Enable all ASSERTs (-DDEBUG)
  35 dnl # - Promote all compiler warnings to errors (-Werror)
  36 dnl #
  37 dnl # (If INVARIANTS is detected, we need to force DEBUG, or strange panics
  38 dnl # can ensue.)
  39 dnl #
  40 AC_DEFUN([ZFS_AC_DEBUG], [
  41         AC_MSG_CHECKING([whether assertion support will be enabled])
  42         AC_ARG_ENABLE([debug],
  43                 [AS_HELP_STRING([--enable-debug],
  44                 [Enable compiler and code assertions @<:@default=no@:>@])],
  45                 [],
  46                 [enable_debug=no])
  47
  48         AS_CASE(["x$enable_debug"],
  49                 ["xyes"],
  50                 [ZFS_AC_DEBUG_ENABLE],
  51                 ["xno"],
  52                 [ZFS_AC_DEBUG_DISABLE],
  53                 [AC_MSG_ERROR([Unknown option $enable_debug])])
  54
  55         AS_CASE(["x$enable_invariants"],
  56                 ["xyes"],
  57                 [],
  58                 ["xno"],
  59                 [],
  60                 [ZFS_AC_DEBUG_INVARIANTS_DETECT])
  61
  62         AS_CASE(["x$enable_invariants"],
  63                 ["xyes"],
  64                 [ZFS_AC_DEBUG_ENABLE],
  65                 ["xno"],
  66                 [],
  67                 [AC_MSG_ERROR([Unknown option $enable_invariants])])
  68
  69         AC_SUBST(DEBUG_CFLAGS)
  70         AC_SUBST(DEBUG_CPPFLAGS)
  71         AC_SUBST(DEBUG_LDFLAGS)
  72         AC_SUBST(DEBUG_ZFS)
  73         AC_SUBST(WITH_DEBUG)
  74
  75         AC_SUBST(KERNEL_DEBUG_CFLAGS)
  76         AC_SUBST(KERNEL_DEBUG_CPPFLAGS)
  77
  78         AC_MSG_RESULT([$enable_debug])
  79 ])
  80
  81 AC_DEFUN([ZFS_AC_DEBUGINFO_ENABLE], [
  82         DEBUG_CFLAGS="$DEBUG_CFLAGS -g -fno-inline $NO_IPA_SRA"
  83
  84         KERNEL_DEBUG_CFLAGS="$KERNEL_DEBUG_CFLAGS -fno-inline $KERNEL_NO_IPA_SRA"
  85         KERNEL_MAKE="$KERNEL_MAKE CONFIG_DEBUG_INFO=y"
  86
  87         DEBUGINFO_ZFS="_with_debuginfo"
  88 ])
  89
  90 AC_DEFUN([ZFS_AC_DEBUGINFO_DISABLE], [
  91         DEBUGINFO_ZFS="_without_debuginfo"
  92 ])
  93
  94 AC_DEFUN([ZFS_AC_DEBUGINFO], [
  95         AC_MSG_CHECKING([whether debuginfo support will be forced])
  96         AC_ARG_ENABLE([debuginfo],
  97                 [AS_HELP_STRING([--enable-debuginfo],
  98                 [Force generation of debuginfo @<:@default=no@:>@])],
  99                 [],
 100                 [enable_debuginfo=no])
 101
 102         AS_CASE(["x$enable_debuginfo"],
 103                 ["xyes"],
 104                 [ZFS_AC_DEBUGINFO_ENABLE],
 105                 ["xno"],
 106                 [ZFS_AC_DEBUGINFO_DISABLE],
 107                 [AC_MSG_ERROR([Unknown option $enable_debuginfo])])
 108
 109         AC_SUBST(DEBUG_CFLAGS)
 110         AC_SUBST(DEBUGINFO_ZFS)
 111
 112         AC_SUBST(KERNEL_DEBUG_CFLAGS)
 113         AC_SUBST(KERNEL_MAKE)
 114
 115         AC_MSG_RESULT([$enable_debuginfo])
 116 ])
 117
 118 dnl #
 119 dnl # Disabled by default, provides basic memory tracking.  Track the total
 120 dnl # number of bytes allocated with kmem_alloc() and freed with kmem_free().
 121 dnl # Then at module unload time if any bytes were leaked it will be reported
 122 dnl # on the console.
 123 dnl #
 124 AC_DEFUN([ZFS_AC_DEBUG_KMEM], [
 125         AC_MSG_CHECKING([whether basic kmem accounting is enabled])
 126         AC_ARG_ENABLE([debug-kmem],
 127                 [AS_HELP_STRING([--enable-debug-kmem],
 128                 [Enable basic kmem accounting @<:@default=no@:>@])],
 129                 [],
 130                 [enable_debug_kmem=no])
 131
 132         AS_IF([test "x$enable_debug_kmem" = xyes], [
 133                 KERNEL_DEBUG_CPPFLAGS="${KERNEL_DEBUG_CPPFLAGS} -DDEBUG_KMEM"
 134                 DEBUG_KMEM_ZFS="_with_debug_kmem"
 135         ], [
 136                 DEBUG_KMEM_ZFS="_without_debug_kmem"
 137         ])
 138
 139         AC_SUBST(KERNEL_DEBUG_CPPFLAGS)
 140         AC_SUBST(DEBUG_KMEM_ZFS)
 141
 142         AC_MSG_RESULT([$enable_debug_kmem])
 143 ])
 144
 145 dnl #
 146 dnl # Disabled by default, provides detailed memory tracking.  This feature
 147 dnl # also requires --enable-debug-kmem to be set.  When enabled not only will
 148 dnl # total bytes be tracked but also the location of every kmem_alloc() and
 149 dnl # kmem_free().  When the module is unloaded a list of all leaked addresses
 150 dnl # and where they were allocated will be dumped to the console.  Enabling
 151 dnl # this feature has a significant impact on performance but it makes finding
 152 dnl # memory leaks straight forward.
 153 dnl #
 154 AC_DEFUN([ZFS_AC_DEBUG_KMEM_TRACKING], [
 155         AC_MSG_CHECKING([whether detailed kmem tracking is enabled])
 156         AC_ARG_ENABLE([debug-kmem-tracking],
 157                 [AS_HELP_STRING([--enable-debug-kmem-tracking],
 158                 [Enable detailed kmem tracking  @<:@default=no@:>@])],
 159                 [],
 160                 [enable_debug_kmem_tracking=no])
 161
 162         AS_IF([test "x$enable_debug_kmem_tracking" = xyes], [
 163                 KERNEL_DEBUG_CPPFLAGS="${KERNEL_DEBUG_CPPFLAGS} -DDEBUG_KMEM_TRACKING"
 164                 DEBUG_KMEM_TRACKING_ZFS="_with_debug_kmem_tracking"
 165         ], [
 166                 DEBUG_KMEM_TRACKING_ZFS="_without_debug_kmem_tracking"
 167         ])
 168
 169         AC_SUBST(KERNEL_DEBUG_CPPFLAGS)
 170         AC_SUBST(DEBUG_KMEM_TRACKING_ZFS)
 171
 172         AC_MSG_RESULT([$enable_debug_kmem_tracking])
 173 ])
 174
 175 AC_DEFUN([ZFS_AC_DEBUG_INVARIANTS_DETECT_FREEBSD], [
 176         AS_IF([sysctl -n kern.conftxt | grep -Fqx $'options\tINVARIANTS'],
 177                 [enable_invariants="yes"],
 178                 [enable_invariants="no"])
 179 ])
 180
 181 AC_DEFUN([ZFS_AC_DEBUG_INVARIANTS_DETECT], [
 182         AM_COND_IF([BUILD_FREEBSD],
 183                 [ZFS_AC_DEBUG_INVARIANTS_DETECT_FREEBSD],
 184                 [enable_invariants="no"])
 185 ])
 186
 187 dnl #
 188 dnl # Detected for the running kernel by default, enables INVARIANTS features
 189 dnl # in the FreeBSD kernel module.  This feature must be used when building
 190 dnl # for a FreeBSD kernel with "options INVARIANTS" in the KERNCONF and must
 191 dnl # not be used when the INVARIANTS option is absent.
 192 dnl #
 193 AC_DEFUN([ZFS_AC_DEBUG_INVARIANTS], [
 194         AC_MSG_CHECKING([whether FreeBSD kernel INVARIANTS checks are enabled])
 195         AC_ARG_ENABLE([invariants],
 196                 [AS_HELP_STRING([--enable-invariants],
 197                 [Enable FreeBSD kernel INVARIANTS checks [[default: detect]]])],
 198                 [], [ZFS_AC_DEBUG_INVARIANTS_DETECT])
 199
 200         AS_IF([test "x$enable_invariants" = xyes],
 201                 [WITH_INVARIANTS="true"],
 202                 [WITH_INVARIANTS=""])
 203         AC_SUBST(WITH_INVARIANTS)
 204
 205         AC_MSG_RESULT([$enable_invariants])
 206 ])
 207
 208 AC_DEFUN([ZFS_AC_CONFIG_ALWAYS], [
 209         AX_COUNT_CPUS([])
 210         AC_SUBST(CPU_COUNT)
 211
 212         ZFS_AC_CONFIG_ALWAYS_CC_NO_CLOBBERED
 213         ZFS_AC_CONFIG_ALWAYS_CC_INFINITE_RECURSION
 214         ZFS_AC_CONFIG_ALWAYS_KERNEL_CC_INFINITE_RECURSION
 215         ZFS_AC_CONFIG_ALWAYS_CC_IMPLICIT_FALLTHROUGH
 216         ZFS_AC_CONFIG_ALWAYS_CC_FRAME_LARGER_THAN
 217         ZFS_AC_CONFIG_ALWAYS_CC_NO_FORMAT_TRUNCATION
 218         ZFS_AC_CONFIG_ALWAYS_CC_NO_FORMAT_ZERO_LENGTH
 219         ZFS_AC_CONFIG_ALWAYS_CC_FORMAT_OVERFLOW
 220         ZFS_AC_CONFIG_ALWAYS_CC_NO_OMIT_FRAME_POINTER
 221         ZFS_AC_CONFIG_ALWAYS_CC_NO_IPA_SRA
 222         ZFS_AC_CONFIG_ALWAYS_KERNEL_CC_NO_IPA_SRA
 223         ZFS_AC_CONFIG_ALWAYS_CC_ASAN
 224         ZFS_AC_CONFIG_ALWAYS_CC_UBSAN
 225         ZFS_AC_CONFIG_ALWAYS_TOOLCHAIN_SIMD
 226         ZFS_AC_CONFIG_ALWAYS_SYSTEM
 227         ZFS_AC_CONFIG_ALWAYS_ARCH
 228         ZFS_AC_CONFIG_ALWAYS_PYTHON
 229         ZFS_AC_CONFIG_ALWAYS_PYZFS
 230         ZFS_AC_CONFIG_ALWAYS_SED
 231         ZFS_AC_CONFIG_ALWAYS_CPPCHECK
 232         ZFS_AC_CONFIG_ALWAYS_SHELLCHECK
 233         ZFS_AC_CONFIG_ALWAYS_PARALLEL
 234 ])
 235
 236 AC_DEFUN([ZFS_AC_CONFIG], [
 237
 238         dnl # Remove the previous build test directory.
 239         rm -Rf build
 240
 241         ZFS_CONFIG=all
 242         AC_ARG_WITH([config],
 243                 AS_HELP_STRING([--with-config=CONFIG],
 244                 [Config file 'kernel|user|all|srpm']),
 245                 [ZFS_CONFIG="$withval"])
 246         AC_ARG_ENABLE([linux-builtin],
 247                 [AS_HELP_STRING([--enable-linux-builtin],
 248                 [Configure for builtin in-tree kernel modules @<:@default=no@:>@])],
 249                 [],
 250                 [enable_linux_builtin=no])
 251
 252         AC_MSG_CHECKING([zfs config])
 253         AC_MSG_RESULT([$ZFS_CONFIG]);
 254         AC_SUBST(ZFS_CONFIG)
 255
 256         ZFS_AC_CONFIG_ALWAYS
 257
 258         AM_COND_IF([BUILD_LINUX], [
 259                 AC_ARG_VAR([TEST_JOBS], [simultaneous jobs during configure])
 260                 if test "x$ac_cv_env_TEST_JOBS_set" != "xset"; then
 261                         TEST_JOBS=$CPU_COUNT
 262                 fi
 263                 AC_SUBST(TEST_JOBS)
 264         ])
 265
 266         ZFS_INIT_SYSV=
 267         ZFS_INIT_SYSTEMD=
 268         ZFS_WANT_MODULES_LOAD_D=
 269
 270         case "$ZFS_CONFIG" in
 271                 kernel) ZFS_AC_CONFIG_KERNEL ;;
 272                 user)   ZFS_AC_CONFIG_USER   ;;
 273                 all)    ZFS_AC_CONFIG_USER
 274                         ZFS_AC_CONFIG_KERNEL ;;
 275                 dist)                        ;;
 276                 srpm)                        ;;
 277                 *)
 278                 AC_MSG_RESULT([Error!])
 279                 AC_MSG_ERROR([Bad value "$ZFS_CONFIG" for --with-config,
 280                               user kernel|user|all|srpm]) ;;
 281         esac
 282
 283         AM_CONDITIONAL([INIT_SYSV],           [test "x$ZFS_INIT_SYSV" = "xyes"])
 284         AM_CONDITIONAL([INIT_SYSTEMD],        [test "x$ZFS_INIT_SYSTEMD" = "xyes"])
 285         AM_CONDITIONAL([WANT_MODULES_LOAD_D], [test "x$ZFS_WANT_MODULES_LOAD_D" = "xyes"])
 286
 287         AM_CONDITIONAL([CONFIG_USER],
 288             [test "$ZFS_CONFIG" = user -o "$ZFS_CONFIG" = all])
 289         AM_CONDITIONAL([CONFIG_KERNEL],
 290             [test "$ZFS_CONFIG" = kernel -o "$ZFS_CONFIG" = all] &&
 291             [test "x$enable_linux_builtin" != xyes ])
 292         AM_CONDITIONAL([CONFIG_QAT],
 293             [test "$ZFS_CONFIG" = kernel -o "$ZFS_CONFIG" = all] &&
 294             [test "x$qatsrc" != x ])
 295         AM_CONDITIONAL([WANT_DEVNAME2DEVID], [test "x$user_libudev" = xyes ])
 296         AM_CONDITIONAL([WANT_MMAP_LIBAIO], [test "x$user_libaio" = xyes ])
 297         AM_CONDITIONAL([PAM_ZFS_ENABLED], [test "x$enable_pam" = xyes])
 298 ])
 299
 300 dnl #
 301 dnl # Check for rpm+rpmbuild to build RPM packages.  If these tools
 302 dnl # are missing it is non-fatal but you will not be able to build
 303 dnl # RPM packages and will be warned if you try too.
 304 dnl #
 305 dnl # By default the generic spec file will be used because it requires
 306 dnl # minimal dependencies.  Distribution specific spec files can be
 307 dnl # placed under the 'rpm/<distribution>' directory and enabled using
 308 dnl # the --with-spec=<distribution> configure option.
 309 dnl #
 310 AC_DEFUN([ZFS_AC_RPM], [
 311         RPM=rpm
 312         RPMBUILD=rpmbuild
 313
 314         AC_MSG_CHECKING([whether $RPM is available])
 315         AS_IF([tmp=$($RPM --version 2>/dev/null)], [
 316                 RPM_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 317                 HAVE_RPM=yes
 318                 AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
 319         ],[
 320                 HAVE_RPM=no
 321                 AC_MSG_RESULT([$HAVE_RPM])
 322         ])
 323
 324         AC_MSG_CHECKING([whether $RPMBUILD is available])
 325         AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
 326                 RPMBUILD_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 327                 HAVE_RPMBUILD=yes
 328                 AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
 329         ],[
 330                 HAVE_RPMBUILD=no
 331                 AC_MSG_RESULT([$HAVE_RPMBUILD])
 332         ])
 333
 334         RPM_DEFINE_COMMON='--define "$(DEBUG_ZFS) 1"'
 335         RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(DEBUGINFO_ZFS) 1"'
 336         RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(DEBUG_KMEM_ZFS) 1"'
 337         RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(DEBUG_KMEM_TRACKING_ZFS) 1"'
 338         RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(ASAN_ZFS) 1"'
 339         RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(UBSAN_ZFS) 1"'
 340
 341         AS_IF([test "x$enable_debuginfo" = xyes], [
 342                 RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "__strip /bin/true"'
 343         ])
 344
 345         RPM_DEFINE_UTIL=' --define "_initconfdir $(initconfdir)"'
 346
 347         dnl # Make the next three RPM_DEFINE_UTIL additions conditional, since
 348         dnl # their values may not be set when running:
 349         dnl #
 350         dnl #   ./configure --with-config=srpm
 351         dnl #
 352         AS_IF([test -n "$dracutdir" ], [
 353                 RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' --define "_dracutdir $(dracutdir)"'
 354         ])
 355         AS_IF([test -n "$udevdir" ], [
 356                 RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' --define "_udevdir $(udevdir)"'
 357         ])
 358         AS_IF([test -n "$udevruledir" ], [
 359                 RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' --define "_udevruledir $(udevruledir)"'
 360         ])
 361         AS_IF([test -n "$bashcompletiondir" ], [
 362                 RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' --define "_bashcompletiondir $(bashcompletiondir)"'
 363         ])
 364         RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_SYSTEMD)'
 365         RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_PYZFS)'
 366         RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_PAM)'
 367         RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_PYTHON_VERSION)'
 368         RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_PYTHON_PKG_VERSION)'
 369
 370         dnl # Override default lib directory on Debian/Ubuntu systems.  The
 371         dnl # provided /usr/lib/rpm/platform/<arch>/macros files do not
 372         dnl # specify the correct path for multiarch systems as described
 373         dnl # by the packaging guidelines.
 374         dnl #
 375         dnl # https://wiki.ubuntu.com/MultiarchSpec
 376         dnl # https://wiki.debian.org/Multiarch/Implementation
 377         dnl #
 378         AS_IF([test "$DEFAULT_PACKAGE" = "deb"], [
 379                 MULTIARCH_LIBDIR="lib/$(dpkg-architecture -qDEB_HOST_MULTIARCH)"
 380                 RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' --define "_lib $(MULTIARCH_LIBDIR)"'
 381                 AC_SUBST(MULTIARCH_LIBDIR)
 382         ])
 383
 384         dnl # Make RPM_DEFINE_KMOD additions conditional on CONFIG_KERNEL,
 385         dnl # since the values will not be set otherwise. The spec files
 386         dnl # provide defaults for them.
 387         dnl #
 388         RPM_DEFINE_KMOD='--define "_wrong_version_format_terminate_build 0"'
 389         AM_COND_IF([CONFIG_KERNEL], [
 390                 RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "kernels $(LINUX_VERSION)"'
 391                 RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "ksrc $(LINUX)"'
 392                 RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "kobj $(LINUX_OBJ)"'
 393                 RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "kernel_cc KERNEL_CC=$(KERNEL_CC)"'
 394                 RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "kernel_ld KERNEL_LD=$(KERNEL_LD)"'
 395                 RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "kernel_llvm KERNEL_LLVM=$(KERNEL_LLVM)"'
 396         ])
 397
 398         RPM_DEFINE_DKMS=''
 399
 400         SRPM_DEFINE_COMMON='--define "build_src_rpm 1"'
 401         SRPM_DEFINE_UTIL=
 402         SRPM_DEFINE_KMOD=
 403         SRPM_DEFINE_DKMS=
 404
 405         RPM_SPEC_DIR="rpm/generic"
 406         AC_ARG_WITH([spec],
 407                 AS_HELP_STRING([--with-spec=SPEC],
 408                 [Spec files 'generic|redhat']),
 409                 [RPM_SPEC_DIR="rpm/$withval"])
 410
 411         AC_MSG_CHECKING([whether spec files are available])
 412         AC_MSG_RESULT([yes ($RPM_SPEC_DIR/*.spec.in)])
 413
 414         AC_SUBST(HAVE_RPM)
 415         AC_SUBST(RPM)
 416         AC_SUBST(RPM_VERSION)
 417
 418         AC_SUBST(HAVE_RPMBUILD)
 419         AC_SUBST(RPMBUILD)
 420         AC_SUBST(RPMBUILD_VERSION)
 421
 422         AC_SUBST(RPM_SPEC_DIR)
 423         AC_SUBST(RPM_DEFINE_UTIL)
 424         AC_SUBST(RPM_DEFINE_KMOD)
 425         AC_SUBST(RPM_DEFINE_DKMS)
 426         AC_SUBST(RPM_DEFINE_COMMON)
 427         AC_SUBST(SRPM_DEFINE_UTIL)
 428         AC_SUBST(SRPM_DEFINE_KMOD)
 429         AC_SUBST(SRPM_DEFINE_DKMS)
 430         AC_SUBST(SRPM_DEFINE_COMMON)
 431 ])
 432
 433 dnl #
 434 dnl # Check for dpkg+dpkg-buildpackage to build DEB packages.  If these
 435 dnl # tools are missing it is non-fatal but you will not be able to build
 436 dnl # DEB packages and will be warned if you try too.
 437 dnl #
 438 AC_DEFUN([ZFS_AC_DPKG], [
 439         DPKG=dpkg
 440         DPKGBUILD=dpkg-buildpackage
 441
 442         AC_MSG_CHECKING([whether $DPKG is available])
 443         AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
 444                 DPKG_VERSION=$(echo $tmp | $AWK '/Debian/ { print $[7] }')
 445                 HAVE_DPKG=yes
 446                 AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
 447         ],[
 448                 HAVE_DPKG=no
 449                 AC_MSG_RESULT([$HAVE_DPKG])
 450         ])
 451
 452         AC_MSG_CHECKING([whether $DPKGBUILD is available])
 453         AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
 454                 DPKGBUILD_VERSION=$(echo $tmp | \
 455                     $AWK '/Debian/ { print $[4] }' | cut -f-4 -d'.')
 456                 HAVE_DPKGBUILD=yes
 457                 AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
 458         ],[
 459                 HAVE_DPKGBUILD=no
 460                 AC_MSG_RESULT([$HAVE_DPKGBUILD])
 461         ])
 462
 463         AC_SUBST(HAVE_DPKG)
 464         AC_SUBST(DPKG)
 465         AC_SUBST(DPKG_VERSION)
 466
 467         AC_SUBST(HAVE_DPKGBUILD)
 468         AC_SUBST(DPKGBUILD)
 469         AC_SUBST(DPKGBUILD_VERSION)
 470         AC_SUBST([CFGOPTS], ["$CFGOPTS"])
 471 ])
 472
 473 dnl #
 474 dnl # Until native packaging for various different packing systems
 475 dnl # can be added the least we can do is attempt to use alien to
 476 dnl # convert the RPM packages to the needed package type.  This is
 477 dnl # a hack but so far it has worked reasonable well.
 478 dnl #
 479 AC_DEFUN([ZFS_AC_ALIEN], [
 480         ALIEN=alien
 481
 482         AC_MSG_CHECKING([whether $ALIEN is available])
 483         AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
 484                 ALIEN_VERSION=$(echo $tmp | $AWK '{ print $[3] }')
 485                 ALIEN_MAJOR=$(echo ${ALIEN_VERSION} | $AWK -F'.' '{ print $[1] }')
 486                 ALIEN_MINOR=$(echo ${ALIEN_VERSION} | $AWK -F'.' '{ print $[2] }')
 487                 ALIEN_POINT=$(echo ${ALIEN_VERSION} | $AWK -F'.' '{ print $[3] }')
 488                 HAVE_ALIEN=yes
 489                 AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
 490         ],[
 491                 HAVE_ALIEN=no
 492                 AC_MSG_RESULT([$HAVE_ALIEN])
 493         ])
 494
 495         AC_SUBST(HAVE_ALIEN)
 496         AC_SUBST(ALIEN)
 497         AC_SUBST(ALIEN_VERSION)
 498         AC_SUBST(ALIEN_MAJOR)
 499         AC_SUBST(ALIEN_MINOR)
 500         AC_SUBST(ALIEN_POINT)
 501 ])
 502
 503 dnl #
 504 dnl # Using the VENDOR tag from config.guess set the default
 505 dnl # package type for 'make pkg': (rpm | deb | tgz)
 506 dnl #
 507 AC_DEFUN([ZFS_AC_DEFAULT_PACKAGE], [
 508         AC_MSG_CHECKING([os distribution])
 509         AC_ARG_WITH([vendor],
 510                 [AS_HELP_STRING([--with-vendor],
 511                         [Distribution vendor @<:@default=check@:>@])],
 512                 [with_vendor=$withval],
 513                 [with_vendor=check])
 514         AS_IF([test "x$with_vendor" = "xcheck"],[
 515                 if test -f /etc/alpine-release ; then
 516                         VENDOR=alpine ;
 517                 elif test -f /etc/arch-release ; then
 518                         VENDOR=arch ;
 519                 elif test -f /etc/artix-release ; then
 520                         VENDOR=artix ;
 521                 elif test -f /etc/fedora-release ; then
 522                         VENDOR=fedora ;
 523                 elif test -f /bin/freebsd-version ; then
 524                         VENDOR=freebsd ;
 525                 elif test -f /etc/gentoo-release ; then
 526                         VENDOR=gentoo ;
 527                 elif test -f /etc/lunar.release ; then
 528                         VENDOR=lunar ;
 529                 elif test -f /etc/openEuler-release ; then
 530                         VENDOR=openeuler ;
 531                 elif test -f /etc/SuSE-release ; then
 532                         VENDOR=sles ;
 533                 elif test -f /etc/slackware-version ; then
 534                         VENDOR=slackware ;
 535                 elif test -f /etc/toss-release ; then
 536                         VENDOR=toss ;
 537                 elif test -f /etc/lsb-release ; then
 538                         VENDOR=ubuntu ;
 539                 # put debian and redhat last as derivatives may have also their file
 540                 elif test -f /etc/debian_version ; then
 541                         VENDOR=debian ;
 542                 elif test -f /etc/redhat-release ; then
 543                         VENDOR=redhat ;
 544                 else
 545                         VENDOR= ;
 546                 fi],
 547                 [ test "x${with_vendor}" != x],[
 548                         VENDOR="$with_vendor" ],
 549                 [ VENDOR= ; ]
 550         )
 551         AC_MSG_RESULT([$VENDOR])
 552         AC_SUBST(VENDOR)
 553
 554         AC_MSG_CHECKING([default package type])
 555         case "$VENDOR" in
 556                 alpine|arch|artix|gentoo|lunar|slackware)
 557                         DEFAULT_PACKAGE=tgz  ;;
 558                 debian|ubuntu)
 559                         DEFAULT_PACKAGE=deb  ;;
 560                 freebsd)
 561                         DEFAULT_PACKAGE=pkg  ;;
 562                 *)
 563                 # fedora|openeuler|redhat|sles|toss
 564                         DEFAULT_PACKAGE=rpm  ;;
 565         esac
 566         AC_MSG_RESULT([$DEFAULT_PACKAGE])
 567         AC_SUBST(DEFAULT_PACKAGE)
 568
 569         AC_MSG_CHECKING([default init directory])
 570         case "$VENDOR" in
 571                 freebsd)    initdir=$sysconfdir/rc.d  ;;
 572                 *)          initdir=$sysconfdir/init.d;;
 573         esac
 574         AC_MSG_RESULT([$initdir])
 575         AC_SUBST(initdir)
 576
 577         AC_MSG_CHECKING([default shell])
 578         case "$VENDOR" in
 579                 alpine|gentoo)  DEFAULT_INIT_SHELL=/sbin/openrc-run
 580                                 IS_SYSV_RC=false        ;;
 581                 artix)          DEFAULT_INIT_SHELL=/usr/bin/openrc-run
 582                                 IS_SYSV_RC=false        ;;
 583                 *)              DEFAULT_INIT_SHELL=/bin/sh
 584                                 IS_SYSV_RC=true         ;;
 585         esac
 586
 587         AC_MSG_RESULT([$DEFAULT_INIT_SHELL])
 588         AC_SUBST(DEFAULT_INIT_SHELL)
 589         AC_SUBST(IS_SYSV_RC)
 590
 591         AC_MSG_CHECKING([default nfs server init script])
 592         AS_IF([test "$VENDOR" = "debian"],
 593                 [DEFAULT_INIT_NFS_SERVER="nfs-kernel-server"],
 594                 [DEFAULT_INIT_NFS_SERVER="nfs"]
 595         )
 596         AC_MSG_RESULT([$DEFAULT_INIT_NFS_SERVER])
 597         AC_SUBST(DEFAULT_INIT_NFS_SERVER)
 598
 599         AC_MSG_CHECKING([default init config directory])
 600         case "$VENDOR" in
 601                 alpine|artix|gentoo)
 602                         initconfdir=/etc/conf.d
 603                         ;;
 604                 fedora|openeuler|redhat|sles|toss)
 605                         initconfdir=/etc/sysconfig
 606                         ;;
 607                 freebsd)
 608                         initconfdir=$sysconfdir/rc.conf.d
 609                         ;;
 610                 *)
 611                 # debian|ubuntu
 612                         initconfdir=/etc/default
 613                         ;;
 614         esac
 615         AC_MSG_RESULT([$initconfdir])
 616         AC_SUBST(initconfdir)
 617
 618         AC_MSG_CHECKING([whether initramfs-tools is available])
 619         if test -d /usr/share/initramfs-tools ; then
 620                 RPM_DEFINE_INITRAMFS='--define "_initramfs 1"'
 621                 AC_MSG_RESULT([yes])
 622         else
 623                 RPM_DEFINE_INITRAMFS=''
 624                 AC_MSG_RESULT([no])
 625         fi
 626         AC_SUBST(RPM_DEFINE_INITRAMFS)
 627
 628         AC_MSG_CHECKING([default bash completion directory])
 629         case "$VENDOR" in
 630                 alpine|artix|debian|gentoo|ubuntu)
 631                         bashcompletiondir=/usr/share/bash-completion/completions
 632                         ;;
 633                 freebsd)
 634                         bashcompletiondir=$sysconfdir/bash_completion.d
 635                         ;;
 636                 *)
 637                         bashcompletiondir=/etc/bash_completion.d
 638                         ;;
 639         esac
 640         AC_MSG_RESULT([$bashcompletiondir])
 641         AC_SUBST(bashcompletiondir)
 642
 643 ])
 644
 645 dnl #
 646 dnl # Default ZFS package configuration
 647 dnl #
 648 AC_DEFUN([ZFS_AC_PACKAGE], [
 649         ZFS_AC_DEFAULT_PACKAGE
 650         AS_IF([test x$VENDOR != xfreebsd], [
 651                 ZFS_AC_RPM
 652                 ZFS_AC_DPKG
 653                 ZFS_AC_ALIEN
 654         ])
 655 ])