config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  10         ZFS_AC_KERNEL_CURRENT_BIO_TAIL
  11         ZFS_AC_KERNEL_SUPER_USER_NS
  12         ZFS_AC_KERNEL_SUBMIT_BIO
  13         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  14         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  15         ZFS_AC_KERNEL_TYPE_FMODE_T
  16         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  17         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  18         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  19         ZFS_AC_KERNEL_LOOKUP_BDEV
  20         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  21         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  22         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  23         ZFS_AC_KERNEL_BIO_BVEC_ITER
  24         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  25         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  26         ZFS_AC_KERNEL_REQ_OP_DISCARD
  27         ZFS_AC_KERNEL_REQ_OP_SECURE_ERASE
  28         ZFS_AC_KERNEL_REQ_OP_FLUSH
  29         ZFS_AC_KERNEL_BIO_BI_OPF
  30         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  31         ZFS_AC_KERNEL_BIO_RW_BARRIER
  32         ZFS_AC_KERNEL_BIO_RW_DISCARD
  33         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  34         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  35         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  36         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BIO_RW_UNPLUG
  37         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BLK_PLUG
  38         ZFS_AC_KERNEL_GET_DISK_RO
  39         ZFS_AC_KERNEL_GET_GENDISK
  40         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  41         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  42         ZFS_AC_KERNEL_XATTR_HANDLER_NAME
  43         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  44         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  45         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  46         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  47         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  48         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  49         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  50         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  51         ZFS_AC_KERNEL_POSIX_ACL_VALID_WITH_NS
  52         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  53         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  54         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  55         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  56         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  57         ZFS_AC_KERNE_GET_ACL_HANDLE_CACHE
  58         ZFS_AC_KERNEL_SHOW_OPTIONS
  59         ZFS_AC_KERNEL_FILE_INODE
  60         ZFS_AC_KERNEL_FILE_DENTRY
  61         ZFS_AC_KERNEL_FSYNC
  62         ZFS_AC_KERNEL_EVICT_INODE
  63         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  64         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  65         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  66         ZFS_AC_KERNEL_FALLOCATE
  67         ZFS_AC_KERNEL_MKDIR_UMODE_T
  68         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  69         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  70         ZFS_AC_KERNEL_GET_LINK
  71         ZFS_AC_KERNEL_PUT_LINK
  72         ZFS_AC_KERNEL_TRUNCATE_RANGE
  73         ZFS_AC_KERNEL_AUTOMOUNT
  74         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  75         ZFS_AC_KERNEL_COMMIT_METADATA
  76         ZFS_AC_KERNEL_CLEAR_INODE
  77         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  78         ZFS_AC_KERNEL_D_MAKE_ROOT
  79         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  80         ZFS_AC_KERNEL_D_PRUNE_ALIASES
  81         ZFS_AC_KERNEL_D_SET_D_OP
  82         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  83         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  84         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  85         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  86         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  87         ZFS_AC_KERNEL_MOUNT_NODEV
  88         ZFS_AC_KERNEL_SHRINK
  89         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
  90         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
  91         ZFS_AC_KERNEL_S_D_OP
  92         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  93         ZFS_AC_KERNEL_SET_NLINK
  94         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  95         ZFS_AC_KERNEL_5ARG_SGET
  96         ZFS_AC_KERNEL_LSEEK_EXECUTE
  97         ZFS_AC_KERNEL_VFS_ITERATE
  98         ZFS_AC_KERNEL_VFS_RW_ITERATE
  99         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
 100         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
 101         ZFS_AC_KERNEL_MAKE_REQUEST_FN
 102         ZFS_AC_KERNEL_GENERIC_IO_ACCT
 103         ZFS_AC_KERNEL_FPU
 104         ZFS_AC_KERNEL_KUID_HELPERS
 105         ZFS_AC_KERNEL_MODULE_PARAM_CALL_CONST
 106
 107         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
 108                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
 109         ])
 110         AC_SUBST(KERNELMAKE_PARAMS)
 111
 112
 113         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
 114         dnl # compiler options are added by the kernel build system.
 115         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
 116         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_BOOL_COMPARE"
 117         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
 118         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
 119
 120         AC_SUBST(KERNELCPPFLAGS)
 121 ])
 122
 123 dnl #
 124 dnl # Detect name used for Module.symvers file in kernel
 125 dnl #
 126 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 127         modpost=$LINUX/scripts/Makefile.modpost
 128         AC_MSG_CHECKING([kernel file name for module symbols])
 129         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 130                 AS_IF([grep -q Modules.symvers $modpost], [
 131                         LINUX_SYMBOLS=Modules.symvers
 132                 ], [
 133                         LINUX_SYMBOLS=Module.symvers
 134                 ])
 135
 136                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 137                         AC_MSG_ERROR([
 138         *** Please make sure the kernel devel package for your distribution
 139         *** is installed.  If you are building with a custom kernel, make sure the
 140         *** kernel is configured, built, and the '--with-linux=PATH' configure
 141         *** option refers to the location of the kernel source.])
 142                 ])
 143         ], [
 144                 LINUX_SYMBOLS=NONE
 145         ])
 146         AC_MSG_RESULT($LINUX_SYMBOLS)
 147         AC_SUBST(LINUX_SYMBOLS)
 148 ])
 149
 150 dnl #
 151 dnl # Detect the kernel to be built against
 152 dnl #
 153 AC_DEFUN([ZFS_AC_KERNEL], [
 154         AC_ARG_WITH([linux],
 155                 AS_HELP_STRING([--with-linux=PATH],
 156                 [Path to kernel source]),
 157                 [kernelsrc="$withval"])
 158
 159         AC_ARG_WITH(linux-obj,
 160                 AS_HELP_STRING([--with-linux-obj=PATH],
 161                 [Path to kernel build objects]),
 162                 [kernelbuild="$withval"])
 163
 164         AC_MSG_CHECKING([kernel source directory])
 165         AS_IF([test -z "$kernelsrc"], [
 166                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 167                         headersdir="/lib/modules/$(uname -r)/source"
 168                         sourcelink=$(readlink -f "$headersdir")
 169                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 170                         headersdir="/lib/modules/$(uname -r)/build"
 171                         sourcelink=$(readlink -f "$headersdir")
 172                 ], [
 173                         sourcelink=$(ls -1d /usr/src/kernels/* \
 174                                      /usr/src/linux-* \
 175                                      2>/dev/null | grep -v obj | tail -1)
 176                 ])
 177
 178                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 179                         kernelsrc=`readlink -f ${sourcelink}`
 180                 ], [
 181                         kernelsrc="[Not found]"
 182                 ])
 183         ], [
 184                 AS_IF([test "$kernelsrc" = "NONE"], [
 185                         kernsrcver=NONE
 186                 ])
 187         ])
 188
 189         AC_MSG_RESULT([$kernelsrc])
 190         AS_IF([test ! -d "$kernelsrc"], [
 191                 AC_MSG_ERROR([
 192         *** Please make sure the kernel devel package for your distribution
 193         *** is installed and then try again.  If that fails, you can specify the
 194         *** location of the kernel source with the '--with-linux=PATH' option.])
 195         ])
 196
 197         AC_MSG_CHECKING([kernel build directory])
 198         AS_IF([test -z "$kernelbuild"], [
 199                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 200                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 201                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 202                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 203                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 204                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 205                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 206                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 207                 ], [
 208                         kernelbuild=${kernelsrc}
 209                 ])
 210         ])
 211         AC_MSG_RESULT([$kernelbuild])
 212
 213         AC_MSG_CHECKING([kernel source version])
 214         utsrelease1=$kernelbuild/include/linux/version.h
 215         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 216         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 217         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 218                 utsrelease=linux/version.h
 219         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 220                 utsrelease=linux/utsrelease.h
 221         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 222                 utsrelease=generated/utsrelease.h
 223         ])
 224
 225         AS_IF([test "$utsrelease"], [
 226                 kernsrcver=`(echo "#include <$utsrelease>";
 227                              echo "kernsrcver=UTS_RELEASE") |
 228                              cpp -I $kernelbuild/include |
 229                              grep "^kernsrcver=" | cut -d \" -f 2`
 230
 231                 AS_IF([test -z "$kernsrcver"], [
 232                         AC_MSG_RESULT([Not found])
 233                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 234                 ])
 235         ], [
 236                 AC_MSG_RESULT([Not found])
 237                 if test "x$enable_linux_builtin" != xyes; then
 238                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 239                 else
 240                         AC_MSG_ERROR([
 241         *** Cannot find UTS_RELEASE definition.
 242         *** Please run 'make prepare' inside the kernel source tree.])
 243                 fi
 244         ])
 245
 246         AC_MSG_RESULT([$kernsrcver])
 247
 248         LINUX=${kernelsrc}
 249         LINUX_OBJ=${kernelbuild}
 250         LINUX_VERSION=${kernsrcver}
 251
 252         AC_SUBST(LINUX)
 253         AC_SUBST(LINUX_OBJ)
 254         AC_SUBST(LINUX_VERSION)
 255
 256         ZFS_AC_MODULE_SYMVERS
 257 ])
 258
 259
 260 dnl #
 261 dnl # Detect the SPL module to be built against
 262 dnl #
 263 AC_DEFUN([ZFS_AC_SPL], [
 264         AC_ARG_WITH([spl],
 265                 AS_HELP_STRING([--with-spl=PATH],
 266                 [Path to spl source]),
 267                 AS_IF([test "$withval" = "yes"],
 268                         AC_MSG_ERROR([--with-spl=PATH requires a PATH]),
 269                         [splsrc="$withval"]))
 270
 271         AC_ARG_WITH([spl-obj],
 272                 AS_HELP_STRING([--with-spl-obj=PATH],
 273                 [Path to spl build objects]),
 274                 [splbuild="$withval"])
 275
 276         AC_ARG_WITH([spl-timeout],
 277                 AS_HELP_STRING([--with-spl-timeout=SECS],
 278                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 279                 [timeout="$withval"], [timeout=0])
 280
 281         dnl #
 282         dnl # The existence of spl.release.in is used to identify a valid
 283         dnl # source directory.  In order of preference:
 284         dnl #
 285         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 286         splsrc1="/usr/local/src/spl-${VERSION}/${LINUX_VERSION}"
 287         splsrc2="/usr/local/src/spl-${VERSION}"
 288         splsrc3="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 289         splsrc4="/usr/src/spl-${VERSION}"
 290         splsrc5="../spl/"
 291         splsrc6="$LINUX"
 292
 293         AC_MSG_CHECKING([spl source directory])
 294         AS_IF([test -z "${splsrc}"], [
 295                 [all_spl_sources="
 296                 ${splsrc0}
 297                 ${splsrc1}
 298                 ${splsrc2}
 299                 ${splsrc3}
 300                 ${splsrc4}
 301                 ${splsrc5}
 302                 ${splsrc6}"],
 303                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 304                         splsrc=${splsrc0}
 305                 ], [ test -e "${splsrc1}/spl.release.in"], [
 306                         splsrc=${splsrc1}
 307                 ], [ test -e "${splsrc2}/spl.release.in"], [
 308                         splsrc=${splsrc2}
 309                 ], [ test -e "${splsrc3}/spl.release.in"], [
 310                         splsrc=$(readlink -f "${splsrc3}")
 311                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 312                         splsrc=${splsrc4}
 313                 ], [ test -e "${splsrc5}/spl.release.in"], [
 314                         splsrc=$(readlink -f "${splsrc5}")
 315                 ], [ test -e "${splsrc6}/spl.release.in" ], [
 316                         splsrc=${splsrc6}
 317                 ], [
 318                         splsrc="[Not found]"
 319                 ])
 320         ], [
 321                 [all_spl_sources="$withval"],
 322                 AS_IF([test "$splsrc" = "NONE"], [
 323                         splbuild=NONE
 324                         splsrcver=NONE
 325                 ])
 326         ])
 327
 328         AC_MSG_RESULT([$splsrc])
 329         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 330                 AC_MSG_ERROR([
 331         *** Please make sure the kmod spl devel package for your distribution
 332         *** is installed then try again.  If that fails you can specify the
 333         *** location of the spl source with the '--with-spl=PATH' option.
 334         *** The spl version must match the version of ZFS you are building,
 335         *** ${VERSION}.  Failed to find spl.release.in in the following:
 336         $all_spl_sources])
 337         ])
 338
 339         dnl #
 340         dnl # The existence of the spl_config.h is used to identify a valid
 341         dnl # spl object directory.  In many cases the object and source
 342         dnl # directory are the same, however the objects may also reside
 343         dnl # is a subdirectory named after the kernel version.
 344         dnl #
 345         dnl # This file is supposed to be available after DKMS finishes
 346         dnl # building the SPL kernel module for the target kernel.  The
 347         dnl # '--with-spl-timeout' option can be passed to pause here,
 348         dnl # waiting for the file to appear from a concurrently building
 349         dnl # SPL package.
 350         dnl #
 351         AC_MSG_CHECKING([spl build directory])
 352
 353         all_spl_config_locs="${splsrc}/${LINUX_VERSION}
 354         ${splsrc}"
 355
 356         while true; do
 357                 AS_IF([test -z "$splbuild"], [
 358                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 359                                 splbuild="${splsrc}/${LINUX_VERSION}"
 360                         ], [ test -e "${splsrc}/spl_config.h" ], [
 361                                 splbuild="${splsrc}"
 362                         ], [ find -L "${splsrc}" -name spl_config.h 2> /dev/null | grep -wq spl_config.h ], [
 363                                 splbuild=$(find -L "${splsrc}" -name spl_config.h | sed 's,/spl_config.h,,')
 364                         ], [
 365                                 splbuild="[Not found]"
 366                         ])
 367                 ])
 368                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 369                         break;
 370                 ], [
 371                         sleep 1
 372                         timeout=$((timeout-1))
 373                 ])
 374         done
 375
 376         AC_MSG_RESULT([$splbuild])
 377         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 378                 AC_MSG_ERROR([
 379         *** Please make sure the kmod spl devel <kernel> package for your
 380         *** distribution is installed then try again.  If that fails you
 381         *** can specify the location of the spl objects with the
 382         *** '--with-spl-obj=PATH' option.  Failed to find spl_config.h in
 383         *** any of the following:
 384         $all_spl_config_locs])
 385         ])
 386
 387         AC_MSG_CHECKING([spl source version])
 388         AS_IF([test -r $splbuild/spl_config.h &&
 389                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 390
 391                 splsrcver=`(echo "#include <spl_config.h>";
 392                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 393                             cpp -I $splbuild |
 394                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 395         ])
 396
 397         AS_IF([test -z "$splsrcver"], [
 398                 AC_MSG_RESULT([Not found])
 399                 AC_MSG_ERROR([
 400         *** Cannot determine the version of the spl source.
 401         *** Please prepare the spl source before running this script])
 402         ])
 403
 404         AC_MSG_RESULT([$splsrcver])
 405
 406         SPL=${splsrc}
 407         SPL_OBJ=${splbuild}
 408         SPL_VERSION=${splsrcver}
 409
 410         AC_SUBST(SPL)
 411         AC_SUBST(SPL_OBJ)
 412         AC_SUBST(SPL_VERSION)
 413
 414         dnl #
 415         dnl # Detect the name used for the SPL Module.symvers file.  If one
 416         dnl # does not exist this is likely because the SPL has been configured
 417         dnl # but not built.  The '--with-spl-timeout' option can be passed
 418         dnl # to pause here, waiting for the file to appear from a concurrently
 419         dnl # building SPL package.  If the file does not appear in time, a good
 420         dnl # guess is made as to what this file will be named based on what it
 421         dnl # is named in the kernel build products.  This file will first be
 422         dnl # used at link time so if the guess is wrong the build will fail
 423         dnl # then.  This unfortunately means the ZFS package does not contain a
 424         dnl # reliable mechanism to detect symbols exported by the SPL at
 425         dnl # configure time.
 426         dnl #
 427         AC_MSG_CHECKING([spl file name for module symbols])
 428         SPL_SYMBOLS=NONE
 429
 430         while true; do
 431                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 432                         SPL_SYMBOLS=Module.symvers
 433                 ], [test -r $SPL_OBJ/Modules.symvers], [
 434                         SPL_SYMBOLS=Modules.symvers
 435                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 436                         SPL_SYMBOLS=Module.symvers
 437                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 438                         SPL_SYMBOLS=Modules.symvers
 439                 ])
 440
 441                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 442                         break;
 443                 ], [
 444                         sleep 1
 445                         timeout=$((timeout-1))
 446                 ])
 447         done
 448
 449         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 450                 SPL_SYMBOLS=$LINUX_SYMBOLS
 451         ])
 452
 453         AC_MSG_RESULT([$SPL_SYMBOLS])
 454         AC_SUBST(SPL_SYMBOLS)
 455 ])
 456
 457 dnl #
 458 dnl # Basic toolchain sanity check.
 459 dnl #
 460 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 461         AC_MSG_CHECKING([whether modules can be built])
 462         ZFS_LINUX_TRY_COMPILE([],[],[
 463                 AC_MSG_RESULT([yes])
 464         ],[
 465                 AC_MSG_RESULT([no])
 466                 if test "x$enable_linux_builtin" != xyes; then
 467                         AC_MSG_ERROR([*** Unable to build an empty module.])
 468                 else
 469                         AC_MSG_ERROR([
 470         *** Unable to build an empty module.
 471         *** Please run 'make scripts' inside the kernel source tree.])
 472                 fi
 473         ])
 474 ])
 475
 476 dnl #
 477 dnl # Certain kernel build options are not supported.  These must be
 478 dnl # detected at configure time and cause a build failure.  Otherwise
 479 dnl # modules may be successfully built that behave incorrectly.
 480 dnl #
 481 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 482         AS_IF([test "x$cross_compiling" != xyes], [
 483                 AC_RUN_IFELSE([
 484                         AC_LANG_PROGRAM([
 485                                 #include "$LINUX/include/linux/license.h"
 486                         ], [
 487                                 return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 488                         ])
 489                 ], [
 490                         AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 491                             [Define to 1 if GPL-only symbols can be used])
 492                 ], [
 493                 ])
 494         ])
 495
 496         ZFS_AC_KERNEL_CONFIG_THREAD_SIZE
 497         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 498 ])
 499
 500 dnl #
 501 dnl # Check configured THREAD_SIZE
 502 dnl #
 503 dnl # The stack size will vary by architecture, but as of Linux 3.15 on x86_64
 504 dnl # the default thread stack size was increased to 16K from 8K.  Therefore,
 505 dnl # on newer kernels and some architectures stack usage optimizations can be
 506 dnl # conditionally applied to improve performance without negatively impacting
 507 dnl # stability.
 508 dnl #
 509 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_THREAD_SIZE], [
 510         AC_MSG_CHECKING([whether kernel was built with 16K or larger stacks])
 511         ZFS_LINUX_TRY_COMPILE([
 512                 #include <linux/module.h>
 513         ],[
 514                 #if (THREAD_SIZE < 16384)
 515                 #error "THREAD_SIZE is less than 16K"
 516                 #endif
 517         ],[
 518                 AC_MSG_RESULT([yes])
 519                 AC_DEFINE(HAVE_LARGE_STACKS, 1, [kernel has large stacks])
 520         ],[
 521                 AC_MSG_RESULT([no])
 522         ])
 523 ])
 524
 525 dnl #
 526 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 527 dnl #
 528 dnl # This is typically only set for debug kernels because it comes with
 529 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 530 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 531 dnl # This will cause a failure at link time which we'd rather know about
 532 dnl # at compile time.
 533 dnl #
 534 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 535 dnl # with the upstream community we add a check to detect this case.
 536 dnl #
 537 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 538
 539         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 540                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 541                 tmp_flags="$EXTRA_KCFLAGS"
 542                 ZFS_LINUX_TRY_COMPILE([
 543                         #include <linux/module.h>
 544                         #include <linux/mutex.h>
 545
 546                         MODULE_LICENSE("$ZFS_META_LICENSE");
 547                 ],[
 548                         struct mutex lock;
 549
 550                         mutex_init(&lock);
 551                         mutex_lock(&lock);
 552                         mutex_unlock(&lock);
 553                 ],[
 554                         AC_MSG_RESULT(no)
 555                 ],[
 556                         AC_MSG_RESULT(yes)
 557                         AC_MSG_ERROR([
 558         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 559         *** with the CDDL license and will prevent the module linking stage
 560         *** from succeeding.  You must rebuild your kernel without this
 561         *** option enabled.])
 562                 ])
 563                 EXTRA_KCFLAGS="$tmp_flags"
 564         ], [])
 565 ])
 566
 567 dnl #
 568 dnl # ZFS_LINUX_CONFTEST_H
 569 dnl #
 570 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 571 cat - <<_ACEOF >conftest.h
 572 $1
 573 _ACEOF
 574 ])
 575
 576 dnl #
 577 dnl # ZFS_LINUX_CONFTEST_C
 578 dnl #
 579 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 580 cat confdefs.h - <<_ACEOF >conftest.c
 581 $1
 582 _ACEOF
 583 ])
 584
 585 dnl #
 586 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 587 dnl #
 588 m4_define([ZFS_LANG_PROGRAM], [
 589 $1
 590 int
 591 main (void)
 592 {
 593 dnl Do *not* indent the following line: there may be CPP directives.
 594 dnl Don't move the `;' right after for the same reason.
 595 $2
 596   ;
 597   return 0;
 598 }
 599 ])
 600
 601 dnl #
 602 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 603 dnl #
 604 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 605         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 606         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 607         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 608         echo "obj-m := conftest.o" >build/Makefile
 609         modpost_flag=''
 610         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 611         AS_IF(
 612                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 613                 [$4],
 614                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 615         )
 616         rm -Rf build
 617 ])
 618
 619 dnl #
 620 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 621 dnl #
 622 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 623         [ZFS_LINUX_COMPILE_IFELSE(
 624         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 625         [modules],
 626         [test -s build/conftest.o],
 627         [$3], [$4])
 628 ])
 629
 630 dnl #
 631 dnl # ZFS_LINUX_CONFIG
 632 dnl #
 633 AC_DEFUN([ZFS_LINUX_CONFIG],
 634         [AC_MSG_CHECKING([whether kernel was built with CONFIG_$1])
 635         ZFS_LINUX_TRY_COMPILE([
 636                 #include <linux/module.h>
 637         ],[
 638                 #ifndef CONFIG_$1
 639                 #error CONFIG_$1 not #defined
 640                 #endif
 641         ],[
 642                 AC_MSG_RESULT([yes])
 643                 $2
 644         ],[
 645                 AC_MSG_RESULT([no])
 646                 $3
 647         ])
 648 ])
 649
 650 dnl #
 651 dnl # ZFS_CHECK_SYMBOL_EXPORT
 652 dnl # check symbol exported or not
 653 dnl #
 654 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 655         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 656                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 657         rc=$?
 658         if test $rc -ne 0; then
 659                 export=0
 660                 for file in $2; do
 661                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 662                                 "$LINUX/$file" 2>/dev/null
 663                         rc=$?
 664                         if test $rc -eq 0; then
 665                                 export=1
 666                                 break;
 667                         fi
 668                 done
 669                 if test $export -eq 0; then :
 670                         $4
 671                 else :
 672                         $3
 673                 fi
 674         else :
 675                 $3
 676         fi
 677 ])
 678
 679 dnl #
 680 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 681 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 682 dnl # is called if not compiling for builtin
 683 dnl #
 684 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 685         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 686         if test $rc -ne 0; then :
 687                 $6
 688         else
 689                 if test "x$enable_linux_builtin" != xyes; then
 690                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 691                 fi
 692                 if test $rc -ne 0; then :
 693                         $6
 694                 else :
 695                         $5
 696                 fi
 697         fi
 698 ])
 699
 700 dnl #
 701 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 702 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 703 dnl # provided via the fifth parameter
 704 dnl #
 705 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 706         [ZFS_LINUX_COMPILE_IFELSE(
 707         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 708         [modules],
 709         [test -s build/conftest.o],
 710         [$3], [$4], [$5])
 711 ])