config/zfs-build.m4

   1 AC_DEFUN([ZFS_AC_LICENSE], [
   2         AC_MSG_CHECKING([zfs author])
   3         AC_MSG_RESULT([$ZFS_META_AUTHOR])
   4
   5         AC_MSG_CHECKING([zfs license])
   6         AC_MSG_RESULT([$ZFS_META_LICENSE])
   7 ])
   8
   9 AC_DEFUN([ZFS_AC_DEBUG_ENABLE], [
  10         DEBUG_CFLAGS="-Werror"
  11         DEBUG_CPPFLAGS="-DDEBUG -UNDEBUG"
  12         DEBUG_LDFLAGS=""
  13         DEBUG_ZFS="_with_debug"
  14         AC_DEFINE(ZFS_DEBUG, 1, [zfs debugging enabled])
  15
  16         KERNEL_DEBUG_CFLAGS="-Werror"
  17         KERNEL_DEBUG_CPPFLAGS="-DDEBUG -UNDEBUG"
  18 ])
  19
  20 AC_DEFUN([ZFS_AC_DEBUG_DISABLE], [
  21         DEBUG_CFLAGS=""
  22         DEBUG_CPPFLAGS="-UDEBUG -DNDEBUG"
  23         DEBUG_LDFLAGS=""
  24         DEBUG_ZFS="_without_debug"
  25
  26         KERNEL_DEBUG_CFLAGS=""
  27         KERNEL_DEBUG_CPPFLAGS="-UDEBUG -DNDEBUG"
  28 ])
  29
  30 dnl #
  31 dnl # When debugging is enabled:
  32 dnl # - Enable all ASSERTs (-DDEBUG)
  33 dnl # - Promote all compiler warnings to errors (-Werror)
  34 dnl #
  35 AC_DEFUN([ZFS_AC_DEBUG], [
  36         AC_MSG_CHECKING([whether assertion support will be enabled])
  37         AC_ARG_ENABLE([debug],
  38                 [AS_HELP_STRING([--enable-debug],
  39                 [Enable compiler and code assertions @<:@default=no@:>@])],
  40                 [],
  41                 [enable_debug=no])
  42
  43         AS_CASE(["x$enable_debug"],
  44                 ["xyes"],
  45                 [ZFS_AC_DEBUG_ENABLE],
  46                 ["xno"],
  47                 [ZFS_AC_DEBUG_DISABLE],
  48                 [AC_MSG_ERROR([Unknown option $enable_debug])])
  49
  50         AC_SUBST(DEBUG_CFLAGS)
  51         AC_SUBST(DEBUG_CPPFLAGS)
  52         AC_SUBST(DEBUG_LDFLAGS)
  53         AC_SUBST(DEBUG_ZFS)
  54
  55         AC_SUBST(KERNEL_DEBUG_CFLAGS)
  56         AC_SUBST(KERNEL_DEBUG_CPPFLAGS)
  57
  58         AC_MSG_RESULT([$enable_debug])
  59 ])
  60
  61 AC_DEFUN([ZFS_AC_DEBUGINFO_ENABLE], [
  62         DEBUG_CFLAGS="$DEBUG_CFLAGS -g -fno-inline $NO_IPA_SRA"
  63
  64         KERNEL_DEBUG_CFLAGS="$KERNEL_DEBUG_CFLAGS -fno-inline $NO_IPA_SRA"
  65         KERNEL_MAKE="$KERNEL_MAKE CONFIG_DEBUG_INFO=y"
  66
  67         DEBUGINFO_ZFS="_with_debuginfo"
  68 ])
  69
  70 AC_DEFUN([ZFS_AC_DEBUGINFO_DISABLE], [
  71         DEBUGINFO_ZFS="_without_debuginfo"
  72 ])
  73
  74 AC_DEFUN([ZFS_AC_DEBUGINFO], [
  75         AC_MSG_CHECKING([whether debuginfo support will be forced])
  76         AC_ARG_ENABLE([debuginfo],
  77                 [AS_HELP_STRING([--enable-debuginfo],
  78                 [Force generation of debuginfo @<:@default=no@:>@])],
  79                 [],
  80                 [enable_debuginfo=no])
  81
  82         AS_CASE(["x$enable_debuginfo"],
  83                 ["xyes"],
  84                 [ZFS_AC_DEBUGINFO_ENABLE],
  85                 ["xno"],
  86                 [ZFS_AC_DEBUGINFO_DISABLE],
  87                 [AC_MSG_ERROR([Unknown option $enable_debuginfo])])
  88
  89         AC_SUBST(DEBUG_CFLAGS)
  90         AC_SUBST(DEBUGINFO_ZFS)
  91
  92         AC_SUBST(KERNEL_DEBUG_CFLAGS)
  93         AC_SUBST(KERNEL_MAKE)
  94
  95         AC_MSG_RESULT([$enable_debuginfo])
  96 ])
  97
  98 dnl #
  99 dnl # Disabled by default, provides basic memory tracking.  Track the total
 100 dnl # number of bytes allocated with kmem_alloc() and freed with kmem_free().
 101 dnl # Then at module unload time if any bytes were leaked it will be reported
 102 dnl # on the console.
 103 dnl #
 104 AC_DEFUN([ZFS_AC_DEBUG_KMEM], [
 105         AC_MSG_CHECKING([whether basic kmem accounting is enabled])
 106         AC_ARG_ENABLE([debug-kmem],
 107                 [AS_HELP_STRING([--enable-debug-kmem],
 108                 [Enable basic kmem accounting @<:@default=no@:>@])],
 109                 [],
 110                 [enable_debug_kmem=no])
 111
 112         AS_IF([test "x$enable_debug_kmem" = xyes], [
 113                 KERNEL_DEBUG_CPPFLAGS="${KERNEL_DEBUG_CPPFLAGS} -DDEBUG_KMEM"
 114                 DEBUG_KMEM_ZFS="_with_debug_kmem"
 115         ], [
 116                 DEBUG_KMEM_ZFS="_without_debug_kmem"
 117         ])
 118
 119         AC_SUBST(KERNEL_DEBUG_CPPFLAGS)
 120         AC_SUBST(DEBUG_KMEM_ZFS)
 121
 122         AC_MSG_RESULT([$enable_debug_kmem])
 123 ])
 124
 125 dnl #
 126 dnl # Disabled by default, provides detailed memory tracking.  This feature
 127 dnl # also requires --enable-debug-kmem to be set.  When enabled not only will
 128 dnl # total bytes be tracked but also the location of every kmem_alloc() and
 129 dnl # kmem_free().  When the module is unloaded a list of all leaked addresses
 130 dnl # and where they were allocated will be dumped to the console.  Enabling
 131 dnl # this feature has a significant impact on performance but it makes finding
 132 dnl # memory leaks straight forward.
 133 dnl #
 134 AC_DEFUN([ZFS_AC_DEBUG_KMEM_TRACKING], [
 135         AC_MSG_CHECKING([whether detailed kmem tracking is enabled])
 136         AC_ARG_ENABLE([debug-kmem-tracking],
 137                 [AS_HELP_STRING([--enable-debug-kmem-tracking],
 138                 [Enable detailed kmem tracking  @<:@default=no@:>@])],
 139                 [],
 140                 [enable_debug_kmem_tracking=no])
 141
 142         AS_IF([test "x$enable_debug_kmem_tracking" = xyes], [
 143                 KERNEL_DEBUG_CPPFLAGS="${KERNEL_DEBUG_CPPFLAGS} -DDEBUG_KMEM_TRACKING"
 144                 DEBUG_KMEM_TRACKING_ZFS="_with_debug_kmem_tracking"
 145         ], [
 146                 DEBUG_KMEM_TRACKING_ZFS="_without_debug_kmem_tracking"
 147         ])
 148
 149         AC_SUBST(KERNEL_DEBUG_CPPFLAGS)
 150         AC_SUBST(DEBUG_KMEM_TRACKING_ZFS)
 151
 152         AC_MSG_RESULT([$enable_debug_kmem_tracking])
 153 ])
 154
 155 AC_DEFUN([ZFS_AC_CONFIG_ALWAYS], [
 156         ZFS_AC_CONFIG_ALWAYS_CC_NO_UNUSED_BUT_SET_VARIABLE
 157         ZFS_AC_CONFIG_ALWAYS_CC_NO_BOOL_COMPARE
 158         ZFS_AC_CONFIG_ALWAYS_CC_FRAME_LARGER_THAN
 159         ZFS_AC_CONFIG_ALWAYS_CC_NO_FORMAT_TRUNCATION
 160         ZFS_AC_CONFIG_ALWAYS_CC_NO_FORMAT_ZERO_LENGTH
 161         ZFS_AC_CONFIG_ALWAYS_CC_NO_OMIT_FRAME_POINTER
 162         ZFS_AC_CONFIG_ALWAYS_CC_NO_IPA_SRA
 163         ZFS_AC_CONFIG_ALWAYS_CC_ASAN
 164         ZFS_AC_CONFIG_ALWAYS_TOOLCHAIN_SIMD
 165         ZFS_AC_CONFIG_ALWAYS_SYSTEM
 166         ZFS_AC_CONFIG_ALWAYS_ARCH
 167         ZFS_AC_CONFIG_ALWAYS_PYTHON
 168         ZFS_AC_CONFIG_ALWAYS_PYZFS
 169         ZFS_AC_CONFIG_ALWAYS_SED
 170 ])
 171
 172 AC_DEFUN([ZFS_AC_CONFIG], [
 173
 174         dnl # Remove the previous build test directory.
 175         rm -Rf build
 176
 177         ZFS_CONFIG=all
 178         AC_ARG_WITH([config],
 179                 AS_HELP_STRING([--with-config=CONFIG],
 180                 [Config file 'kernel|user|all|srpm']),
 181                 [ZFS_CONFIG="$withval"])
 182         AC_ARG_ENABLE([linux-builtin],
 183                 [AC_HELP_STRING([--enable-linux-builtin],
 184                 [Configure for builtin in-tree kernel modules @<:@default=no@:>@])],
 185                 [],
 186                 [enable_linux_builtin=no])
 187
 188         AC_MSG_CHECKING([zfs config])
 189         AC_MSG_RESULT([$ZFS_CONFIG]);
 190         AC_SUBST(ZFS_CONFIG)
 191
 192         ZFS_AC_CONFIG_ALWAYS
 193
 194
 195         AM_COND_IF([BUILD_LINUX], [
 196                 AC_ARG_VAR([TEST_JOBS],
 197                     [simultaneous jobs during configure (defaults to $(nproc))])
 198                 if test "x$ac_cv_env_TEST_JOBS_set" != "xset"; then
 199                         TEST_JOBS=$(nproc)
 200                 fi
 201                 AC_SUBST(TEST_JOBS)
 202         ])
 203
 204         case "$ZFS_CONFIG" in
 205                 kernel) ZFS_AC_CONFIG_KERNEL ;;
 206                 user)   ZFS_AC_CONFIG_USER   ;;
 207                 all)    ZFS_AC_CONFIG_USER
 208                         ZFS_AC_CONFIG_KERNEL ;;
 209                 srpm)                        ;;
 210                 *)
 211                 AC_MSG_RESULT([Error!])
 212                 AC_MSG_ERROR([Bad value "$ZFS_CONFIG" for --with-config,
 213                               user kernel|user|all|srpm]) ;;
 214         esac
 215
 216         AM_CONDITIONAL([CONFIG_USER],
 217             [test "$ZFS_CONFIG" = user -o "$ZFS_CONFIG" = all])
 218         AM_CONDITIONAL([CONFIG_KERNEL],
 219             [test "$ZFS_CONFIG" = kernel -o "$ZFS_CONFIG" = all] &&
 220             [test "x$enable_linux_builtin" != xyes ])
 221         AM_CONDITIONAL([CONFIG_QAT],
 222             [test "$ZFS_CONFIG" = kernel -o "$ZFS_CONFIG" = all] &&
 223             [test "x$qatsrc" != x ])
 224         AM_CONDITIONAL([WANT_DEVNAME2DEVID], [test "x$user_libudev" = xyes ])
 225         AM_CONDITIONAL([WANT_MMAP_LIBAIO], [test "x$user_libaio" = xyes ])
 226         AM_CONDITIONAL([PAM_ZFS_ENABLED], [test "x$enable_pam" = xyes])
 227 ])
 228
 229 dnl #
 230 dnl # Check for rpm+rpmbuild to build RPM packages.  If these tools
 231 dnl # are missing it is non-fatal but you will not be able to build
 232 dnl # RPM packages and will be warned if you try too.
 233 dnl #
 234 dnl # By default the generic spec file will be used because it requires
 235 dnl # minimal dependencies.  Distribution specific spec files can be
 236 dnl # placed under the 'rpm/<distribution>' directory and enabled using
 237 dnl # the --with-spec=<distribution> configure option.
 238 dnl #
 239 AC_DEFUN([ZFS_AC_RPM], [
 240         RPM=rpm
 241         RPMBUILD=rpmbuild
 242
 243         AC_MSG_CHECKING([whether $RPM is available])
 244         AS_IF([tmp=$($RPM --version 2>/dev/null)], [
 245                 RPM_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 246                 HAVE_RPM=yes
 247                 AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
 248         ],[
 249                 HAVE_RPM=no
 250                 AC_MSG_RESULT([$HAVE_RPM])
 251         ])
 252
 253         AC_MSG_CHECKING([whether $RPMBUILD is available])
 254         AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
 255                 RPMBUILD_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 256                 HAVE_RPMBUILD=yes
 257                 AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
 258         ],[
 259                 HAVE_RPMBUILD=no
 260                 AC_MSG_RESULT([$HAVE_RPMBUILD])
 261         ])
 262
 263         RPM_DEFINE_COMMON='--define "$(DEBUG_ZFS) 1"'
 264         RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(DEBUG_KMEM_ZFS) 1"'
 265         RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(DEBUG_KMEM_TRACKING_ZFS) 1"'
 266         RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(DEBUGINFO_ZFS) 1"'
 267         RPM_DEFINE_COMMON=${RPM_DEFINE_COMMON}' --define "$(ASAN_ZFS) 1"'
 268
 269         RPM_DEFINE_UTIL=' --define "_initconfdir $(DEFAULT_INITCONF_DIR)"'
 270
 271         dnl # Make the next three RPM_DEFINE_UTIL additions conditional, since
 272         dnl # their values may not be set when running:
 273         dnl #
 274         dnl #   ./configure --with-config=srpm
 275         dnl #
 276         AS_IF([test -n "$dracutdir" ], [
 277                 RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' --define "_dracutdir $(dracutdir)"'
 278         ])
 279         AS_IF([test -n "$udevdir" ], [
 280                 RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' --define "_udevdir $(udevdir)"'
 281         ])
 282         AS_IF([test -n "$udevruledir" ], [
 283                 RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' --define "_udevruledir $(udevruledir)"'
 284         ])
 285         RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_INITRAMFS)'
 286         RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_SYSTEMD)'
 287         RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_PYZFS)'
 288         RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_PAM)'
 289         RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_PYTHON_VERSION)'
 290         RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' $(DEFINE_PYTHON_PKG_VERSION)'
 291
 292         dnl # Override default lib directory on Debian/Ubuntu systems.  The
 293         dnl # provided /usr/lib/rpm/platform/<arch>/macros files do not
 294         dnl # specify the correct path for multiarch systems as described
 295         dnl # by the packaging guidelines.
 296         dnl #
 297         dnl # https://wiki.ubuntu.com/MultiarchSpec
 298         dnl # https://wiki.debian.org/Multiarch/Implementation
 299         dnl #
 300         AS_IF([test "$DEFAULT_PACKAGE" = "deb"], [
 301                 MULTIARCH_LIBDIR="lib/$(dpkg-architecture -qDEB_HOST_MULTIARCH)"
 302                 RPM_DEFINE_UTIL=${RPM_DEFINE_UTIL}' --define "_lib $(MULTIARCH_LIBDIR)"'
 303                 AC_SUBST(MULTIARCH_LIBDIR)
 304         ])
 305
 306         RPM_DEFINE_KMOD='--define "kernels $(LINUX_VERSION)"'
 307         RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "ksrc $(LINUX)"'
 308         RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "kobj $(LINUX_OBJ)"'
 309         RPM_DEFINE_KMOD=${RPM_DEFINE_KMOD}' --define "_wrong_version_format_terminate_build 0"'
 310
 311         RPM_DEFINE_DKMS=''
 312
 313         SRPM_DEFINE_COMMON='--define "build_src_rpm 1"'
 314         SRPM_DEFINE_UTIL=
 315         SRPM_DEFINE_KMOD=
 316         SRPM_DEFINE_DKMS=
 317
 318         RPM_SPEC_DIR="rpm/generic"
 319         AC_ARG_WITH([spec],
 320                 AS_HELP_STRING([--with-spec=SPEC],
 321                 [Spec files 'generic|redhat']),
 322                 [RPM_SPEC_DIR="rpm/$withval"])
 323
 324         AC_MSG_CHECKING([whether spec files are available])
 325         AC_MSG_RESULT([yes ($RPM_SPEC_DIR/*.spec.in)])
 326
 327         AC_SUBST(HAVE_RPM)
 328         AC_SUBST(RPM)
 329         AC_SUBST(RPM_VERSION)
 330
 331         AC_SUBST(HAVE_RPMBUILD)
 332         AC_SUBST(RPMBUILD)
 333         AC_SUBST(RPMBUILD_VERSION)
 334
 335         AC_SUBST(RPM_SPEC_DIR)
 336         AC_SUBST(RPM_DEFINE_UTIL)
 337         AC_SUBST(RPM_DEFINE_KMOD)
 338         AC_SUBST(RPM_DEFINE_DKMS)
 339         AC_SUBST(RPM_DEFINE_COMMON)
 340         AC_SUBST(SRPM_DEFINE_UTIL)
 341         AC_SUBST(SRPM_DEFINE_KMOD)
 342         AC_SUBST(SRPM_DEFINE_DKMS)
 343         AC_SUBST(SRPM_DEFINE_COMMON)
 344 ])
 345
 346 dnl #
 347 dnl # Check for dpkg+dpkg-buildpackage to build DEB packages.  If these
 348 dnl # tools are missing it is non-fatal but you will not be able to build
 349 dnl # DEB packages and will be warned if you try too.
 350 dnl #
 351 AC_DEFUN([ZFS_AC_DPKG], [
 352         DPKG=dpkg
 353         DPKGBUILD=dpkg-buildpackage
 354
 355         AC_MSG_CHECKING([whether $DPKG is available])
 356         AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
 357                 DPKG_VERSION=$(echo $tmp | $AWK '/Debian/ { print $[7] }')
 358                 HAVE_DPKG=yes
 359                 AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
 360         ],[
 361                 HAVE_DPKG=no
 362                 AC_MSG_RESULT([$HAVE_DPKG])
 363         ])
 364
 365         AC_MSG_CHECKING([whether $DPKGBUILD is available])
 366         AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
 367                 DPKGBUILD_VERSION=$(echo $tmp | \
 368                     $AWK '/Debian/ { print $[4] }' | cut -f-4 -d'.')
 369                 HAVE_DPKGBUILD=yes
 370                 AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
 371         ],[
 372                 HAVE_DPKGBUILD=no
 373                 AC_MSG_RESULT([$HAVE_DPKGBUILD])
 374         ])
 375
 376         AC_SUBST(HAVE_DPKG)
 377         AC_SUBST(DPKG)
 378         AC_SUBST(DPKG_VERSION)
 379
 380         AC_SUBST(HAVE_DPKGBUILD)
 381         AC_SUBST(DPKGBUILD)
 382         AC_SUBST(DPKGBUILD_VERSION)
 383 ])
 384
 385 dnl #
 386 dnl # Until native packaging for various different packing systems
 387 dnl # can be added the least we can do is attempt to use alien to
 388 dnl # convert the RPM packages to the needed package type.  This is
 389 dnl # a hack but so far it has worked reasonable well.
 390 dnl #
 391 AC_DEFUN([ZFS_AC_ALIEN], [
 392         ALIEN=alien
 393
 394         AC_MSG_CHECKING([whether $ALIEN is available])
 395         AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
 396                 ALIEN_VERSION=$(echo $tmp | $AWK '{ print $[3] }')
 397                 HAVE_ALIEN=yes
 398                 AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
 399         ],[
 400                 HAVE_ALIEN=no
 401                 AC_MSG_RESULT([$HAVE_ALIEN])
 402         ])
 403
 404         AC_SUBST(HAVE_ALIEN)
 405         AC_SUBST(ALIEN)
 406         AC_SUBST(ALIEN_VERSION)
 407 ])
 408
 409 dnl #
 410 dnl # Using the VENDOR tag from config.guess set the default
 411 dnl # package type for 'make pkg': (rpm | deb | tgz)
 412 dnl #
 413 AC_DEFUN([ZFS_AC_DEFAULT_PACKAGE], [
 414         AC_MSG_CHECKING([os distribution])
 415         if test -f /etc/toss-release ; then
 416                 VENDOR=toss ;
 417         elif test -f /etc/fedora-release ; then
 418                 VENDOR=fedora ;
 419         elif test -f /etc/redhat-release ; then
 420                 VENDOR=redhat ;
 421         elif test -f /etc/gentoo-release ; then
 422                 VENDOR=gentoo ;
 423         elif test -f /etc/arch-release ; then
 424                 VENDOR=arch ;
 425         elif test -f /etc/SuSE-release ; then
 426                 VENDOR=sles ;
 427         elif test -f /etc/slackware-version ; then
 428                 VENDOR=slackware ;
 429         elif test -f /etc/lunar.release ; then
 430                 VENDOR=lunar ;
 431         elif test -f /etc/lsb-release ; then
 432                 VENDOR=ubuntu ;
 433         elif test -f /etc/debian_version ; then
 434                 VENDOR=debian ;
 435         elif test -f /etc/alpine-release ; then
 436                 VENDOR=alpine ;
 437         elif test -f /bin/freebsd-version ; then
 438                 VENDOR=freebsd ;
 439         else
 440                 VENDOR= ;
 441         fi
 442         AC_MSG_RESULT([$VENDOR])
 443         AC_SUBST(VENDOR)
 444
 445         AC_MSG_CHECKING([default package type])
 446         case "$VENDOR" in
 447                 toss)       DEFAULT_PACKAGE=rpm  ;;
 448                 redhat)     DEFAULT_PACKAGE=rpm  ;;
 449                 fedora)     DEFAULT_PACKAGE=rpm  ;;
 450                 gentoo)     DEFAULT_PACKAGE=tgz  ;;
 451                 alpine)     DEFAULT_PACKAGE=tgz  ;;
 452                 arch)       DEFAULT_PACKAGE=tgz  ;;
 453                 sles)       DEFAULT_PACKAGE=rpm  ;;
 454                 slackware)  DEFAULT_PACKAGE=tgz  ;;
 455                 lunar)      DEFAULT_PACKAGE=tgz  ;;
 456                 ubuntu)     DEFAULT_PACKAGE=deb  ;;
 457                 debian)     DEFAULT_PACKAGE=deb  ;;
 458                 freebsd)    DEFAULT_PACKAGE=pkg  ;;
 459                 *)          DEFAULT_PACKAGE=rpm  ;;
 460         esac
 461         AC_MSG_RESULT([$DEFAULT_PACKAGE])
 462         AC_SUBST(DEFAULT_PACKAGE)
 463
 464         AC_MSG_CHECKING([default init directory])
 465         case "$VENDOR" in
 466                 freebsd)    DEFAULT_INIT_DIR=$sysconfdir/rc.d  ;;
 467                 *)          DEFAULT_INIT_DIR=$sysconfdir/init.d;;
 468         esac
 469         AC_MSG_RESULT([$DEFAULT_INIT_DIR])
 470         AC_SUBST(DEFAULT_INIT_DIR)
 471
 472         AC_MSG_CHECKING([default init script type])
 473         case "$VENDOR" in
 474                 toss)       DEFAULT_INIT_SCRIPT=redhat ;;
 475                 redhat)     DEFAULT_INIT_SCRIPT=redhat ;;
 476                 fedora)     DEFAULT_INIT_SCRIPT=fedora ;;
 477                 gentoo)     DEFAULT_INIT_SCRIPT=openrc ;;
 478                 alpine)     DEFAULT_INIT_SCRIPT=openrc ;;
 479                 arch)       DEFAULT_INIT_SCRIPT=lsb    ;;
 480                 sles)       DEFAULT_INIT_SCRIPT=lsb    ;;
 481                 slackware)  DEFAULT_INIT_SCRIPT=lsb    ;;
 482                 lunar)      DEFAULT_INIT_SCRIPT=lunar  ;;
 483                 ubuntu)     DEFAULT_INIT_SCRIPT=lsb    ;;
 484                 debian)     DEFAULT_INIT_SCRIPT=lsb    ;;
 485                 freebsd)    DEFAULT_INIT_SCRIPT=freebsd;;
 486                 *)          DEFAULT_INIT_SCRIPT=lsb    ;;
 487         esac
 488         AC_MSG_RESULT([$DEFAULT_INIT_SCRIPT])
 489         AC_SUBST(DEFAULT_INIT_SCRIPT)
 490
 491         AC_MSG_CHECKING([default init config directory])
 492         case "$VENDOR" in
 493                 alpine)     DEFAULT_INITCONF_DIR=/etc/conf.d    ;;
 494                 gentoo)     DEFAULT_INITCONF_DIR=/etc/conf.d    ;;
 495                 toss)       DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 496                 redhat)     DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 497                 fedora)     DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 498                 sles)       DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 499                 ubuntu)     DEFAULT_INITCONF_DIR=/etc/default   ;;
 500                 debian)     DEFAULT_INITCONF_DIR=/etc/default   ;;
 501                 freebsd)    DEFAULT_INITCONF_DIR=$sysconfdir/rc.conf.d;;
 502                 *)          DEFAULT_INITCONF_DIR=/etc/default   ;;
 503         esac
 504         AC_MSG_RESULT([$DEFAULT_INITCONF_DIR])
 505         AC_SUBST(DEFAULT_INITCONF_DIR)
 506
 507         AC_MSG_CHECKING([whether initramfs-tools is available])
 508         if test -d /usr/share/initramfs-tools ; then
 509                 DEFINE_INITRAMFS='--define "_initramfs 1"'
 510                 AC_MSG_RESULT([yes])
 511         else
 512                 DEFINE_INITRAMFS=''
 513                 AC_MSG_RESULT([no])
 514         fi
 515         AC_SUBST(DEFINE_INITRAMFS)
 516 ])
 517
 518 dnl #
 519 dnl # Default ZFS package configuration
 520 dnl #
 521 AC_DEFUN([ZFS_AC_PACKAGE], [
 522         ZFS_AC_DEFAULT_PACKAGE
 523         AS_IF([test x$VENDOR != xfreebsd], [
 524                 ZFS_AC_RPM
 525                 ZFS_AC_DPKG
 526                 ZFS_AC_ALIEN
 527         ])
 528 ])