toolchain/gcc/libgloss/mips/ddb-kseg0.ld

   1 /* The following TEXT start address leaves space for the monitor
   2    workspace. */
   3
   4 ENTRY(_start)
   5 STARTUP(crt0.o)
   6 OUTPUT_FORMAT("elf32-bigmips", "elf32-bigmips", "elf32-littlemips")
   7 GROUP(-lc -lpmon -lgcc)
   8 SEARCH_DIR(.)
   9 __DYNAMIC  =  0;
  10
  11 /*
  12  * Allocate the stack to be at the top of memory, since the stack
  13  * grows down
  14  */
  15 PROVIDE (__stack = 0);
  16 /* PROVIDE (__global = 0); */
  17
  18 /*
  19  * Initalize some symbols to be zero so we can reference them in the
  20  * crt0 without core dumping. These functions are all optional, but
  21  * we do this so we can have our crt0 always use them if they exist.
  22  * This is so BSPs work better when using the crt0 installed with gcc.
  23  * We have to initalize them twice, so we multiple object file
  24  * formats, as some prepend an underscore.
  25  */
  26 PROVIDE (hardware_exit_hook = 0);
  27 PROVIDE (hardware_hazard_hook = 0);
  28 PROVIDE (hardware_init_hook = 0);
  29 PROVIDE (software_init_hook = 0);
  30
  31 SECTIONS
  32 {
  33   . = 0x80100000;
  34   .text : {
  35      _ftext = . ;
  36     KEEP (*(.init))
  37      eprol  =  .;
  38     *(.text)
  39     *(.text.*)
  40     *(.gnu.linkonce.t*)
  41     *(.mips16.fn.*)
  42     *(.mips16.call.*)
  43     PROVIDE (__runtime_reloc_start = .);
  44     *(.rel.sdata)
  45     PROVIDE (__runtime_reloc_stop = .);
  46     KEEP (*(.fini))
  47      etext  =  .;
  48      _etext  =  .;
  49   }
  50
  51   .ctors    :
  52   {
  53     /* gcc uses crtbegin.o to find the start of
  54        the constructors, so we make sure it is
  55        first.  Because this is a wildcard, it
  56        doesn't matter if the user does not
  57        actually link against crtbegin.o; the
  58        linker won't look for a file to match a
  59        wildcard.  The wildcard also means that it
  60        doesn't matter which directory crtbegin.o
  61        is in.  */
  62
  63     KEEP (*crtbegin.o(.ctors))
  64
  65     /* We don't want to include the .ctor section from
  66        from the crtend.o file until after the sorted ctors.
  67        The .ctor section from the crtend file contains the
  68        end of ctors marker and it must be last */
  69
  70     KEEP (*(EXCLUDE_FILE (*crtend.o) .ctors))
  71     KEEP (*(SORT(.ctors.*)))
  72     KEEP (*(.ctors))
  73   }
  74
  75   .dtors    :
  76   {
  77     KEEP (*crtbegin.o(.dtors))
  78     KEEP (*(EXCLUDE_FILE (*crtend.o) .dtors))
  79     KEEP (*(SORT(.dtors.*)))
  80     KEEP (*(.dtors))
  81   }
  82
  83   . = .;
  84   .rdata : {
  85     *(.rdata)
  86     *(.rodata)
  87     *(.rodata.*)
  88     *(.gnu.linkonce.r*)
  89   }
  90    _fdata = ALIGN(16);
  91   .data : {
  92     *(.data)
  93     *(.data.*)
  94     *(.gnu.linkonce.d*)
  95   }
  96   . = ALIGN(8);
  97   _gp = . + 0x8000;
  98   __global = _gp;
  99   .lit8 : {
 100     *(.lit8)
 101   }
 102   .lit4 : {
 103     *(.lit4)
 104   }
 105   .sdata : {
 106     *(.sdata)
 107     *(.sdata.*)
 108     *(.gnu.linkonce.s*)
 109   }
 110   . = ALIGN(4);
 111    edata  =  .;
 112    _edata  =  .;
 113    _fbss = .;
 114   .sbss : {
 115     *(.sbss)
 116     *(.scommon)
 117   }
 118   .bss : {
 119     _bss_start = . ;
 120     *(.bss)
 121     *(COMMON)
 122   }
 123
 124    end = .;
 125    _end = .;
 126
 127   /* DWARF debug sections.
 128      Symbols in the DWARF debugging sections are relative to
 129      the beginning of the section so we begin them at 0.  */
 130
 131   /* DWARF 1 */
 132   .debug          0 : { *(.debug) }
 133   .line           0 : { *(.line) }
 134
 135   /* GNU DWARF 1 extensions */
 136   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 137   .debug_sfnames  0 : { *(.debug_sfnames) }
 138
 139   /* DWARF 1.1 and DWARF 2 */
 140   .debug_aranges  0 : { *(.debug_aranges) }
 141   .debug_pubnames 0 : { *(.debug_pubnames) }
 142
 143   /* DWARF 2 */
 144   .debug_info     0 : { *(.debug_info) }
 145   .debug_abbrev   0 : { *(.debug_abbrev) }
 146   .debug_line     0 : { *(.debug_line) }
 147   .debug_frame    0 : { *(.debug_frame) }
 148   .debug_str      0 : { *(.debug_str) }
 149   .debug_loc      0 : { *(.debug_loc) }
 150   .debug_macinfo  0 : { *(.debug_macinfo) }
 151
 152   /* SGI/MIPS DWARF 2 extensions */
 153   .debug_weaknames 0 : { *(.debug_weaknames) }
 154   .debug_funcnames 0 : { *(.debug_funcnames) }
 155   .debug_typenames 0 : { *(.debug_typenames) }
 156   .debug_varnames  0 : { *(.debug_varnames) }
 157 }