adwaita-icon-theme/repos/extra-any/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Lukas Fleischer <lfleischer@archlinux.org>
   3 # Contributor: Jan de Groot <jgc@archlinux.org>
   4
   5 pkgbase=adwaita-icon-theme
   6 pkgname=(adwaita-icon-theme adwaita-cursors)
   7 pkgver=43
   8 pkgrel=2
   9 pkgdesc="GNOME standard icons"
  10 url="https://gitlab.gnome.org/GNOME/adwaita-icon-theme"
  11 arch=(any)
  12 license=(LGPL3 CCPL:by-sa)
  13 depends=(hicolor-icon-theme gtk-update-icon-cache librsvg)
  14 makedepends=(git gtk3)
  15 _commit=3ea65342a846b2b29fe6feedcd13e2ecc5b5c2b2  # tags/43^0
  16 source=("git+https://gitlab.gnome.org/GNOME/adwaita-icon-theme.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd $pkgname
  21   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd $pkgname
  26   autoreconf -fvi
  27 }
  28
  29 build() {
  30   cd $pkgname
  31   ./configure --prefix=/usr
  32   make
  33 }
  34
  35 check() {
  36   cd $pkgname
  37   make check
  38 }
  39
  40 package_adwaita-icon-theme() {
  41   depends+=(adwaita-cursors)
  42
  43   make -C $pkgname DESTDIR="$pkgdir" install
  44
  45   mkdir -p cursors/usr/share/icons/Adwaita
  46   mv {"$pkgdir",cursors}/usr/share/icons/Adwaita/cursors
  47 }
  48
  49 package_adwaita-cursors() {
  50   pkgdesc="GNOME standard cursors"
  51   depends=()
  52
  53   mv cursors/* "$pkgdir"
  54 }
  55
  56 # vim:set sw=2 sts=-1 et: