toolchain/gcc/newlib/libc/machine/i960/memchr_ca.S

   1 /*******************************************************************************
   2  *
   3  * Copyright (c) 1993 Intel Corporation
   4  *
   5  * Intel hereby grants you permission to copy, modify, and distribute this
   6  * software and its documentation.  Intel grants this permission provided
   7  * that the above copyright notice appears in all copies and that both the
   8  * copyright notice and this permission notice appear in supporting
   9  * documentation.  In addition, Intel grants this permission provided that
  10  * you prominently mark as "not part of the original" any modifications
  11  * made to this software or documentation, and that the name of Intel
  12  * Corporation not be used in advertising or publicity pertaining to
  13  * distribution of the software or the documentation without specific,
  14  * written prior permission.
  15  *
  16  * Intel Corporation provides this AS IS, WITHOUT ANY WARRANTY, EXPRESS OR
  17  * IMPLIED, INCLUDING, WITHOUT LIMITATION, ANY WARRANTY OF MERCHANTABILITY
  18  * OR FITNESS FOR A PARTICULAR PURPOSE.  Intel makes no guarantee or
  19  * representations regarding the use of, or the results of the use of,
  20  * the software and documentation in terms of correctness, accuracy,
  21  * reliability, currentness, or otherwise; and you rely on the software,
  22  * documentation and results solely at your own risk.
  23  *
  24  * IN NO EVENT SHALL INTEL BE LIABLE FOR ANY LOSS OF USE, LOSS OF BUSINESS,
  25  * LOSS OF PROFITS, INDIRECT, INCIDENTAL, SPECIAL OR CONSEQUENTIAL DAMAGES
  26  * OF ANY KIND.  IN NO EVENT SHALL INTEL'S TOTAL LIABILITY EXCEED THE SUM
  27  * PAID TO INTEL FOR THE PRODUCT LICENSED HEREUNDER.
  28  *
  29  ******************************************************************************/
  30
  31         .file "memchr_ca.s"
  32 #ifdef  __PIC
  33         .pic
  34 #endif
  35 #ifdef  __PID
  36         .pid
  37 #endif
  38 /*
  39  * (c) copyright 1988,1993 Intel Corp., all rights reserved
  40  */
  41
  42 /*
  43         procedure memchr  (optimized assembler version for the CA)
  44
  45         src_addr = memchr (src_addr, char, max_bytes)
  46
  47         searching from src_addr for max_bytes bytes, return a pointer to the
  48         first byte that contains the indicated byte in the source string.
  49         Return null if the byte is not found.
  50
  51         Undefined behavior will occur if the end of the source string (i.e.
  52         the terminating null byte) is in the last two words of the program's
  53         allocated memory space.  This is so because, in several cases, memchr
  54         will fetch ahead.  Disallowing the fetch ahead would impose a severe
  55         performance penalty.
  56
  57         This program handles two cases:
  58
  59         1) the argument starts on a word boundary
  60         2) the argument doesn't start on a word boundary
  61
  62         At the time of this writing, only g0 thru g7 and g13 are available
  63         for use in this leafproc;  other registers would have to be saved and
  64         restored.  These nine registers, plus tricky use of g14 are sufficient
  65         to implement the routine.  The registers are used as follows:
  66
  67         g0  src ptr;  upon return it is a pointer to the matching byte, or null
  68         g1  char to seek
  69         g2  maximum number of bytes to check
  70         g3  char to seek, broadcast to all four bytes
  71         g4  word of the source string
  72         g5  copy of the word
  73         g6  mask to avoid unimportant bytes in first word
  74         g7  byte extraction mask
  75         g13 return address
  76         g14
  77 */
  78
  79         .globl  _memchr
  80         .globl  __memchr
  81         .leafproc       _memchr, __memchr
  82         .align  2
  83 _memchr:
  84 #ifndef __PIC
  85         lda     Lrett,g14
  86 #else
  87         lda     Lrett-(.+8)(ip),g14
  88 #endif
  89 __memchr:
  90
  91         mov     g14,g13         # preserve return address
  92          lda    0xff,g7         # byte extraction mask
  93         and     g1,g7,g1        # make char an 8-bit ordinal
  94          lda    0,g14           # conform to register linkage standard
  95         cmpibge.f 0,g2,Lnot_found       # do nothing if max_bytes <= 0
  96         addo    g0,g2,g2        # compute ending address from start and len
  97         and     g0,3,g6         # extract byte offset of src
  98         notand  g0,3,g0         # extract word addr of start of src
  99         shlo    8,g1,g3         # broadcast the char to four bytes
 100          ld     (g0),g4         # fetch word containing at least first byte
 101         or      g1,g3,g3
 102         shlo    16,g3,g5
 103         cmpo    g1,g7           # is char being sought 0xff?
 104         or      g5,g3,g3
 105         shlo    3,g6,g6         # get shift count for making mask for first word
 106         subi    1,0,g5          # mask initially all ones
 107 #if __i960_BIG_ENDIAN__
 108         shro    g6,g5,g5        # get mask for bytes needed from first word
 109 #else
 110         shlo    g6,g5,g5        # get mask for bytes needed from first word
 111 #endif
 112         notor   g4,g5,g4        # set unneeded bytes to all ones
 113          be.f   Lsearch_for_0xff        # branch if seeking 0xff
 114
 115 Lsearch_for_word_with_char:
 116         scanbyte g3,g4          # check for byte with char
 117          lda    4(g0),g0        # pre-increment src word pointer
 118         mov     g4,g5           # keep a copy of word
 119         ld      (g0),g4         # fetch next word of src
 120          bo.f   Lsearch_for_char        # branch if null found
 121         cmpoble.t g0,g2,Lsearch_for_word_with_char      # branch if not null
 122
 123 Lnot_found:
 124         mov     0,g0            # char not found.  Return null
 125 Lexit_code:
 126         bx      (g13)           # g0 = addr of char in src (or null);  g14 = 0
 127 Lrett:
 128         ret
 129
 130 Lsearch_for_char:
 131         subo    4,g0,g0         # back up the byte pointer
 132 Lsearch_for_char.a:
 133         cmpobe.f g0,g2,Lnot_found       # quit if max_bytes exhausted
 134 #if __i960_BIG_ENDIAN__
 135         rotate  8,g5,g5         # shift word to position next byte
 136 #endif
 137         and     g5,g7,g6        # extract byte
 138         cmpo    g1,g6           # is it char?
 139          lda    1(g0),g0        # bump src byte ptr
 140 #if ! __i960_BIG_ENDIAN__
 141         shro    8,g5,g5         # shift word to position next byte
 142 #endif
 143          bne.t  Lsearch_for_char.a
 144         subo    1,g0,g0         # back up the byte pointer
 145          b      Lexit_code
 146
 147 Lsearch_for_0xff:
 148         lda     0xf0f0f0f0,g6   # make first comparison mask for char=-1 case.
 149         or      g6,g5,g6
 150         and     g4,g6,g4        # make unimportant bytes of first word 0x0f
 151          b      Lsearch_for_word_with_char
 152
 153 /* end of memchr */