nixos/tests/guix/publish.nix

   1 # Testing out the substitute server with two machines in a local network. As a
   2 # bonus, we'll also test a feature of the substitute server being able to
   3 # advertise its service to the local network with Avahi.
   4
   5 import ../make-test-python.nix ({ pkgs, lib, ... }: let
   6   publishPort = 8181;
   7   inherit (builtins) toString;
   8 in {
   9   name = "guix-publish";
  10
  11   meta.maintainers = with lib.maintainers; [ foo-dogsquared ];
  12
  13   nodes = let
  14     commonConfig = { config, ... }: {
  15       # We'll be using '--advertise' flag with the
  16       # substitute server which requires Avahi.
  17       services.avahi = {
  18         enable = true;
  19         nssmdns4 = true;
  20         publish = {
  21           enable = true;
  22           userServices = true;
  23         };
  24       };
  25     };
  26   in {
  27     server = { config, lib, pkgs, ... }: {
  28       imports = [ commonConfig ];
  29
  30       services.guix = {
  31         enable = true;
  32         publish = {
  33           enable = true;
  34           port = publishPort;
  35
  36           generateKeyPair = true;
  37           extraArgs = [ "--advertise" ];
  38         };
  39       };
  40
  41       networking.firewall.allowedTCPPorts = [ publishPort ];
  42     };
  43
  44     client = { config, lib, pkgs, ... }: {
  45       imports = [ commonConfig ];
  46
  47       services.guix = {
  48         enable = true;
  49
  50         extraArgs = [
  51           # Force to only get all substitutes from the local server. We don't
  52           # have anything in the Guix store directory and we cannot get
  53           # anything from the official substitute servers anyways.
  54           "--substitute-urls='http://server.local:${toString publishPort}'"
  55
  56           # Enable autodiscovery of the substitute servers in the local
  57           # network. This machine shouldn't need to import the signing key from
  58           # the substitute server since it is automatically done anyways.
  59           "--discover=yes"
  60         ];
  61       };
  62     };
  63   };
  64
  65   testScript = ''
  66     import pathlib
  67
  68     start_all()
  69
  70     scripts_dir = pathlib.Path("/etc/guix/scripts")
  71
  72     for machine in machines:
  73       machine.wait_for_unit("multi-user.target")
  74       machine.wait_for_unit("guix-daemon.service")
  75       machine.wait_for_unit("avahi-daemon.service")
  76
  77     server.wait_for_unit("guix-publish.service")
  78     server.wait_for_open_port(${toString publishPort})
  79     server.succeed("curl http://localhost:${toString publishPort}/")
  80
  81     # Now it's the client turn to make use of it.
  82     substitute_server = "http://server.local:${toString publishPort}"
  83     client.systemctl("start network-online.target")
  84     client.wait_for_unit("network-online.target")
  85     response = client.succeed(f"curl {substitute_server}")
  86     assert "Guix Substitute Server" in response
  87
  88     # Authorizing the server to be used as a substitute server.
  89     client.succeed(f"curl -O {substitute_server}/signing-key.pub")
  90     client.succeed("guix archive --authorize < ./signing-key.pub")
  91
  92     # Since we're using the substitute server with the `--advertise` flag, we
  93     # might as well check it.
  94     client.succeed("avahi-browse --resolve --terminate _guix_publish._tcp | grep '_guix_publish._tcp'")
  95   '';
  96 })