rsync/trunk/PKGBUILD

   1 # Maintainer: Christian Hesse <mail@eworm.de>
   2
   3 pkgname=rsync
   4 _tag='db2a0aed76cfedeb87179017167c29cc2ab7a1e8' # git rev-parse v${pkgver}
   5 pkgver=3.2.4
   6 pkgrel=1
   7 pkgdesc='A fast and versatile file copying tool for remote and local files'
   8 arch=('x86_64')
   9 url='https://rsync.samba.org/'
  10 license=('GPL3')
  11 depends=('acl' 'libacl.so' 'lz4' 'openssl' 'perl' 'popt' 'xxhash' 'libxxhash.so'
  12          'zlib' 'zstd')
  13 makedepends=('git' 'python-commonmark')
  14 backup=('etc/rsyncd.conf'
  15         'etc/xinetd.d/rsync')
  16 validpgpkeys=('0048C8B026D4C96F0E589C2F6C859FB14B96A8C5') # Wayne Davison <wayned@users.sourceforge.net>
  17 source=("git+https://github.com/WayneD/rsync#tag=${_tag}?signed"
  18         'rsyncd.conf')
  19 sha256sums=('SKIP'
  20             '733ccb571721433c3a6262c58b658253ca6553bec79c2bdd0011810bb4f2156b')
  21
  22 build() {
  23         cd "$srcdir/rsync"
  24
  25         ./configure \
  26                 --prefix=/usr \
  27                 --disable-debug \
  28                 --with-included-popt=no \
  29                 --with-included-zlib=no
  30         make
  31 }
  32
  33 check() {
  34         cd "$srcdir/rsync"
  35
  36         make test
  37 }
  38
  39 package() {
  40         cd "$srcdir/rsync"
  41
  42         make DESTDIR="$pkgdir" install
  43         install -Dm0644 ../rsyncd.conf "$pkgdir/etc/rsyncd.conf"
  44         install -Dm0644 packaging/lsb/rsync.xinetd "$pkgdir/etc/xinetd.d/rsync"
  45         install -Dm0644 packaging/systemd/rsync.service "$pkgdir/usr/lib/systemd/system/rsyncd.service"
  46         install -Dm0644 packaging/systemd/rsync.socket "$pkgdir/usr/lib/systemd/system/rsyncd.socket"
  47         install -Dm0644 packaging/systemd/rsync@.service "$pkgdir/usr/lib/systemd/system/rsyncd@.service"
  48         install -Dm0755 support/rrsync "$pkgdir/usr/lib/rsync/rrsync"
  49 }