networkmanager-pptp/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgname=networkmanager-pptp
   5 pkgver=1.2.10
   6 pkgrel=2
   7 pkgdesc="NetworkManager VPN plugin for PPTP"
   8 url="https://wiki.gnome.org/Projects/NetworkManager"
   9 arch=(x86_64)
  10 license=(GPL)
  11 _pppver=2.4.9
  12 depends=(libnm libsecret "ppp=$_pppver" pptpclient)
  13 makedepends=(libnma libnma-gtk4 intltool python git)
  14 optdepends=('libnma: GUI support (GTK 3)'
  15             'libnma-gtk4: GUI support (GTK 4)')
  16 options=(debug)
  17 _commit=0c066e55fe9b34bf4c05e82601feee78c6bf29b1  # tags/1.2.10^0
  18 source=("git+https://gitlab.gnome.org/GNOME/NetworkManager-pptp.git#commit=$_commit")
  19 sha256sums=('SKIP')
  20
  21 pkgver() {
  22   cd NetworkManager-pptp
  23   git describe --tags | sed 's/-dev/dev/;s/[^-]*-g/r&/;s/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd NetworkManager-pptp
  28   intltoolize --automake --copy
  29   autoreconf -fvi
  30 }
  31
  32 build() {
  33   cd NetworkManager-pptp
  34   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
  35     --libexecdir=/usr/lib --disable-static --with-gtk4 \
  36     --with-pppd-plugin-dir=/usr/lib/pppd/$_pppver
  37   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  38   make
  39 }
  40
  41 package() {
  42   cd NetworkManager-pptp
  43   make DESTDIR="$pkgdir" install dbusservicedir=/usr/share/dbus-1/system.d
  44 }
  45
  46 # vim:set sw=2 et: