pkgs/applications/networking/znc/modules.nix

   1 { lib, stdenv, fetchFromGitHub, znc }:
   2
   3 let
   4   zncDerivation =
   5     a@{ pname
   6     , src
   7     , module_name
   8     , buildPhase ? "${znc}/bin/znc-buildmod ${module_name}.cpp"
   9     , installPhase ? "install -D ${module_name}.so $out/lib/znc/${module_name}.so"
  10     , ...
  11     }: stdenv.mkDerivation (a // {
  12       inherit buildPhase;
  13       inherit installPhase;
  14
  15       buildInputs = znc.buildInputs;
  16
  17       meta = a.meta // { platforms = lib.platforms.unix; };
  18       passthru.module_name = module_name;
  19     });
  20
  21 in
  22 {
  23
  24   backlog = zncDerivation rec {
  25     pname = "znc-backlog";
  26     version = "unstable-2017-06-13";
  27     module_name = "backlog";
  28
  29     src = fetchFromGitHub {
  30       owner = "FruitieX";
  31       repo = "znc-backlog";
  32       rev = "42e8f439808882d2dae60f2a161eabead14e4b0d";
  33       sha256 = "1k7ifpqqzzf2j7w795q4mx1nvmics2higzjqr3mid3lp43sqg5s6";
  34     };
  35
  36     meta = with lib; {
  37       description = "Request backlog for IRC channels";
  38       homepage = "https://github.com/fruitiex/znc-backlog/";
  39       license = licenses.asl20;
  40       maintainers = [ ];
  41     };
  42   };
  43
  44   clientbuffer = zncDerivation rec {
  45     pname = "znc-clientbuffer";
  46     version = "unstable-2021-05-30";
  47     module_name = "clientbuffer";
  48
  49     src = fetchFromGitHub {
  50       owner = "CyberShadow";
  51       repo = "znc-clientbuffer";
  52       rev = "9a7465b413b53408f5d7af86e84b1d08efb6bec0";
  53       sha256 = "0a3f4j6s5j7p53y42zrgpqyl2zm0jxb69lp24j6mni3licigh254";
  54     };
  55
  56     meta = with lib; {
  57       description = "ZNC module for client specific buffers";
  58       homepage = "https://github.com/CyberShadow/znc-clientbuffer";
  59       license = licenses.asl20;
  60       maintainers = with maintainers; [ hrdinka szlend cybershadow ];
  61     };
  62   };
  63
  64   clientaway = zncDerivation rec {
  65     pname = "znc-clientaway";
  66     version = "unstable-2017-04-28";
  67     module_name = "clientaway";
  68
  69     src = fetchFromGitHub {
  70       owner = "kylef";
  71       repo = "znc-contrib";
  72       rev = "f6724a4a3b16b050088adde0cbeed74f189e5044";
  73       sha256 = "0ikd3dzjjlr0gs0ikqfk50msm6mij99ln2rjzqavh58iwzr7n5r8";
  74     };
  75
  76     meta = with lib; {
  77       description = "ZNC clientaway module";
  78       homepage = "https://github.com/kylef/znc-contrib";
  79       license = licenses.gpl2;
  80       maintainers = [ ];
  81     };
  82   };
  83
  84   fish = zncDerivation rec {
  85     pname = "znc-fish";
  86     version = "unstable-2017-06-26";
  87     module_name = "fish";
  88
  89     src = fetchFromGitHub {
  90       # this fork works with ZNC 1.7
  91       owner = "oilslump";
  92       repo = "znc-fish";
  93       rev = "7d91467dbb195f7b591567911210523c6087662e";
  94       sha256 = "1ky5xg17k5f393whrv5iv8zsmdvdyk2f7z5qdsmxcwy3pdxy6vsm";
  95     };
  96
  97     meta = {
  98       description = "ZNC FiSH module";
  99       homepage = "https://github.com/dctrwatson/znc-fish";
 100       maintainers = [ lib.maintainers.offline ];
 101     };
 102   };
 103
 104   ignore = zncDerivation rec {
 105     pname = "znc-ignore";
 106     version = "unstable-2017-04-28";
 107     module_name = "ignore";
 108
 109     src = fetchFromGitHub {
 110       owner = "kylef";
 111       repo = "znc-contrib";
 112       rev = "f6724a4a3b16b050088adde0cbeed74f189e5044";
 113       sha256 = "0ikd3dzjjlr0gs0ikqfk50msm6mij99ln2rjzqavh58iwzr7n5r8";
 114     };
 115
 116     meta = with lib; {
 117       description = "ZNC ignore module";
 118       homepage = "https://github.com/kylef/znc-contrib";
 119       license = licenses.gpl2;
 120       maintainers = [ ];
 121     };
 122   };
 123
 124   palaver = zncDerivation rec {
 125     pname = "znc-palaver";
 126     version = "1.2.2";
 127     module_name = "palaver";
 128
 129     src = fetchFromGitHub {
 130       owner = "cocodelabs";
 131       repo = "znc-palaver";
 132       rev = version;
 133       hash = "sha256-8W3uF1PrLQiEZm7JaFrpqmJLSFioa4F4qlM1J6Zua8U=";
 134     };
 135
 136     meta = with lib; {
 137       description = "Palaver ZNC module";
 138       homepage = "https://github.com/cocodelabs/znc-palaver";
 139       license = licenses.mit;
 140       maintainers = with maintainers; [ szlend ];
 141     };
 142   };
 143
 144   playback = zncDerivation rec {
 145     pname = "znc-playback";
 146     version = "unstable-2015-08-04";
 147     module_name = "playback";
 148
 149     src = fetchFromGitHub {
 150       owner = "jpnurmi";
 151       repo = "znc-playback";
 152       rev = "8691abf75becc1f3d7b5bb5ad68dad17cd21863b";
 153       sha256 = "0mgfajljy035051b2sx70i8xrb51zw9q2z64kf85zw1lynihzyh4";
 154     };
 155
 156     meta = with lib; {
 157       description = "Advanced playback module for ZNC";
 158       homepage = "https://github.com/jpnurmi/znc-playback";
 159       license = licenses.asl20;
 160       maintainers = with maintainers; [ hrdinka ];
 161     };
 162   };
 163
 164   privmsg = zncDerivation rec {
 165     pname = "znc-privmsg";
 166     version = "unstable-2015-02-22";
 167     module_name = "privmsg";
 168
 169     src = fetchFromGitHub {
 170       owner = "kylef";
 171       repo = "znc-contrib";
 172       rev = "9f1f98db56cbbea96d83e6628f657e0d62cd9517";
 173       sha256 = "0n82z87gdxxragcaixjc80z8bw4bmfwbk0jrf9zs8kk42phlkkc2";
 174     };
 175
 176     meta = {
 177       description = "ZNC privmsg module";
 178       homepage = "https://github.com/kylef/znc-contrib";
 179     };
 180   };
 181
 182   push = zncDerivation rec {
 183     pname = "znc-push";
 184     version = "unstable-2016-10-12";
 185     module_name = "push";
 186
 187     src = fetchFromGitHub {
 188       owner = "jreese";
 189       repo = "znc-push";
 190       rev = "cf08b9e0f483f03c28d72dd78df932cbef141f10";
 191       sha256 = "0xpwjw8csyrg736g1jc1n8d6804x6kbdkrvldzhk9ldj4iwqz7ay";
 192     };
 193
 194     meta = {
 195       description = "Push notification service module for ZNC";
 196       homepage = "https://github.com/jreese/znc-push";
 197       license = lib.licenses.mit;
 198       maintainers = with lib.maintainers; [ offline schneefux ];
 199     };
 200   };
 201
 202 }