pkgs/development/libraries/xapian/default.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , autoreconfHook
   5 , libuuid
   6 , zlib
   7
   8 # tests
   9 , mu
  10 }:
  11
  12 let
  13   generic = version: hash: stdenv.mkDerivation {
  14     pname = "xapian";
  15     inherit version;
  16     passthru = { inherit version; };
  17
  18     src = fetchurl {
  19       url = "https://oligarchy.co.uk/xapian/${version}/xapian-core-${version}.tar.xz";
  20       inherit hash;
  21     };
  22
  23     outputs = [ "out" "man" "doc" ];
  24
  25     buildInputs = [ libuuid zlib ];
  26     nativeBuildInputs = [ autoreconfHook ];
  27
  28     doCheck = true;
  29     AUTOMATED_TESTING = true; # https://trac.xapian.org/changeset/8be35f5e1/git
  30
  31     patches = lib.optionals stdenv.isDarwin [ ./skip-flaky-darwin-test.patch ];
  32
  33     # the configure script thinks that Darwin has ___exp10
  34     # but it’s not available on my systems (or hydra apparently)
  35     postConfigure = lib.optionalString stdenv.isDarwin ''
  36       substituteInPlace config.h \
  37         --replace "#define HAVE___EXP10 1" "#undef HAVE___EXP10"
  38     '';
  39
  40     passthru.tests = {
  41       inherit mu;
  42     };
  43
  44     meta = with lib; {
  45       description = "Search engine library";
  46       homepage = "https://xapian.org/";
  47       changelog = "https://xapian.org/docs/xapian-core-${version}/NEWS";
  48       license = licenses.gpl2Plus;
  49       maintainers = with maintainers; [ ];
  50       platforms = platforms.unix;
  51     };
  52   };
  53 in {
  54   # Don't forget to change the hashes in xapian-omega and
  55   # python3Packages.xapian. They inherit the version from this package, and
  56   # should always be built with the equivalent xapian version.
  57   xapian_1_4 = generic "1.4.21" "sha256-gPhgNNL7VZAHlUgd+uaBv6oQ776BirrTYizcDFXgb4g=";
  58 }