toolchain/gcc/libgloss/pa/w89k.ld

   1 OUTPUT_ARCH(hppa)
   2 ENTRY("$START$")
   3 STARTUP(crt0.o)
   4 GROUP(-lc -lw89k -lgcc)
   5 SEARCH_DIR(.)
   6
   7 MEMORY
   8 {
   9   ram (rwx) : ORIGIN = 0x100000, LENGTH = 0x100000
  10 }
  11
  12 SECTIONS
  13 {
  14   .text :
  15   {
  16     CREATE_OBJECT_SYMBOLS
  17     *(.PARISC.stubs)
  18     *(.text)
  19      etext  =  . ;
  20      _etext  =  . ;
  21      __CTOR_LIST__ = . ;
  22      LONG((__CTOR_END__ - __CTOR_LIST__) / 4 - 2)
  23     *(.ctors)
  24      LONG(0)
  25      __CTOR_END__ = . ;
  26      __DTOR_LIST__ = . ;
  27      LONG((__DTOR_END__ - __DTOR_LIST__) / 4 - 2)
  28     *(.dtors)
  29      LONG(0)
  30      __DTOR_END__ = . ;
  31     *(.lit)
  32     *(.shdata)
  33     $global$ = ALIGN(4) ;
  34     . += 4;
  35   } > ram
  36
  37   .data : {
  38     *(.data)
  39     CONSTRUCTORS
  40     edata  =  . ;
  41     _edata  =  . ;
  42   } > ram
  43
  44   .bss : {
  45     _bss_start = ALIGN(4) ;
  46     *(.bss)
  47     *(COMMON)
  48     _stack = ALIGN(64) ;        /* Stack grows up on the PA!!! */
  49     . += 0x2000 ;
  50     end = . ;
  51     _end = . ;
  52   } > ram
  53
  54 }