toolchain/gcc/libgloss/m68k/sim.ld

   1 STARTUP(sim-crt0.o)
   2 OUTPUT_ARCH(m68k)
   3
   4 SEARCH_DIR(.)
   5 GROUP(-lsim -lc -lgcc -lsim)
   6 __DYNAMIC  =  0;
   7
   8
   9 MEMORY
  10 {
  11   ram (rwx) : ORIGIN = 0x80000000, LENGTH = 1M
  12 }
  13
  14 PROVIDE (__stack = 0);
  15
  16 SECTIONS
  17 {
  18   .text :
  19   {
  20     CREATE_OBJECT_SYMBOLS
  21     *(.text)
  22
  23     . = ALIGN(0x4);
  24     /* These are for running static constructors and destructors under ELF.  */
  25     KEEP (*crtbegin.o(.ctors))
  26     KEEP (*(EXCLUDE_FILE (*crtend.o) .ctors))
  27     KEEP (*(SORT(.ctors.*)))
  28     KEEP (*(.ctors))
  29     KEEP (*crtbegin.o(.dtors))
  30     KEEP (*(EXCLUDE_FILE (*crtend.o) .dtors))
  31     KEEP (*(SORT(.dtors.*)))
  32     KEEP (*(.dtors))
  33
  34     *(.rodata)
  35
  36     . = ALIGN(0x4);
  37     *(.gcc_except_table)
  38
  39     . = ALIGN(0x4);
  40     *(.eh_frame)
  41
  42     . = ALIGN(0x4);
  43     __INIT_SECTION__ = . ;
  44     LONG (0x4e560000)   /* linkw %fp,#0 */
  45     *(.init)
  46     SHORT (0x4e5e)      /* unlk %fp */
  47     SHORT (0x4e75)      /* rts */
  48
  49     . = ALIGN(0x4);
  50     __FINI_SECTION__ = . ;
  51     LONG (0x4e560000)   /* linkw %fp,#0 */
  52     *(.fini)
  53     SHORT (0x4e5e)      /* unlk %fp */
  54     SHORT (0x4e75)      /* rts */
  55
  56     _etext = .;
  57     *(.lit)
  58   } > ram
  59
  60   .data :
  61   {
  62     *(.shdata)
  63     *(.data)
  64     _edata = .;
  65   } > ram
  66
  67   .bss :
  68   {
  69     . = ALIGN(0x4);
  70     __bss_start = . ;
  71     *(.shbss)
  72     *(.bss)
  73     *(COMMON)
  74     _end =  ALIGN (0x8);
  75     __end = _end;
  76   } > ram
  77
  78   .stab 0 (NOLOAD) :
  79   {
  80     *(.stab)
  81   }
  82
  83   .stabstr 0 (NOLOAD) :
  84   {
  85     *(.stabstr)
  86   }
  87 }