toolchain/gcc/libgloss/mips/pmon.ld

   1 /* The following TEXT start address leaves space for the monitor
   2    workspace. */
   3
   4 ENTRY(_start)
   5 STARTUP(crt0.o)
   6 OUTPUT_ARCH("mips:4000")
   7 OUTPUT_FORMAT("elf32-bigmips", "elf32-bigmips", "elf32-littlemips")
   8 GROUP(-lc -lpmon -lgcc)
   9 SEARCH_DIR(.)
  10 __DYNAMIC  =  0;
  11
  12 /*
  13  * Allocate the stack to be at the top of memory, since the stack
  14  * grows down
  15  */
  16 PROVIDE (__stack = 0);
  17 /* PROVIDE (__global = 0); */
  18
  19 /*
  20  * Initalize some symbols to be zero so we can reference them in the
  21  * crt0 without core dumping. These functions are all optional, but
  22  * we do this so we can have our crt0 always use them if they exist.
  23  * This is so BSPs work better when using the crt0 installed with gcc.
  24  * We have to initalize them twice, so we multiple object file
  25  * formats, as some prepend an underscore.
  26  */
  27 PROVIDE (hardware_exit_hook = 0);
  28 PROVIDE (hardware_hazard_hook = 0);
  29 PROVIDE (hardware_init_hook = 0);
  30 PROVIDE (software_init_hook = 0);
  31
  32 SECTIONS
  33 {
  34   . = 0xA0020000;
  35   .text : {
  36      _ftext = . ;
  37     *(.init)
  38      eprol  =  .;
  39     *(.text)
  40     *(.text.*)
  41     *(.gnu.linkonce.t*)
  42     *(.mips16.fn.*)
  43     *(.mips16.call.*)
  44     PROVIDE (__runtime_reloc_start = .);
  45     *(.rel.sdata)
  46     PROVIDE (__runtime_reloc_stop = .);
  47     *(.fini)
  48      etext  =  .;
  49      _etext  =  .;
  50   }
  51
  52   .ctors    :
  53   {
  54     /* gcc uses crtbegin.o to find the start of
  55        the constructors, so we make sure it is
  56        first.  Because this is a wildcard, it
  57        doesn't matter if the user does not
  58        actually link against crtbegin.o; the
  59        linker won't look for a file to match a
  60        wildcard.  The wildcard also means that it
  61        doesn't matter which directory crtbegin.o
  62        is in.  */
  63
  64     KEEP (*crtbegin.o(.ctors))
  65
  66     /* We don't want to include the .ctor section from
  67        from the crtend.o file until after the sorted ctors.
  68        The .ctor section from the crtend file contains the
  69        end of ctors marker and it must be last */
  70
  71     KEEP (*(EXCLUDE_FILE (*crtend.o) .ctors))
  72     KEEP (*(SORT(.ctors.*)))
  73     KEEP (*(.ctors))
  74   }
  75
  76   .dtors    :
  77   {
  78     KEEP (*crtbegin.o(.dtors))
  79     KEEP (*(EXCLUDE_FILE (*crtend.o) .dtors))
  80     KEEP (*(SORT(.dtors.*)))
  81     KEEP (*(.dtors))
  82   }
  83
  84   . = .;
  85   .rodata : {
  86     *(.rdata)
  87     *(.rodata)
  88     *(.rodata.*)
  89     *(.gnu.linkonce.r*)
  90   }
  91    _fdata = ALIGN(16);
  92   .data : {
  93     *(.data)
  94     *(.data.*)
  95     *(.gnu.linkonce.d*)
  96   }
  97   . = ALIGN(8);
  98   _gp = . + 0x8000;
  99   __global = _gp;
 100   .lit8 : {
 101     *(.lit8)
 102   }
 103   .lit4 : {
 104     *(.lit4)
 105   }
 106   .sdata : {
 107     *(.sdata)
 108     *(.sdata.*)
 109     *(.gnu.linkonce.s*)
 110   }
 111   . = ALIGN(4);
 112    edata  =  .;
 113    _edata  =  .;
 114    _fbss = .;
 115   .sbss : {
 116     *(.sbss)
 117     *(.scommon)
 118   }
 119   .bss : {
 120     _bss_start = . ;
 121     *(.bss)
 122     *(COMMON)
 123   }
 124
 125    end = .;
 126    _end = .;
 127
 128   /* DWARF debug sections.
 129      Symbols in the DWARF debugging sections are relative to
 130      the beginning of the section so we begin them at 0.  */
 131
 132   /* DWARF 1 */
 133   .debug          0 : { *(.debug) }
 134   .line           0 : { *(.line) }
 135
 136   /* GNU DWARF 1 extensions */
 137   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 138   .debug_sfnames  0 : { *(.debug_sfnames) }
 139
 140   /* DWARF 1.1 and DWARF 2 */
 141   .debug_aranges  0 : { *(.debug_aranges) }
 142   .debug_pubnames 0 : { *(.debug_pubnames) }
 143
 144   /* DWARF 2 */
 145   .debug_info     0 : { *(.debug_info) }
 146   .debug_abbrev   0 : { *(.debug_abbrev) }
 147   .debug_line     0 : { *(.debug_line) }
 148   .debug_frame    0 : { *(.debug_frame) }
 149   .debug_str      0 : { *(.debug_str) }
 150   .debug_loc      0 : { *(.debug_loc) }
 151   .debug_macinfo  0 : { *(.debug_macinfo) }
 152
 153   /* SGI/MIPS DWARF 2 extensions */
 154   .debug_weaknames 0 : { *(.debug_weaknames) }
 155   .debug_funcnames 0 : { *(.debug_funcnames) }
 156   .debug_typenames 0 : { *(.debug_typenames) }
 157   .debug_varnames  0 : { *(.debug_varnames) }
 158 }