dav1d/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2
   3 pkgbase=dav1d
   4 pkgname=(dav1d dav1d-doc)
   5 pkgver=1.0.0
   6 pkgrel=1
   7 pkgdesc='AV1 cross-platform decoder focused on speed and correctness'
   8 url='https://code.videolan.org/videolan/dav1d/'
   9 arch=('x86_64')
  10 license=('BSD')
  11 makedepends=('meson' 'ninja' 'nasm' 'doxygen' 'graphviz' 'xxhash')
  12 source=(https://downloads.videolan.org/pub/videolan/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.xz{,.asc}
  13         https://code.videolan.org/videolan/dav1d-test-data/-/archive/${pkgver}/dav1d-test-data-${pkgver}.tar.gz)
  14 sha512sums=('a3a7e162e45181449cd42af3a4d36669a850a4ee9ab17641dcd63d84406444566e8ebc7caa55b0620ab581039f36d19a90218a40f52ebbe525b37ed9493fb3f3'
  15             'SKIP'
  16             '6ce106e13217296ab9521dfb447c988f499770b201bc34b3aa4e161274139f6c6654d01b0a09f75e599c485ab8ff1bbac417acab6716f8f7c7c134278eea2e0e')
  17 b2sums=('792ba23ce3bd2ed9245d94daebf3a1e3e1df3cb463a9c54a0c23190801fc71c98c66f54f52b821f7741c818c80b308f41c5aed3ba68e234034285a48044f433e'
  18         'SKIP'
  19         '76a41bdfa50c68cb1133b7669698e2f463c5ddd716919235d7b3624039dd4ed1e78b2e917796372caec2290affb3713d118373109d6baec921adeb7367a8117c')
  20 validpgpkeys=('65F7C6B4206BD057A7EB73787180713BE58D1ADC') # VideoLAN Release Signing Key
  21
  22 prepare() {
  23   cd ${pkgbase}-${pkgver}
  24   ln -s "${srcdir}/dav1d-test-data-${pkgver}" tests/dav1d-test-data
  25 }
  26
  27 build() {
  28   cd ${pkgbase}-${pkgver}
  29   arch-meson \
  30     -Dtestdata_tests=true \
  31     -Denable_docs=true \
  32     build
  33   ninja -C build all doc/html
  34 }
  35
  36 check() {
  37   cd ${pkgbase}-${pkgver}/build
  38   meson test
  39 }
  40
  41 package_dav1d() {
  42   depends=('glibc')
  43   provides=('libdav1d.so')
  44   optdepends=('dav1d-doc: HTML documentation')
  45
  46   cd ${pkgbase}-${pkgver}
  47   DESTDIR="${pkgdir}" ninja -C build install
  48   install -Dm 644 README.md CONTRIBUTING.md NEWS -t "${pkgdir}/usr/share/doc/${pkgname}"
  49   install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
  50 }
  51
  52 package_dav1d-doc() {
  53   pkgdesc+=" (documentation)"
  54
  55   cd ${pkgbase}-${pkgver}
  56   install -d "${pkgdir}/usr/share/doc/${pkgbase}"
  57   cp -r build/doc/html -t "${pkgdir}/usr/share/doc/${pkgbase}"
  58   install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
  59 }
  60
  61 # vim: ts=2 sw=2 et: