pkgs/development/libraries/physics/hepmc3/default.nix

   1 { lib, stdenv, fetchurl, cmake, coreutils, python, root }:
   2
   3 let
   4   pythonVersion = with lib.versions; "${major python.version}${minor python.version}";
   5   withPython = python != null;
   6   # ensure that root is built with the same python interpreter, as it links against numpy
   7   root_py = if withPython then root.override { inherit python; } else root;
   8 in
   9
  10 stdenv.mkDerivation rec {
  11   pname = "hepmc3";
  12   version = "3.2.5";
  13
  14   src = fetchurl {
  15     url = "http://hepmc.web.cern.ch/hepmc/releases/HepMC3-${version}.tar.gz";
  16     sha256 = "sha256-zQ91yA91VJxZzCqCns52Acd96Xyypat1eQysjh1YUDI=";
  17   };
  18
  19   nativeBuildInputs = [ cmake ];
  20   buildInputs = [ root_py ]
  21     ++ lib.optional withPython python;
  22
  23   cmakeFlags = [
  24     "-DHEPMC3_ENABLE_PYTHON=${if withPython then "ON" else "OFF"}"
  25   ] ++ lib.optionals withPython [
  26     "-DHEPMC3_PYTHON_VERSIONS=${if python.isPy3k then "3.X" else "2.X"}"
  27     "-DHEPMC3_Python_SITEARCH${pythonVersion}=${placeholder "out"}/${python.sitePackages}"
  28   ];
  29
  30   postInstall = ''
  31     substituteInPlace "$out"/bin/HepMC3-config \
  32       --replace 'greadlink' '${coreutils}/bin/readlink' \
  33       --replace 'readlink' '${coreutils}/bin/readlink'
  34   '';
  35
  36   doInstallCheck = withPython;
  37   # prevent nix from trying to dereference a null python
  38   installCheckPhase = lib.optionalString withPython ''
  39     PYTHONPATH=${placeholder "out"}/${python.sitePackages} python -c 'import pyHepMC3'
  40   '';
  41
  42   meta = with lib; {
  43     description = "The HepMC package is an object oriented, C++ event record for High Energy Physics Monte Carlo generators and simulation";
  44     license = licenses.gpl3;
  45     homepage = "http://hepmc.web.cern.ch/hepmc/";
  46     platforms = platforms.unix;
  47     maintainers = with maintainers; [ veprbl ];
  48   };
  49 }