pkgs/development/libraries/gdk-pixbuf/default.nix

   1 { stdenv
   2 , fetchurl
   3 , nixosTests
   4 , fixDarwinDylibNames
   5 , meson
   6 , ninja
   7 , pkg-config
   8 , gettext
   9 , python3
  10 , docutils
  11 , gi-docgen
  12 , glib
  13 , libtiff
  14 , libjpeg
  15 , libpng
  16 , gnome
  17 , doCheck ? false
  18 , makeWrapper
  19 , lib
  20 , testers
  21 , buildPackages
  22 , withIntrospection ? lib.meta.availableOn stdenv.hostPlatform gobject-introspection && stdenv.hostPlatform.emulatorAvailable buildPackages
  23 , gobject-introspection
  24 }:
  25
  26 stdenv.mkDerivation (finalAttrs: {
  27   pname = "gdk-pixbuf";
  28   version = "2.42.12";
  29
  30   outputs = [ "out" "dev" "man" ]
  31     ++ lib.optional withIntrospection "devdoc"
  32     ++ lib.optional (stdenv.buildPlatform == stdenv.hostPlatform) "installedTests";
  33
  34   src = let
  35     inherit (finalAttrs) pname version;
  36   in fetchurl {
  37     url = "mirror://gnome/sources/${pname}/${lib.versions.majorMinor version}/${pname}-${version}.tar.xz";
  38     hash = "sha256-uVBbNEW5p+SM7TR2DDvLc+lm3zrJTJWhSMtmmrdI48c=";
  39   };
  40
  41   patches = [
  42     # Move installed tests to a separate output
  43     ./installed-tests-path.patch
  44   ];
  45
  46   # gdk-pixbuf-thumbnailer is not wrapped therefore strictDeps will work
  47   strictDeps = true;
  48
  49   depsBuildBuild = [
  50     pkg-config
  51   ];
  52
  53   nativeBuildInputs = [
  54     meson
  55     ninja
  56     pkg-config
  57     gettext
  58     python3
  59     makeWrapper
  60     glib
  61
  62     # for man pages
  63     docutils
  64   ] ++ lib.optionals stdenv.hostPlatform.isDarwin [
  65     fixDarwinDylibNames
  66   ] ++ lib.optionals withIntrospection [
  67     gi-docgen
  68     gobject-introspection
  69   ];
  70
  71   propagatedBuildInputs = [
  72     glib
  73     libtiff
  74     libjpeg
  75     libpng
  76   ];
  77
  78   mesonFlags = [
  79     "-Dgio_sniffing=false"
  80     (lib.mesonBool "gtk_doc" withIntrospection)
  81     (lib.mesonEnable "introspection" withIntrospection)
  82     (lib.mesonEnable "others" true)
  83   ];
  84
  85   postPatch = ''
  86     chmod +x build-aux/* # patchShebangs only applies to executables
  87     patchShebangs build-aux
  88
  89     substituteInPlace tests/meson.build --subst-var-by installedtestsprefix "$installedTests"
  90
  91     # Run-time dependency gi-docgen found: NO (tried pkgconfig and cmake)
  92     # it should be a build-time dep for build
  93     # TODO: send upstream
  94     substituteInPlace docs/meson.build \
  95       --replace "dependency('gi-docgen'," "dependency('gi-docgen', native:true," \
  96       --replace "'gi-docgen', req" "'gi-docgen', native:true, req"
  97
  98     # Remove 'ani' loader until proper fix for CVE-2022-48622
  99     substituteInPlace meson.build --replace-fail "'ani'," ""
 100   '';
 101
 102   postInstall =
 103     ''
 104       # All except one utility seem to be only useful during building.
 105       moveToOutput "bin" "$dev"
 106       moveToOutput "bin/gdk-pixbuf-thumbnailer" "$out"
 107
 108     '' + lib.optionalString stdenv.hostPlatform.isDarwin ''
 109       # meson erroneously installs loaders with .dylib extension on Darwin.
 110       # Their @rpath has to be replaced before gdk-pixbuf-query-loaders looks at them.
 111       for f in $out/${finalAttrs.passthru.moduleDir}/*.dylib; do
 112           install_name_tool -change @rpath/libgdk_pixbuf-2.0.0.dylib $out/lib/libgdk_pixbuf-2.0.0.dylib $f
 113           mv $f ''${f%.dylib}.so
 114       done
 115     '' + lib.optionalString withIntrospection ''
 116       # We need to install 'loaders.cache' in lib/gdk-pixbuf-2.0/2.10.0/
 117       ${stdenv.hostPlatform.emulator buildPackages} $dev/bin/gdk-pixbuf-query-loaders --update-cache
 118     '';
 119
 120   # The fixDarwinDylibNames hook doesn't patch binaries.
 121   preFixup = lib.optionalString stdenv.hostPlatform.isDarwin ''
 122     for f in $out/bin/* $dev/bin/*; do
 123         install_name_tool -change @rpath/libgdk_pixbuf-2.0.0.dylib $out/lib/libgdk_pixbuf-2.0.0.dylib $f
 124     done
 125   '';
 126
 127   postFixup = lib.optionalString withIntrospection ''
 128     # Cannot be in postInstall, otherwise _multioutDocs hook in preFixup will move right back.
 129     moveToOutput "share/doc" "$devdoc"
 130   '';
 131
 132   # The tests take an excessive amount of time (> 1.5 hours) and memory (> 6 GB).
 133   inherit doCheck;
 134
 135   setupHook = ./setup-hook.sh;
 136
 137   separateDebugInfo = stdenv.hostPlatform.isLinux;
 138
 139   passthru = {
 140     updateScript = gnome.updateScript {
 141       packageName = finalAttrs.pname;
 142       versionPolicy = "odd-unstable";
 143     };
 144
 145     tests = {
 146       installedTests = nixosTests.installed-tests.gdk-pixbuf;
 147       pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
 148     };
 149
 150     # gdk_pixbuf_binarydir and gdk_pixbuf_moduledir variables from gdk-pixbuf-2.0.pc
 151     binaryDir = "lib/gdk-pixbuf-2.0/2.10.0";
 152     moduleDir = "${finalAttrs.passthru.binaryDir}/loaders";
 153   };
 154
 155   meta = with lib; {
 156     description = "Library for image loading and manipulation";
 157     homepage = "https://gitlab.gnome.org/GNOME/gdk-pixbuf";
 158     license = licenses.lgpl21Plus;
 159     maintainers = teams.gnome.members;
 160     mainProgram = "gdk-pixbuf-thumbnailer";
 161     pkgConfigModules = [ "gdk-pixbuf-2.0" ];
 162     platforms = platforms.unix;
 163   };
 164 })