toolchain/gcc/libgloss/mips/array.ld

   1 /*
   2  * memory map assumed by prom and standalone system
   3  *
   4  * physical     kseg1                   use
   5  *
   6  * 0x1fc20000   0xbfc20000
   7  * to                                   prom text and read-only data
   8  * 0x1fc00000   0xbfc00000              (in cpu board "prom space")
   9  *
  10  * (Top of RAM - 8K) downward           sash and standalone program stack
  11  *              |                       ( - 8K to preserve kernel message bufs)
  12  *              V                       (standalone programs grow their stack
  13  *                                       immediately below sash's stack)
  14  *
  15  *              ^
  16  *              |
  17  * 0x00100000   0xa0100000 upward       sash program text, data, and bss
  18  *
  19  *              ^
  20  *              |
  21  * 0x00020000   0xa0020000 upward       standalone program text, data, and bss
  22  *                                      (kernel is loaded here, also)
  23  *
  24  * 0x0001ffff   0xa001ffff downward     dbgmon stack
  25  *              |
  26  *              V
  27  *
  28  *              ^
  29  *              |
  30  * 0x00010000   0xa0010000 upward       dbgmon text, data, and bss
  31  *
  32  * 0x0000ffff   0xa000ffff downward     prom monitor stack
  33  *              |
  34  *              V
  35  *
  36  *              ^
  37  *              |
  38  * 0x00000500   0xa0000500 upward       prom monitor bss
  39  *
  40  * 0x000004ff   0xa00004ff
  41  * to                                   restart block
  42  * 0x00000400   0xa0000400
  43  *
  44  * 0x000003ff   0xa00003ff
  45  * to                                   general exception code
  46  * 0x00000080   0xa0000080              (note cpu addresses as 0x80000080!)
  47  *
  48  * 0x0000007f   0xa000007f
  49  * to                                   utlbmiss exception code
  50  * 0x00000000   0xa0000000              (note cpu addresses as 0x80000000!)
  51  */
  52
  53 /* Uncomment this if you want srecords.
  54 OUTPUT_FORMAT(srec)
  55  */
  56 ENTRY(start)
  57 STARTUP(crt0.o)
  58 INPUT(array.o)
  59 SEARCH_DIR(.)
  60 __DYNAMIC  =  0;
  61
  62 /*
  63  * Allocate the stack to be at the top of memory, since the stack
  64  * grows down
  65  *
  66 PROVIDE (__stack = 1M - 8);
  67  */
  68
  69 /*
  70  * Initalize some symbols to be zero so we can reference them in the
  71  * crt0 without core dumping. These functions are all optional, but
  72  * we do this so we can have our crt0 always use them if they exist.
  73  * This is so BSPs work better when using the crt0 installed with gcc.
  74  * We have to initalize them twice, so we multiple object file
  75  * formats, as some prepend an underscore.
  76  */
  77 PROVIDE (hardware_exit_hook = 0);
  78 PROVIDE (hardware_hazard_hook = 0);
  79 PROVIDE (hardware_init_hook = 0);
  80 PROVIDE (software_init_hook = 0);
  81
  82 SECTIONS
  83 {
  84   . = 0x80020000;
  85   .text : {
  86      _ftext = . ;
  87     *(.init)
  88      eprol  =  .;
  89     *(.text)
  90     *(.text.*)
  91     *(.gnu.linkonce.t*)
  92     *(.mips16.fn.*)
  93     *(.mips16.call.*)
  94     PROVIDE (__runtime_reloc_start = .);
  95     *(.rel.sdata)
  96     PROVIDE (__runtime_reloc_stop = .);
  97     *(.fini)
  98      etext  =  .;
  99      _etext  =  .;
 100   }
 101
 102   .ctors    :
 103   {
 104     /* gcc uses crtbegin.o to find the start of
 105        the constructors, so we make sure it is
 106        first.  Because this is a wildcard, it
 107        doesn't matter if the user does not
 108        actually link against crtbegin.o; the
 109        linker won't look for a file to match a
 110        wildcard.  The wildcard also means that it
 111        doesn't matter which directory crtbegin.o
 112        is in.  */
 113
 114     KEEP (*crtbegin.o(.ctors))
 115
 116     /* We don't want to include the .ctor section from
 117        from the crtend.o file until after the sorted ctors.
 118        The .ctor section from the crtend file contains the
 119        end of ctors marker and it must be last */
 120
 121     KEEP (*(EXCLUDE_FILE (*crtend.o) .ctors))
 122     KEEP (*(SORT(.ctors.*)))
 123     KEEP (*(.ctors))
 124   }
 125
 126   .dtors    :
 127   {
 128     KEEP (*crtbegin.o(.dtors))
 129     KEEP (*(EXCLUDE_FILE (*crtend.o) .dtors))
 130     KEEP (*(SORT(.dtors.*)))
 131     KEEP (*(.dtors))
 132   }
 133
 134   . = .;
 135   .rdata : {
 136     *(.rdata)
 137     *(.rodata)
 138     *(.rodata.*)
 139     *(.gnu.linkonce.r*)
 140   }
 141    _fdata = ALIGN(16);
 142   .data : {
 143     *(.data)
 144     *(.data.*)
 145     *(.gnu.linkonce.d*)
 146   }
 147    _gp = ALIGN(16) + 0x8000;
 148   .lit8 : {
 149     *(.lit8)
 150   }
 151   .lit4 : {
 152     *(.lit4)
 153   }
 154   .sdata : {
 155     *(.sdata)
 156     *(.sdata.*)
 157     *(.gnu.linkonce.s*)
 158   }
 159    edata  =  .;
 160    _edata  =  .;
 161    _fbss = .;
 162   .sbss : {
 163     *(.sbss)
 164     *(.scommon)
 165   }
 166   .bss : {
 167     _bss_start = . ;
 168     *(.bss)
 169     *(COMMON)
 170   }
 171    end = .;
 172    _end = .;
 173 }