nixos/modules/hardware/video/bumblebee.nix

   1 { config, lib, pkgs, ... }:
   2
   3 with lib;
   4 let
   5   cfg = config.hardware.bumblebee;
   6
   7   kernel = config.boot.kernelPackages;
   8
   9   useNvidia = cfg.driver == "nvidia";
  10
  11   bumblebee = pkgs.bumblebee.override {
  12     inherit useNvidia;
  13     useDisplayDevice = cfg.connectDisplay;
  14   };
  15
  16   useBbswitch = cfg.pmMethod == "bbswitch" || cfg.pmMethod == "auto" && useNvidia;
  17
  18   primus = pkgs.primus.override {
  19     inherit useNvidia;
  20   };
  21
  22 in
  23
  24 {
  25
  26   options = {
  27     hardware.bumblebee = {
  28
  29       enable = mkOption {
  30         default = false;
  31         type = types.bool;
  32         description = lib.mdDoc ''
  33           Enable the bumblebee daemon to manage Optimus hybrid video cards.
  34           This should power off secondary GPU until its use is requested
  35           by running an application with optirun.
  36         '';
  37       };
  38
  39       group = mkOption {
  40         default = "wheel";
  41         example = "video";
  42         type = types.str;
  43         description = lib.mdDoc "Group for bumblebee socket";
  44       };
  45
  46       connectDisplay = mkOption {
  47         default = false;
  48         type = types.bool;
  49         description = lib.mdDoc ''
  50           Set to true if you intend to connect your discrete card to a
  51           monitor. This option will set up your Nvidia card for EDID
  52           discovery and to turn on the monitor signal.
  53
  54           Only nvidia driver is supported so far.
  55         '';
  56       };
  57
  58       driver = mkOption {
  59         default = "nvidia";
  60         type = types.enum [ "nvidia" "nouveau" ];
  61         description = lib.mdDoc ''
  62           Set driver used by bumblebeed. Supported are nouveau and nvidia.
  63         '';
  64       };
  65
  66       pmMethod = mkOption {
  67         default = "auto";
  68         type = types.enum [ "auto" "bbswitch" "switcheroo" "none" ];
  69         description = lib.mdDoc ''
  70           Set preferred power management method for unused card.
  71         '';
  72       };
  73
  74     };
  75   };
  76
  77   config = mkIf cfg.enable {
  78     boot.blacklistedKernelModules = [ "nvidia-drm" "nvidia" "nouveau" ];
  79     boot.kernelModules = optional useBbswitch "bbswitch";
  80     boot.extraModulePackages = optional useBbswitch kernel.bbswitch ++ optional useNvidia kernel.nvidia_x11.bin;
  81
  82     environment.systemPackages = [ bumblebee primus ];
  83
  84     systemd.services.bumblebeed = {
  85       description = "Bumblebee Hybrid Graphics Switcher";
  86       wantedBy = [ "multi-user.target" ];
  87       before = [ "display-manager.service" ];
  88       serviceConfig = {
  89         ExecStart = "${bumblebee}/bin/bumblebeed --use-syslog -g ${cfg.group} --driver ${cfg.driver} --pm-method ${cfg.pmMethod}";
  90       };
  91     };
  92   };
  93 }