libxfce4ui/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
   2 # Contributor: Xavier Devlamynck <magicrhesus@ouranos.be>
   3
   4 pkgname=libxfce4ui
   5 pkgver=4.16.1
   6 pkgrel=1
   7 pkgdesc="Commonly used Xfce widgets among Xfce applications"
   8 arch=('x86_64')
   9 url="https://www.xfce.org/"
  10 license=('GPL2')
  11 depends=('libxfce4util' 'gtk3' 'xfconf' 'libsm' 'startup-notification'
  12          'libgtop' 'libepoxy' 'hicolor-icon-theme')
  13 makedepends=('intltool' 'gobject-introspection' 'vala')
  14 source=(https://archive.xfce.org/src/xfce/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.bz2)
  15 sha256sums=('d96946ae5af6bf078dda415419e0021909f763ee0020b42f3e26f603e51585f6')
  16
  17 build() {
  18   cd "$srcdir/$pkgname-$pkgver"
  19
  20   ./configure \
  21     --prefix=/usr \
  22     --sysconfdir=/etc \
  23     --libexecdir=/usr/lib \
  24     --localstatedir=/var \
  25     --disable-static \
  26     --disable-debug \
  27     --with-vendor-info='Arch Linux'
  28   make
  29 }
  30
  31 package() {
  32   cd "$srcdir/$pkgname-$pkgver"
  33   make DESTDIR="$pkgdir" install
  34 }
  35
  36 # vim:set ts=2 sw=2 et: