gnome-bluetooth-3.0/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3 # Contributor: Roman Kyrylych <roman@archlinux.org>
   4
   5 pkgname=gnome-bluetooth-3.0
   6 pkgver=42.5
   7 pkgrel=1
   8 pkgdesc="GNOME Bluetooth Subsystem"
   9 url="https://wiki.gnome.org/Projects/GnomeBluetooth"
  10 arch=(x86_64)
  11 license=(GPL LGPL)
  12 depends=(gtk4 libadwaita libnotify bluez gsound systemd pulseaudio-bluetooth
  13          upower)
  14 makedepends=(gobject-introspection gtk-doc docbook-xsl git meson)
  15 checkdepends=(python-dbusmock)
  16 provides=(libgnome-bluetooth{,-ui}-3.0.so)
  17 options=(debug)
  18 _commit=8ff1cc5f60b4855c9618d3cef75abf9a0b9c66f8  # master
  19 source=("git+https://gitlab.gnome.org/GNOME/gnome-bluetooth.git#commit=$_commit")
  20 sha256sums=('SKIP')
  21
  22 pkgver() {
  23   cd gnome-bluetooth
  24   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  25 }
  26
  27 prepare() {
  28   cd gnome-bluetooth
  29
  30   # Fixup missing tag
  31   git tag -f 42.5 8ff1cc5f60b4855c9618d3cef75abf9a0b9c66f8
  32 }
  33
  34 build() {
  35   arch-meson gnome-bluetooth build -D gtk_doc=true
  36   meson compile -C build
  37 }
  38
  39 check() {
  40   meson test -C build --print-errorlogs
  41 }
  42
  43 package() {
  44   meson install -C build --destdir "$pkgdir"
  45 }
  46
  47 # vim:set sw=2 sts=-1 et: