pkgs/by-name/db/dbqn/package.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , jdk
   5 , makeWrapper
   6 , buildNativeImage ? false
   7 }:
   8
   9 stdenv.mkDerivation rec {
  10   pname = "dbqn" + lib.optionalString buildNativeImage "-native";
  11   version = "0.2.2";
  12
  13   src = fetchFromGitHub {
  14     owner = "dzaima";
  15     repo = "BQN";
  16     rev = "v${version}";
  17     hash = "sha256-AUfT7l7zr/pyG63wX8FMej8RUg7tXC1aroCrunjyw/8=";
  18   };
  19
  20   nativeBuildInputs = [
  21     jdk
  22     makeWrapper
  23   ];
  24
  25   dontConfigure = true;
  26
  27   postPatch = ''
  28     patchShebangs --build ./build8
  29   '';
  30
  31   buildPhase = ''
  32     runHook preBuild
  33
  34     ./build8
  35   '' + lib.optionalString buildNativeImage ''
  36     native-image --report-unsupported-elements-at-runtime \
  37       -H:CLibraryPath=${lib.getLib jdk}/lib -J-Dfile.encoding=UTF-8 \
  38       -jar BQN.jar dbqn
  39   '' + ''
  40     runHook postBuild
  41   '';
  42
  43   installPhase = ''
  44     runHook preInstall
  45
  46     mkdir -p $out/bin
  47
  48   '' + (if buildNativeImage then ''
  49     mv dbqn $out/bin
  50   '' else ''
  51     mkdir -p $out/share/dbqn
  52     mv BQN.jar $out/share/dbqn/
  53
  54     makeWrapper "${lib.getBin jdk}/bin/java" "$out/bin/dbqn" \
  55       --add-flags "-jar $out/share/dbqn/BQN.jar"
  56   '') + ''
  57     ln -s $out/bin/dbqn $out/bin/bqn
  58
  59     runHook postInstall
  60   '';
  61
  62   meta = with lib; {
  63     homepage = "https://github.com/dzaima/BQN";
  64     description = "BQN implementation in Java" + lib.optionalString buildNativeImage ", compiled as a native image";
  65     license = licenses.mit;
  66     maintainers = with maintainers; [ AndersonTorres sternenseemann ];
  67     inherit (jdk.meta) platforms;
  68     broken = stdenv.hostPlatform.isDarwin; # never built on Hydra https://hydra.nixos.org/job/nixpkgs/staging-next/dbqn-native.x86_64-darwin
  69   };
  70 }
  71 # TODO: Processing app
  72 # TODO: minimalistic JDK