pkgs/by-name/ps/psqlodbc/package.nix

   1 { lib, stdenv, fetchurl, postgresql, openssl
   2 , withLibiodbc ? false, libiodbc
   3 , withUnixODBC ? true, unixODBC
   4 }:
   5
   6 assert lib.xor withLibiodbc withUnixODBC;
   7
   8 stdenv.mkDerivation rec {
   9   pname = "psqlodbc";
  10   version = "16.00.0000";
  11
  12   src = fetchurl {
  13     url = "mirror://postgresql/odbc/versions.old/src/${pname}-${version}.tar.gz";
  14     hash = "sha256-r9iS+J0uzujT87IxTxvVvy0CIBhyxuNDHlwxCW7KTIs=";
  15   };
  16
  17   buildInputs = [
  18     postgresql
  19     openssl
  20   ]
  21   ++ lib.optional withLibiodbc libiodbc
  22   ++ lib.optional withUnixODBC unixODBC;
  23
  24   passthru = lib.optionalAttrs withUnixODBC {
  25     fancyName = "PostgreSQL";
  26     driver = "lib/psqlodbcw.so";
  27   };
  28
  29   configureFlags = [
  30     "--with-libpq=${lib.getDev postgresql}/bin/pg_config"
  31   ]
  32   ++ lib.optional withLibiodbc "--with-iodbc=${libiodbc}";
  33
  34   meta = with lib; {
  35     homepage = "https://odbc.postgresql.org/";
  36     description = "ODBC driver for PostgreSQL";
  37     license = licenses.lgpl2;
  38     platforms = platforms.unix;
  39     maintainers = [ ];
  40   };
  41 }