config/user-systemd.m4

   1 AC_DEFUN([ZFS_AC_CONFIG_USER_SYSTEMD], [
   2         AC_ARG_ENABLE(systemd,
   3                 AS_HELP_STRING([--enable-systemd],
   4                 [install systemd unit/preset files [[default: yes]]]),
   5                 [enable_systemd=$enableval],
   6                 [enable_systemd=check])
   7
   8         AC_ARG_WITH(systemdunitdir,
   9                 AS_HELP_STRING([--with-systemdunitdir=DIR],
  10                 [install systemd unit files in dir [[/usr/lib/systemd/system]]]),
  11                 systemdunitdir=$withval,systemdunitdir=/usr/lib/systemd/system)
  12
  13         AC_ARG_WITH(systemdpresetdir,
  14                 AS_HELP_STRING([--with-systemdpresetdir=DIR],
  15                 [install systemd preset files in dir [[/usr/lib/systemd/system-preset]]]),
  16                 systemdpresetdir=$withval,systemdpresetdir=/usr/lib/systemd/system-preset)
  17
  18         AC_ARG_WITH(systemdmodulesloaddir,
  19                 AS_HELP_STRING([--with-systemdmodulesloaddir=DIR],
  20                 [install systemd module load files into dir [[/usr/lib/modules-load.d]]]),
  21                 systemdmodulesloaddir=$withval,systemdmodulesloaddir=/usr/lib/modules-load.d)
  22
  23         AC_ARG_WITH(systemdgeneratordir,
  24                 AS_HELP_STRING([--with-systemdgeneratordir=DIR],
  25                 [install systemd generators in dir [[/usr/lib/systemd/system-generators]]]),
  26                 systemdgeneratordir=$withval,systemdgeneratordir=/usr/lib/systemd/system-generators)
  27
  28         AS_IF([test "x$enable_systemd" = xcheck], [
  29                 AS_IF([systemctl --version >/dev/null 2>&1],
  30                         [enable_systemd=yes],
  31                         [enable_systemd=no])
  32         ])
  33
  34         AC_MSG_CHECKING(for systemd support)
  35         AC_MSG_RESULT([$enable_systemd])
  36
  37         AS_IF([test "x$enable_systemd" = xyes], [
  38                 ZFS_INIT_SYSTEMD=systemd
  39                 ZFS_MODULE_LOAD=modules-load.d
  40                 DEFINE_SYSTEMD='--with systemd --define "_unitdir $(systemdunitdir)" --define "_presetdir $(systemdpresetdir)" --define "_generatordir $(systemdgeneratordir)"'
  41                 modulesloaddir=$systemdmodulesloaddir
  42         ],[
  43                 DEFINE_SYSTEMD='--without systemd'
  44         ])
  45
  46         AC_SUBST(ZFS_INIT_SYSTEMD)
  47         AC_SUBST(ZFS_MODULE_LOAD)
  48         AC_SUBST(DEFINE_SYSTEMD)
  49         AC_SUBST(systemdunitdir)
  50         AC_SUBST(systemdpresetdir)
  51         AC_SUBST(systemdgeneratordir)
  52         AC_SUBST(modulesloaddir)
  53 ])