toolchain/binutils/ld/ldlex.l

   1 %{
   2
   3 /* Copyright 1991, 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4    2000, 2001, 2002, 2003  Free Software Foundation, Inc.
   5
   6 This file is part of GLD, the Gnu Linker.
   7
   8 GLD is free software; you can redistribute it and/or modify
   9 it under the terms of the GNU General Public License as published by
  10 the Free Software Foundation; either version 2, or (at your option)
  11 any later version.
  12
  13 GLD is distributed in the hope that it will be useful,
  14 but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 GNU General Public License for more details.
  17
  18 You should have received a copy of the GNU General Public License
  19 along with GLD; see the file COPYING.  If not, write to the Free
  20 Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  21 02111-1307, USA.  */
  22
  23 /*
  24 This was written by steve chamberlain
  25                     sac@cygnus.com
  26 */
  27
  28
  29 #include <stdio.h>
  30
  31 #ifdef MPW
  32 /* Prevent enum redefinition problems. */
  33 #define TRUE_FALSE_ALREADY_DEFINED
  34 #endif /* MPW */
  35
  36 #include "bfd.h"
  37 #include "sysdep.h"
  38 #include "safe-ctype.h"
  39 #include "bfdlink.h"
  40 #include "ld.h"
  41 #include "ldmisc.h"
  42 #include "ldexp.h"
  43 #include "ldlang.h"
  44 #include <ldgram.h>
  45 #include "ldfile.h"
  46 #include "ldlex.h"
  47 #include "ldmain.h"
  48 #include "libiberty.h"
  49
  50 /* The type of top-level parser input.
  51    yylex and yyparse (indirectly) both check this.  */
  52 input_type parser_input;
  53
  54 /* Line number in the current input file.
  55    (FIXME Actually, it doesn't appear to get reset for each file?)  */
  56 unsigned int lineno = 1;
  57
  58 /* The string we are currently lexing, or NULL if we are reading a
  59    file.  */
  60 const char *lex_string = NULL;
  61
  62 /* Support for flex reading from more than one input file (stream).
  63    `include_stack' is flex's input state for each open file;
  64    `file_name_stack' is the file names.  `lineno_stack' is the current
  65    line numbers.
  66
  67    If `include_stack_ptr' is 0, we haven't started reading anything yet.
  68    Otherwise, stack elements 0 through `include_stack_ptr - 1' are valid.  */
  69
  70 #undef YY_INPUT
  71 #define YY_INPUT(buf,result,max_size) yy_input (buf, &result, max_size)
  72
  73 #define MAX_INCLUDE_DEPTH 10
  74 static YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
  75 static const char *file_name_stack[MAX_INCLUDE_DEPTH];
  76 static unsigned int lineno_stack[MAX_INCLUDE_DEPTH];
  77 static unsigned int include_stack_ptr = 0;
  78 static int vers_node_nesting = 0;
  79
  80 static void yy_input (char *, int *, int);
  81 static void comment (void);
  82 static void lex_warn_invalid (char *where, char *what);
  83
  84 /* STATES
  85         EXPRESSION      definitely in an expression
  86         SCRIPT          definitely in a script
  87         BOTH            either EXPRESSION or SCRIPT
  88         DEFSYMEXP       in an argument to -defsym
  89         MRI             in an MRI script
  90         VERS_START      starting a Sun style mapfile
  91         VERS_SCRIPT     a Sun style mapfile
  92         VERS_NODE       a node within a Sun style mapfile
  93 */
  94 #define RTOKEN(x)  {  yylval.token = x; return x; }
  95
  96 /* Some versions of flex want this.  */
  97 #ifndef yywrap
  98 int yywrap (void) { return 1; }
  99 #endif
 100 %}
 101
 102 %a 4000
 103 %o 5000
 104
 105 CMDFILENAMECHAR   [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\-\~]
 106 CMDFILENAMECHAR1  [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\~]
 107 FILENAMECHAR1   [_a-zA-Z\/\.\\\$\_\~]
 108 SYMBOLCHARN     [_a-zA-Z\/\.\\\$\_\~0-9]
 109 FILENAMECHAR    [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~]
 110 WILDCHAR        [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~\?\*]
 111 WHITE           [ \t\n\r]+
 112
 113 NOCFILENAMECHAR [_a-zA-Z0-9\/\.\-\_\+\$\:\[\]\\\~]
 114
 115 V_TAG [.$_a-zA-Z][._a-zA-Z0-9]*
 116 V_IDENTIFIER [*?.$_a-zA-Z\[\]\-\!\^\\]([*?.$_a-zA-Z0-9\[\]\-\!\^\\]|::)*
 117
 118 %s SCRIPT
 119 %s EXPRESSION
 120 %s BOTH
 121 %s DEFSYMEXP
 122 %s MRI
 123 %s VERS_START
 124 %s VERS_SCRIPT
 125 %s VERS_NODE
 126 %%
 127
 128   if (parser_input != input_selected)
 129     {
 130       /* The first token of the input determines the initial parser state.  */
 131       input_type t = parser_input;
 132       parser_input = input_selected;
 133       switch (t)
 134         {
 135         case input_script: return INPUT_SCRIPT; break;
 136         case input_mri_script: return INPUT_MRI_SCRIPT; break;
 137         case input_version_script: return INPUT_VERSION_SCRIPT; break;
 138         case input_defsym: return INPUT_DEFSYM; break;
 139         default: abort ();
 140         }
 141     }
 142
 143 <BOTH,SCRIPT,EXPRESSION,VERS_START,VERS_NODE,VERS_SCRIPT>"/*"   { comment (); }
 144
 145
 146 <DEFSYMEXP>"-"                  { RTOKEN('-');}
 147 <DEFSYMEXP>"+"                  { RTOKEN('+');}
 148 <DEFSYMEXP>{FILENAMECHAR1}{SYMBOLCHARN}*   { yylval.name = xstrdup (yytext); return NAME; }
 149 <DEFSYMEXP>"="                  { RTOKEN('='); }
 150
 151 <MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
 152                                 yylval.integer = bfd_scan_vma (yytext + 1, 0, 16);
 153                                 yylval.bigint.str = NULL;
 154                                 return INT;
 155                         }
 156
 157 <MRI,EXPRESSION>([0-9A-Fa-f])+(H|h|X|x|B|b|O|o|D|d) {
 158                                    int ibase ;
 159                                    switch (yytext[yyleng - 1]) {
 160                                     case 'X':
 161                                     case 'x':
 162                                     case 'H':
 163                                     case 'h':
 164                                      ibase = 16;
 165                                      break;
 166                                     case 'O':
 167                                     case 'o':
 168                                      ibase = 8;
 169                                      break;
 170                                     case 'B':
 171                                     case 'b':
 172                                      ibase = 2;
 173                                      break;
 174                                     default:
 175                                      ibase = 10;
 176                                    }
 177                                    yylval.integer = bfd_scan_vma (yytext, 0,
 178                                                                   ibase);
 179                                    yylval.bigint.str = NULL;
 180                                    return INT;
 181                                  }
 182 <SCRIPT,DEFSYMEXP,MRI,BOTH,EXPRESSION>((("$"|0[xX])([0-9A-Fa-f])+)|(([0-9])+))(M|K|m|k)? {
 183                                   char *s = yytext;
 184                                   int ibase = 0;
 185
 186                                   if (*s == '$')
 187                                     {
 188                                       ++s;
 189                                       ibase = 16;
 190                                     }
 191                                   yylval.integer = bfd_scan_vma (s, 0, ibase);
 192                                   yylval.bigint.str = NULL;
 193                                   if (yytext[yyleng - 1] == 'M'
 194                                       || yytext[yyleng - 1] == 'm')
 195                                     {
 196                                       yylval.integer *= 1024 * 1024;
 197                                     }
 198                                   else if (yytext[yyleng - 1] == 'K'
 199                                       || yytext[yyleng - 1]=='k')
 200                                     {
 201                                       yylval.integer *= 1024;
 202                                     }
 203                                   else if (yytext[0] == '0'
 204                                            && (yytext[1] == 'x'
 205                                                || yytext[1] == 'X'))
 206                                     {
 207                                       yylval.bigint.str = xstrdup (yytext + 2);
 208                                     }
 209                                   return INT;
 210                                 }
 211 <BOTH,SCRIPT,EXPRESSION,MRI>"]"         { RTOKEN(']');}
 212 <BOTH,SCRIPT,EXPRESSION,MRI>"["         { RTOKEN('[');}
 213 <BOTH,SCRIPT,EXPRESSION,MRI>"<<="       { RTOKEN(LSHIFTEQ);}
 214 <BOTH,SCRIPT,EXPRESSION,MRI>">>="       { RTOKEN(RSHIFTEQ);}
 215 <BOTH,SCRIPT,EXPRESSION,MRI>"||"        { RTOKEN(OROR);}
 216 <BOTH,SCRIPT,EXPRESSION,MRI>"=="        { RTOKEN(EQ);}
 217 <BOTH,SCRIPT,EXPRESSION,MRI>"!="        { RTOKEN(NE);}
 218 <BOTH,SCRIPT,EXPRESSION,MRI>">="        { RTOKEN(GE);}
 219 <BOTH,SCRIPT,EXPRESSION,MRI>"<="        { RTOKEN(LE);}
 220 <BOTH,SCRIPT,EXPRESSION,MRI>"<<"        { RTOKEN(LSHIFT);}
 221 <BOTH,SCRIPT,EXPRESSION,MRI>">>"        { RTOKEN(RSHIFT);}
 222 <BOTH,SCRIPT,EXPRESSION,MRI>"+="        { RTOKEN(PLUSEQ);}
 223 <BOTH,SCRIPT,EXPRESSION,MRI>"-="        { RTOKEN(MINUSEQ);}
 224 <BOTH,SCRIPT,EXPRESSION,MRI>"*="        { RTOKEN(MULTEQ);}
 225 <BOTH,SCRIPT,EXPRESSION,MRI>"/="        { RTOKEN(DIVEQ);}
 226 <BOTH,SCRIPT,EXPRESSION,MRI>"&="        { RTOKEN(ANDEQ);}
 227 <BOTH,SCRIPT,EXPRESSION,MRI>"|="        { RTOKEN(OREQ);}
 228 <BOTH,SCRIPT,EXPRESSION,MRI>"&&"        { RTOKEN(ANDAND);}
 229 <BOTH,SCRIPT,EXPRESSION,MRI>">"         { RTOKEN('>');}
 230 <BOTH,SCRIPT,EXPRESSION,MRI>","         { RTOKEN(',');}
 231 <BOTH,SCRIPT,EXPRESSION,MRI>"&"         { RTOKEN('&');}
 232 <BOTH,SCRIPT,EXPRESSION,MRI>"|"         { RTOKEN('|');}
 233 <BOTH,SCRIPT,EXPRESSION,MRI>"~"         { RTOKEN('~');}
 234 <BOTH,SCRIPT,EXPRESSION,MRI>"!"         { RTOKEN('!');}
 235 <BOTH,SCRIPT,EXPRESSION,MRI>"?"         { RTOKEN('?');}
 236 <BOTH,SCRIPT,EXPRESSION,MRI>"*"         { RTOKEN('*');}
 237 <BOTH,SCRIPT,EXPRESSION,MRI>"+"         { RTOKEN('+');}
 238 <BOTH,SCRIPT,EXPRESSION,MRI>"-"         { RTOKEN('-');}
 239 <BOTH,SCRIPT,EXPRESSION,MRI>"/"         { RTOKEN('/');}
 240 <BOTH,SCRIPT,EXPRESSION,MRI>"%"         { RTOKEN('%');}
 241 <BOTH,SCRIPT,EXPRESSION,MRI>"<"         { RTOKEN('<');}
 242 <BOTH,SCRIPT,EXPRESSION,MRI>"="          { RTOKEN('=');}
 243 <BOTH,SCRIPT,EXPRESSION,MRI>"}"                 { RTOKEN('}') ; }
 244 <BOTH,SCRIPT,EXPRESSION,MRI>"{"                 { RTOKEN('{'); }
 245 <BOTH,SCRIPT,EXPRESSION,MRI>")"                 { RTOKEN(')');}
 246 <BOTH,SCRIPT,EXPRESSION,MRI>"("                 { RTOKEN('(');}
 247 <BOTH,SCRIPT,EXPRESSION,MRI>":"         { RTOKEN(':'); }
 248 <BOTH,SCRIPT,EXPRESSION,MRI>";"         { RTOKEN(';');}
 249 <BOTH,SCRIPT>"MEMORY"           { RTOKEN(MEMORY);}
 250 <BOTH,SCRIPT>"ORIGIN"           { RTOKEN(ORIGIN);}
 251 <BOTH,SCRIPT>"VERSION"          { RTOKEN(VERSIONK);}
 252 <EXPRESSION,BOTH,SCRIPT>"BLOCK"         { RTOKEN(BLOCK);}
 253 <EXPRESSION,BOTH,SCRIPT>"BIND"          { RTOKEN(BIND);}
 254 <BOTH,SCRIPT>"LENGTH"           { RTOKEN(LENGTH);}
 255 <EXPRESSION,BOTH,SCRIPT>"ALIGN"                 { RTOKEN(ALIGN_K);}
 256 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_ALIGN"    { RTOKEN(DATA_SEGMENT_ALIGN);}
 257 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_END"      { RTOKEN(DATA_SEGMENT_END);}
 258 <EXPRESSION,BOTH,SCRIPT>"ADDR"                  { RTOKEN(ADDR);}
 259 <EXPRESSION,BOTH,SCRIPT>"LOADADDR"              { RTOKEN(LOADADDR);}
 260 <EXPRESSION,BOTH>"MAX"                  { RTOKEN(MAX_K); }
 261 <EXPRESSION,BOTH>"MIN"                  { RTOKEN(MIN_K); }
 262 <EXPRESSION,BOTH>"ASSERT"               { RTOKEN(ASSERT_K); }
 263 <BOTH,SCRIPT>"ENTRY"                    { RTOKEN(ENTRY);}
 264 <BOTH,SCRIPT,MRI>"EXTERN"               { RTOKEN(EXTERN);}
 265 <EXPRESSION,BOTH,SCRIPT>"NEXT"                  { RTOKEN(NEXT);}
 266 <EXPRESSION,BOTH,SCRIPT>"sizeof_headers"        { RTOKEN(SIZEOF_HEADERS);}
 267 <EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS"        { RTOKEN(SIZEOF_HEADERS);}
 268 <BOTH,SCRIPT>"MAP"                      { RTOKEN(MAP);}
 269 <EXPRESSION,BOTH,SCRIPT>"SIZEOF"                { RTOKEN(SIZEOF);}
 270 <BOTH,SCRIPT>"TARGET"           { RTOKEN(TARGET_K);}
 271 <BOTH,SCRIPT>"SEARCH_DIR"               { RTOKEN(SEARCH_DIR);}
 272 <BOTH,SCRIPT>"OUTPUT"           { RTOKEN(OUTPUT);}
 273 <BOTH,SCRIPT>"INPUT"                    { RTOKEN(INPUT);}
 274 <EXPRESSION,BOTH,SCRIPT>"GROUP"         { RTOKEN(GROUP);}
 275 <EXPRESSION,BOTH,SCRIPT>"DEFINED"               { RTOKEN(DEFINED);}
 276 <BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS"    { RTOKEN(CREATE_OBJECT_SYMBOLS);}
 277 <BOTH,SCRIPT>"CONSTRUCTORS"             { RTOKEN( CONSTRUCTORS);}
 278 <BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION" { RTOKEN(FORCE_COMMON_ALLOCATION);}
 279 <BOTH,SCRIPT>"INHIBIT_COMMON_ALLOCATION" { RTOKEN(INHIBIT_COMMON_ALLOCATION);}
 280 <BOTH,SCRIPT>"SECTIONS"         { RTOKEN(SECTIONS);}
 281 <BOTH,SCRIPT>"FILL"                     { RTOKEN(FILL);}
 282 <BOTH,SCRIPT>"STARTUP"          { RTOKEN(STARTUP);}
 283 <BOTH,SCRIPT>"OUTPUT_FORMAT"            { RTOKEN(OUTPUT_FORMAT);}
 284 <BOTH,SCRIPT>"OUTPUT_ARCH"              { RTOKEN( OUTPUT_ARCH);}
 285 <BOTH,SCRIPT>"HLL"                      { RTOKEN(HLL);}
 286 <BOTH,SCRIPT>"SYSLIB"           { RTOKEN(SYSLIB);}
 287 <BOTH,SCRIPT>"FLOAT"                    { RTOKEN(FLOAT);}
 288 <BOTH,SCRIPT>"QUAD"                     { RTOKEN( QUAD);}
 289 <BOTH,SCRIPT>"SQUAD"                    { RTOKEN( SQUAD);}
 290 <BOTH,SCRIPT>"LONG"                     { RTOKEN( LONG);}
 291 <BOTH,SCRIPT>"SHORT"                    { RTOKEN( SHORT);}
 292 <BOTH,SCRIPT>"BYTE"                     { RTOKEN( BYTE);}
 293 <BOTH,SCRIPT>"NOFLOAT"          { RTOKEN(NOFLOAT);}
 294 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS"   { RTOKEN(NOCROSSREFS);}
 295 <BOTH,SCRIPT>"OVERLAY"                  { RTOKEN(OVERLAY); }
 296 <BOTH,SCRIPT>"SORT"                     { RTOKEN(SORT); }
 297 <EXPRESSION,BOTH,SCRIPT>"NOLOAD"        { RTOKEN(NOLOAD);}
 298 <EXPRESSION,BOTH,SCRIPT>"DSECT"         { RTOKEN(DSECT);}
 299 <EXPRESSION,BOTH,SCRIPT>"COPY"          { RTOKEN(COPY);}
 300 <EXPRESSION,BOTH,SCRIPT>"INFO"          { RTOKEN(INFO);}
 301 <EXPRESSION,BOTH,SCRIPT>"OVERLAY"       { RTOKEN(OVERLAY);}
 302 <BOTH,SCRIPT>"o"                        { RTOKEN(ORIGIN);}
 303 <BOTH,SCRIPT>"org"                      { RTOKEN(ORIGIN);}
 304 <BOTH,SCRIPT>"l"                        { RTOKEN( LENGTH);}
 305 <BOTH,SCRIPT>"len"                      { RTOKEN( LENGTH);}
 306 <BOTH,SCRIPT>"INCLUDE"                  { RTOKEN(INCLUDE);}
 307 <BOTH,SCRIPT>"PHDRS"                    { RTOKEN (PHDRS); }
 308 <EXPRESSION,BOTH,SCRIPT>"AT"                    { RTOKEN(AT);}
 309 <EXPRESSION,BOTH,SCRIPT>"SUBALIGN"              { RTOKEN(SUBALIGN);}
 310 <EXPRESSION,BOTH,SCRIPT>"PROVIDE"               { RTOKEN(PROVIDE); }
 311 <EXPRESSION,BOTH,SCRIPT>"KEEP"          { RTOKEN(KEEP); }
 312 <EXPRESSION,BOTH,SCRIPT>"EXCLUDE_FILE"        { RTOKEN(EXCLUDE_FILE); }
 313 <MRI>"#".*\n?                   { ++ lineno; }
 314 <MRI>"\n"                       { ++ lineno;  RTOKEN(NEWLINE); }
 315 <MRI>"*".*                      { /* Mri comment line */ }
 316 <MRI>";".*                      { /* Mri comment line */ }
 317 <MRI>"END"                      { RTOKEN(ENDWORD); }
 318 <MRI>"ALIGNMOD"         { RTOKEN(ALIGNMOD);}
 319 <MRI>"ALIGN"            { RTOKEN(ALIGN_K);}
 320 <MRI>"CHIP"                     { RTOKEN(CHIP); }
 321 <MRI>"BASE"                     { RTOKEN(BASE); }
 322 <MRI>"ALIAS"                     { RTOKEN(ALIAS); }
 323 <MRI>"TRUNCATE"                     { RTOKEN(TRUNCATE); }
 324 <MRI>"LOAD"                     { RTOKEN(LOAD); }
 325 <MRI>"PUBLIC"                   { RTOKEN(PUBLIC); }
 326 <MRI>"ORDER"                    { RTOKEN(ORDER); }
 327 <MRI>"NAME"                     { RTOKEN(NAMEWORD); }
 328 <MRI>"FORMAT"                   { RTOKEN(FORMAT); }
 329 <MRI>"CASE"                     { RTOKEN(CASE); }
 330 <MRI>"START"                    { RTOKEN(START); }
 331 <MRI>"LIST".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 332 <MRI>"SECT"                     { RTOKEN(SECT); }
 333 <EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE"                  { RTOKEN(ABSOLUTE); }
 334 <MRI>"end"                      { RTOKEN(ENDWORD); }
 335 <MRI>"alignmod"         { RTOKEN(ALIGNMOD);}
 336 <MRI>"align"            { RTOKEN(ALIGN_K);}
 337 <MRI>"chip"                     { RTOKEN(CHIP); }
 338 <MRI>"base"                     { RTOKEN(BASE); }
 339 <MRI>"alias"                     { RTOKEN(ALIAS); }
 340 <MRI>"truncate"                     { RTOKEN(TRUNCATE); }
 341 <MRI>"load"                     { RTOKEN(LOAD); }
 342 <MRI>"public"                   { RTOKEN(PUBLIC); }
 343 <MRI>"order"                    { RTOKEN(ORDER); }
 344 <MRI>"name"                     { RTOKEN(NAMEWORD); }
 345 <MRI>"format"                   { RTOKEN(FORMAT); }
 346 <MRI>"case"                     { RTOKEN(CASE); }
 347 <MRI>"extern"                   { RTOKEN(EXTERN); }
 348 <MRI>"start"                    { RTOKEN(START); }
 349 <MRI>"list".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 350 <MRI>"sect"                     { RTOKEN(SECT); }
 351 <EXPRESSION,BOTH,SCRIPT,MRI>"absolute"                  { RTOKEN(ABSOLUTE); }
 352
 353 <MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}*  {
 354 /* Filename without commas, needed to parse mri stuff */
 355                                  yylval.name = xstrdup (yytext);
 356                                   return NAME;
 357                                 }
 358
 359
 360 <BOTH,EXPRESSION>{FILENAMECHAR1}{FILENAMECHAR}* {
 361                                  yylval.name = xstrdup (yytext);
 362                                   return NAME;
 363                                 }
 364 <BOTH,EXPRESSION>"-l"{FILENAMECHAR}+ {
 365                                   yylval.name = xstrdup (yytext + 2);
 366                                   return LNAME;
 367                                 }
 368 <SCRIPT>{WILDCHAR}* {
 369                 /* Annoyingly, this pattern can match comments, and we have
 370                    longest match issues to consider.  So if the first two
 371                    characters are a comment opening, put the input back and
 372                    try again.  */
 373                 if (yytext[0] == '/' && yytext[1] == '*')
 374                   {
 375                     yyless (2);
 376                     comment ();
 377                   }
 378                 else
 379                   {
 380                     yylval.name = xstrdup (yytext);
 381                     return NAME;
 382                   }
 383         }
 384
 385 <EXPRESSION,BOTH,SCRIPT,VERS_NODE>"\""[^\"]*"\"" {
 386                                         /* No matter the state, quotes
 387                                            give what's inside */
 388                                         yylval.name = xstrdup (yytext + 1);
 389                                         yylval.name[yyleng - 2] = 0;
 390                                         return NAME;
 391                                 }
 392 <BOTH,SCRIPT,EXPRESSION>"\n"            { lineno++;}
 393 <MRI,BOTH,SCRIPT,EXPRESSION>[ \t\r]+    { }
 394
 395 <VERS_NODE,VERS_SCRIPT>[:,;]    { return *yytext; }
 396
 397 <VERS_NODE>global               { RTOKEN(GLOBAL); }
 398
 399 <VERS_NODE>local                { RTOKEN(LOCAL); }
 400
 401 <VERS_NODE>extern               { RTOKEN(EXTERN); }
 402
 403 <VERS_NODE>{V_IDENTIFIER}       { yylval.name = xstrdup (yytext);
 404                                   return VERS_IDENTIFIER; }
 405
 406 <VERS_SCRIPT>{V_TAG}            { yylval.name = xstrdup (yytext);
 407                                   return VERS_TAG; }
 408
 409 <VERS_START>"{"                 { BEGIN(VERS_SCRIPT); return *yytext; }
 410
 411 <VERS_SCRIPT>"{"                { BEGIN(VERS_NODE);
 412                                   vers_node_nesting = 0;
 413                                   return *yytext;
 414                                 }
 415 <VERS_SCRIPT>"}"                { return *yytext; }
 416 <VERS_NODE>"{"                  { vers_node_nesting++; return *yytext; }
 417 <VERS_NODE>"}"                  { if (--vers_node_nesting < 0)
 418                                     BEGIN(VERS_SCRIPT);
 419                                   return *yytext;
 420                                 }
 421
 422 <VERS_START,VERS_NODE,VERS_SCRIPT>[\n]          { lineno++; }
 423
 424 <VERS_START,VERS_NODE,VERS_SCRIPT>#.*           { /* Eat up comments */ }
 425
 426 <VERS_START,VERS_NODE,VERS_SCRIPT>[ \t\r]+      { /* Eat up whitespace */ }
 427
 428 <<EOF>> {
 429   include_stack_ptr--;
 430
 431   if (include_stack_ptr == 0)
 432   {
 433     yyterminate ();
 434   }
 435   else
 436   {
 437     yy_switch_to_buffer (include_stack[include_stack_ptr]);
 438   }
 439
 440   ldfile_input_filename = file_name_stack[include_stack_ptr - 1];
 441   lineno = lineno_stack[include_stack_ptr];
 442
 443   return END;
 444 }
 445
 446 <SCRIPT,MRI,VERS_START,VERS_SCRIPT,VERS_NODE>.  lex_warn_invalid (" in script", yytext);
 447 <EXPRESSION,DEFSYMEXP,BOTH>.    lex_warn_invalid (" in expression", yytext);
 448
 449 %%
 450 \f
 451
 452 /* Switch flex to reading script file NAME, open on FILE,
 453    saving the current input info on the include stack.  */
 454
 455 void
 456 lex_push_file (FILE *file, const char *name)
 457 {
 458   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 459     {
 460       einfo ("%F:includes nested too deeply\n");
 461     }
 462   file_name_stack[include_stack_ptr] = name;
 463   lineno_stack[include_stack_ptr] = lineno;
 464   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 465
 466   include_stack_ptr++;
 467   lineno = 1;
 468   yyin = file;
 469   yy_switch_to_buffer (yy_create_buffer (yyin, YY_BUF_SIZE));
 470 }
 471
 472 /* Return a newly created flex input buffer containing STRING,
 473    which is SIZE bytes long.  */
 474
 475 static YY_BUFFER_STATE
 476 yy_create_string_buffer (const char *string, size_t size)
 477 {
 478   YY_BUFFER_STATE b;
 479
 480   /* Calls to m-alloc get turned by sed into xm-alloc.  */
 481   b = malloc (sizeof (struct yy_buffer_state));
 482   b->yy_input_file = 0;
 483   b->yy_buf_size = size;
 484
 485   /* yy_ch_buf has to be 2 characters longer than the size given because
 486      we need to put in 2 end-of-buffer characters.  */
 487   b->yy_ch_buf = malloc ((unsigned) (b->yy_buf_size + 3));
 488
 489   b->yy_ch_buf[0] = '\n';
 490   strcpy (b->yy_ch_buf+1, string);
 491   b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
 492   b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
 493   b->yy_n_chars = size+1;
 494   b->yy_buf_pos = &b->yy_ch_buf[1];
 495
 496   b->yy_is_our_buffer = 1;
 497   b->yy_is_interactive = 0;
 498   b->yy_at_bol = 1;
 499   b->yy_fill_buffer = 0;
 500
 501   /* flex 2.4.7 changed the interface.  FIXME: We should not be using
 502      a flex internal interface in the first place!  */
 503 #ifdef YY_BUFFER_NEW
 504   b->yy_buffer_status = YY_BUFFER_NEW;
 505 #else
 506   b->yy_eof_status = EOF_NOT_SEEN;
 507 #endif
 508
 509   return b;
 510 }
 511
 512 /* Switch flex to reading from STRING, saving the current input info
 513    on the include stack.  */
 514
 515 void
 516 lex_redirect (const char *string)
 517 {
 518   YY_BUFFER_STATE tmp;
 519
 520   yy_init = 0;
 521   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 522     {
 523       einfo("%F: macros nested too deeply\n");
 524     }
 525   file_name_stack[include_stack_ptr] = "redirect";
 526   lineno_stack[include_stack_ptr] = lineno;
 527   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 528   include_stack_ptr++;
 529   lineno = 1;
 530   tmp = yy_create_string_buffer (string, strlen (string));
 531   yy_switch_to_buffer (tmp);
 532 }
 533 \f
 534 /* Functions to switch to a different flex start condition,
 535    saving the current start condition on `state_stack'.  */
 536
 537 static int state_stack[MAX_INCLUDE_DEPTH * 2];
 538 static int *state_stack_p = state_stack;
 539
 540 void
 541 ldlex_script (void)
 542 {
 543   *(state_stack_p)++ = yy_start;
 544   BEGIN (SCRIPT);
 545 }
 546
 547 void
 548 ldlex_mri_script (void)
 549 {
 550   *(state_stack_p)++ = yy_start;
 551   BEGIN (MRI);
 552 }
 553
 554 void
 555 ldlex_version_script (void)
 556 {
 557   *(state_stack_p)++ = yy_start;
 558   BEGIN (VERS_START);
 559 }
 560
 561 void
 562 ldlex_version_file (void)
 563 {
 564   *(state_stack_p)++ = yy_start;
 565   BEGIN (VERS_SCRIPT);
 566 }
 567
 568 void
 569 ldlex_defsym (void)
 570 {
 571   *(state_stack_p)++ = yy_start;
 572   BEGIN (DEFSYMEXP);
 573 }
 574
 575 void
 576 ldlex_expression (void)
 577 {
 578   *(state_stack_p)++ = yy_start;
 579   BEGIN (EXPRESSION);
 580 }
 581
 582 void
 583 ldlex_both (void)
 584 {
 585   *(state_stack_p)++ = yy_start;
 586   BEGIN (BOTH);
 587 }
 588
 589 void
 590 ldlex_popstate (void)
 591 {
 592   yy_start = *(--state_stack_p);
 593 }
 594 \f
 595
 596 /* Place up to MAX_SIZE characters in BUF and return in *RESULT
 597    either the number of characters read, or 0 to indicate EOF.  */
 598
 599 static void
 600 yy_input (char *buf, int *result, int max_size)
 601 {
 602   *result = 0;
 603   if (YY_CURRENT_BUFFER->yy_input_file)
 604     {
 605       if (yyin)
 606         {
 607           *result = fread (buf, 1, max_size, yyin);
 608           if (*result < max_size && ferror (yyin))
 609             einfo ("%F%P: read in flex scanner failed\n");
 610         }
 611     }
 612 }
 613
 614 /* Eat the rest of a C-style comment.  */
 615
 616 static void
 617 comment (void)
 618 {
 619   int c;
 620
 621   while (1)
 622   {
 623     c = input();
 624     while (c != '*' && c != EOF)
 625     {
 626       if (c == '\n')
 627         lineno++;
 628       c = input();
 629     }
 630
 631     if (c == '*')
 632     {
 633       c = input();
 634       while (c == '*')
 635        c = input();
 636       if (c == '/')
 637        break;                   /* found the end */
 638     }
 639
 640     if (c == '\n')
 641       lineno++;
 642
 643     if (c == EOF)
 644     {
 645       einfo( "%F%P: EOF in comment\n");
 646       break;
 647     }
 648   }
 649 }
 650
 651 /* Warn the user about a garbage character WHAT in the input
 652    in context WHERE.  */
 653
 654 static void
 655 lex_warn_invalid (char *where, char *what)
 656 {
 657   char buf[5];
 658
 659   /* If we have found an input file whose format we do not recognize,
 660      and we are therefore treating it as a linker script, and we find
 661      an invalid character, then most likely this is a real object file
 662      of some different format.  Treat it as such.  */
 663   if (ldfile_assumed_script)
 664     {
 665       bfd_set_error (bfd_error_file_not_recognized);
 666       einfo ("%F%s: file not recognized: %E\n", ldfile_input_filename);
 667     }
 668
 669   if (! ISPRINT (*what))
 670     {
 671       sprintf (buf, "\\%03o", (unsigned int) *what);
 672       what = buf;
 673     }
 674
 675   einfo ("%P:%S: ignoring invalid character `%s'%s\n", what, where);
 676 }