pkgs/by-name/wc/wcurl/package.nix

   1 {
   2   stdenvNoCC,
   3   lib,
   4   curl,
   5   fetchFromGitLab,
   6   installShellFiles,
   7   nix-update-script,
   8   shunit2,
   9 }:
  10
  11 stdenvNoCC.mkDerivation (finalAttrs: {
  12   pname = "wcurl";
  13   version = "2024.07.10";
  14
  15   src = fetchFromGitLab {
  16     domain = "salsa.debian.org";
  17     owner = "debian";
  18     repo = "wcurl";
  19     rev = "refs/tags/${finalAttrs.version}";
  20     hash = "sha256-FYkG74uoXFNYT7tszDcdCPQCEG3ePOFBUgIUYpsAzb8=";
  21   };
  22
  23   strictDeps = true;
  24
  25   nativeBuildInputs = [ installShellFiles ];
  26
  27   nativeCheckInputs = [ shunit2 ];
  28
  29   doCheck = true;
  30
  31   dontBuild = true;
  32
  33   postPatch = ''
  34     substituteInPlace wcurl \
  35       --replace-fail '"curl "' '"${curl}/bin/curl "'
  36   '';
  37
  38   checkPhase = ''
  39     runHook preCheck
  40
  41     tests/tests.sh
  42
  43     runHook postCheck
  44   '';
  45
  46   installPhase = ''
  47     runHook preInstall
  48
  49     install -D wcurl -t $out/bin
  50     installManPage wcurl.1
  51
  52     runHook postInstall
  53   '';
  54
  55   passthru.updateScript = nix-update-script { };
  56
  57   meta = {
  58     homepage = "https://salsa.debian.org/debian/wcurl";
  59     description = "Simple wrapper around curl to easily download files";
  60     mainProgram = "wcurl";
  61     license = lib.licenses.curl;
  62     maintainers = with lib.maintainers; [ deejayem ];
  63     platforms = lib.platforms.all;
  64   };
  65 })