toolchain/gcc/libgloss/mips/jmr3904app.ld

   1 /* Linker script forJMR 3904 board */
   2
   3 ENTRY(_start)
   4 STARTUP(crt0.o)
   5 OUTPUT_ARCH("mips:3000")
   6 OUTPUT_FORMAT("elf32-bigmips", "elf32-bigmips", "elf32-littlemips")
   7 GROUP(-lc -ljmr3904 -lgcc)
   8 SEARCH_DIR(.)
   9 __DYNAMIC  =  0;
  10
  11 PROVIDE (_mem_size = 0x100000); /* JMR3904 comes as standard with 512k of RAM */
  12
  13 /* PROVIDE (__global = 0); */
  14
  15 /*
  16  * Initalize some symbols to be zero so we can reference them in the
  17  * crt0 without core dumping. These functions are all optional, but
  18  * we do this so we can have our crt0 always use them if they exist.
  19  * This is so BSPs work better when using the crt0 installed with gcc.
  20  * We have to initalize them twice, so we multiple object file
  21  * formats, as some prepend an underscore.
  22  */
  23 PROVIDE (hardware_exit_hook = 0);
  24 PROVIDE (hardware_hazard_hook = 0);
  25 PROVIDE (hardware_init_hook = 0);
  26 PROVIDE (software_init_hook = 0);
  27
  28 SECTIONS
  29 {
  30   . = 0x80008000;
  31       /* This is NOT the address which fits with the monitor from jmr. */
  32       /* It fits the Cygmon ROMS */
  33   .text : {
  34      _ftext = . ;
  35     *(.init)
  36      eprol  =  .;
  37     *(.text)
  38     *(.text.*)
  39     *(.gnu.linkonce.t*)
  40     *(.mips16.fn.*)
  41     *(.mips16.call.*)
  42     PROVIDE (__runtime_reloc_start = .);
  43     *(.rel.sdata)
  44     PROVIDE (__runtime_reloc_stop = .);
  45     *(.fini)
  46      etext  =  .;
  47      _etext  =  .;
  48   }
  49
  50   .ctors    :
  51   {
  52     /* gcc uses crtbegin.o to find the start of
  53        the constructors, so we make sure it is
  54        first.  Because this is a wildcard, it
  55        doesn't matter if the user does not
  56        actually link against crtbegin.o; the
  57        linker won't look for a file to match a
  58        wildcard.  The wildcard also means that it
  59        doesn't matter which directory crtbegin.o
  60        is in.  */
  61
  62     KEEP (*crtbegin.o(.ctors))
  63
  64     /* We don't want to include the .ctor section from
  65        from the crtend.o file until after the sorted ctors.
  66        The .ctor section from the crtend file contains the
  67        end of ctors marker and it must be last */
  68
  69     KEEP (*(EXCLUDE_FILE (*crtend.o) .ctors))
  70     KEEP (*(SORT(.ctors.*)))
  71     KEEP (*(.ctors))
  72   }
  73
  74   .dtors    :
  75   {
  76     KEEP (*crtbegin.o(.dtors))
  77     KEEP (*(EXCLUDE_FILE (*crtend.o) .dtors))
  78     KEEP (*(SORT(.dtors.*)))
  79     KEEP (*(.dtors))
  80   }
  81
  82   . = .;
  83   .rodata : {
  84     *(.rdata)
  85     *(.rodata)
  86     *(.rodata.*)
  87     *(.gnu.linkonce.r*)
  88   }
  89    _fdata = ALIGN(16);
  90   .data : {
  91     *(.data)
  92     *(.data.*)
  93     *(.gnu.linkonce.d*)
  94   }
  95   . = ALIGN(8);
  96   _gp = . + 0x8000;
  97   __global = _gp;
  98   .lit8 : {
  99     *(.lit8)
 100   }
 101   .lit4 : {
 102     *(.lit4)
 103   }
 104   .sdata : {
 105     *(.sdata)
 106     *(.sdata.*)
 107     *(.gnu.linkonce.s*)
 108   }
 109   . = ALIGN(4);
 110    edata  =  .;
 111    _edata  =  .;
 112    _fbss = .;
 113   .sbss : {
 114     *(.sbss)
 115     *(.scommon)
 116   }
 117   .bss : {
 118     _bss_start = . ;
 119     *(.bss)
 120     *(COMMON)
 121     . += 0x2000 ;  /* 8k bytes of stack. */
 122     __stack = ALIGN(64) ;
 123     . = __stack ;
 124   }
 125
 126    end = .;
 127    _end = .;
 128
 129   /* DWARF debug sections.
 130      Symbols in the DWARF debugging sections are relative to
 131      the beginning of the section so we begin them at 0.  */
 132
 133   /* DWARF 1 */
 134   .debug          0 : { *(.debug) }
 135   .line           0 : { *(.line) }
 136
 137   /* GNU DWARF 1 extensions */
 138   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 139   .debug_sfnames  0 : { *(.debug_sfnames) }
 140
 141   /* DWARF 1.1 and DWARF 2 */
 142   .debug_aranges  0 : { *(.debug_aranges) }
 143   .debug_pubnames 0 : { *(.debug_pubnames) }
 144
 145   /* DWARF 2 */
 146   .debug_info     0 : { *(.debug_info) }
 147   .debug_abbrev   0 : { *(.debug_abbrev) }
 148   .debug_line     0 : { *(.debug_line) }
 149   .debug_frame    0 : { *(.debug_frame) }
 150   .debug_str      0 : { *(.debug_str) }
 151   .debug_loc      0 : { *(.debug_loc) }
 152   .debug_macinfo  0 : { *(.debug_macinfo) }
 153
 154   /* SGI/MIPS DWARF 2 extensions */
 155   .debug_weaknames 0 : { *(.debug_weaknames) }
 156   .debug_funcnames 0 : { *(.debug_funcnames) }
 157   .debug_typenames 0 : { *(.debug_typenames) }
 158   .debug_varnames  0 : { *(.debug_varnames) }
 159 }