python-dask/repos/community-any/PKGBUILD

   1 # Maintainer: Bruno Pagani <archange@archlinux.org>
   2
   3 _pkg=dask
   4 pkgname=python-${_pkg}
   5 pkgver=2023.4.0
   6 pkgrel=1
   7 pkgdesc="Parallel computing with task scheduling"
   8 arch=(any)
   9 url="https://dask.org"
  10 license=(BSD)
  11 depends=(
  12     mpdecimal
  13     python
  14     python-click
  15     python-cloudpickle
  16     python-fsspec
  17     python-importlib-metadata
  18     python-packaging
  19     python-partd
  20     python-pyyaml
  21     python-toolz
  22 )
  23 makedepends=(
  24     python-build
  25     python-installer
  26     python-setuptools
  27     python-versioneer
  28     python-wheel
  29 )
  30 optdepends=(
  31 #    'python-bokeh: visualizing dask diagnostics'
  32 #    'python-cityhash: faster hashing of arrays'
  33     'python-distributed: distributed computing'
  34 #    'python-fastparquet: storing and reading data from parquet files'
  35 #    'python-gcsfs: file-system interface to Google Cloud Storage'
  36 #    'python-jinja: diagnostics'
  37 #    'python-murmurhash: faster hashing of arrays'
  38     'python-numpy: arrays and dataframes support'
  39     'python-pandas: dataframes support'
  40     'python-psutil: more accurate CPU count'
  41     'python-pyarrow: Apache Arrow, for parquet support'
  42 #    'python-s3fs: Amazon S3 support'
  43     'python-sqlalchemy: writing and reading from SQL databases'
  44     'python-xxhash: faster hashing of arrays'
  45 )
  46 checkdepends=(
  47     ipython
  48     python-pytest
  49     python-pytest-rerunfailures
  50     python-aiohttp
  51 #    python-bokeh
  52     python-boto3
  53     python-botocore
  54     python-cytoolz
  55 #    python-cityhash
  56     python-distributed
  57 #    python-fastparquet
  58 #    python-gcsfs
  59     python-graphviz
  60     python-h5py
  61     python-httpretty
  62     python-jinja
  63     python-jsonschema
  64     python-lz4
  65     python-matplotlib
  66     python-moto
  67 #    python-murmurhash
  68 #    python-numba
  69     python-numexpr
  70     python-numpy
  71     python-pandas
  72     python-psutil
  73     python-pyarrow
  74     python-pytables
  75     python-requests
  76 #    python-s3fs
  77     python-scikit-learn
  78     python-scipy
  79     python-snappy
  80 #    python-sparse
  81     python-sqlalchemy
  82     python-xarray
  83     python-xxhash
  84 )
  85 #source=(https://files.pythonhosted.org/packages/source/${_pkg::1}/${_pkg}/${_pkg}-${pkgver}.tar.gz)
  86 source=(https://github.com/dask/dask/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
  87 sha256sums=('f3d4d4ab004f617f7f8f0dddac55a87c6ebae19fccdf2b68a400870bdbfbd4d3')
  88
  89 build() {
  90   cd ${_pkg}-${pkgver}
  91   python -m build --wheel --no-isolation
  92 }
  93
  94 check() {
  95   local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
  96   local pytest_options=(
  97     -vv
  98     --ignore test_dir/$site_packages/$_pkg/tests/test_distributed.py
  99   )
 100
 101   cd ${_pkg}-${pkgver}
 102   python -m installer --destdir=test_dir dist/*.whl
 103   export PYTHONPATH="$PWD/test_dir/$site_packages:$PYTHONPATH"
 104   pytest "${pytest_options[@]}" "$PWD/test_dir/$site_packages/$_pkg/"
 105 }
 106
 107 package() {
 108   cd ${_pkg}-${pkgver}
 109   python -m installer --destdir="$pkgdir" dist/*.whl
 110   install -Dm644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}/
 111 }