pkgs/by-name/al/alsa-tools/package.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , alsa-lib
   5 , fltk13
   6 , gtk2
   7 , gtk3
   8 , makeWrapper
   9 , pkg-config
  10 , psmisc
  11 }:
  12
  13 stdenv.mkDerivation (finalAttrs: {
  14   pname = "alsa-tools";
  15   version = "1.2.5";
  16
  17   src = fetchurl {
  18     url = "mirror://alsa/tools/alsa-tools-${finalAttrs.version}.tar.bz2";
  19     hash = "sha256-NacQJ6AfTX3kci4iNSDpQN5os8VwtsZxaRVnrij5iT4=";
  20   };
  21
  22   nativeBuildInputs = [
  23     makeWrapper
  24     pkg-config
  25   ];
  26
  27   buildInputs = [
  28     alsa-lib
  29     fltk13
  30     gtk2
  31     gtk3
  32     psmisc
  33   ];
  34
  35   env.TOOLSET = lib.concatStringsSep " " [
  36     "as10k1"
  37     "echomixer"
  38     "envy24control"
  39     "hda-verb"
  40     "hdajackretask"
  41     "hdajacksensetest"
  42     "hdspconf"
  43     "hdsploader"
  44     "hdspmixer"
  45     # "hwmixvolume" # Requires old, unmaintained, abandoned EOL Python 2
  46     "ld10k1"
  47     # "qlo10k1" # needs Qt
  48     "mixartloader"
  49     "pcxhrloader"
  50     "rmedigicontrol"
  51     "sb16_csp"
  52     # "seq" # mysterious configure error
  53     "sscape_ctl"
  54     "us428control"
  55     # "usx2yloader" # tries to create /etc/hotplug/usb
  56     "vxloader"
  57   ];
  58
  59   configurePhase = ''
  60     runHook preConfigure
  61
  62     for tool in $TOOLSET; do
  63       echo "Configuring $tool:"
  64       pushd "$tool"
  65       ./configure --prefix="$out"
  66       popd
  67     done
  68
  69     runHook postConfigure
  70   '';
  71
  72   buildPhase = ''
  73     runHook preBuild
  74
  75     for tool in $TOOLSET; do
  76       echo "Building $tool:"
  77       pushd "$tool"
  78       make
  79       popd
  80     done
  81
  82     runHook postBuild
  83   '';
  84
  85   installPhase = ''
  86     runHook preInstall
  87
  88     for tool in $TOOLSET; do
  89       echo "Installing $tool:"
  90       pushd "$tool"
  91       make install
  92       popd
  93     done
  94
  95     runHook postInstall
  96   '';
  97
  98   fixupPhase = ''
  99     runHook preFixup
 100
 101     wrapProgram $out/bin/hdajackretask \
 102       --prefix PATH : ${lib.makeBinPath [ psmisc ]}
 103
 104     runHook postFixup
 105   '';
 106
 107   meta = {
 108     homepage = "http://www.alsa-project.org/";
 109     description = "ALSA Tools";
 110     license = lib.licenses.gpl2Plus;
 111     maintainers = [ lib.maintainers.AndersonTorres ];
 112     platforms = lib.platforms.linux;
 113   };
 114 })