sof-bin/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgbase=sof-bin
   4 pkgname=(sof-firmware sof-tools)
   5 pkgver=2.2.4
   6 pkgrel=1
   7 pkgdesc="Sound Open Firmware"
   8 url="https://www.sofproject.org/"
   9 arch=(x86_64)
  10 license=(custom:BSD custom:ISC)
  11 options=(debug)
  12 _binver=v${pkgver}
  13 source=(https://github.com/thesofproject/sof-bin/releases/download/$_binver/sof-bin-$_binver.tar.gz)
  14 sha256sums=('ce8aaeba103aa56a82662552b0f33f33a859aa1008d8bfbc2c22f0ccfc8c6b3a')
  15
  16 package_sof-firmware() {
  17   options+=(!strip)
  18
  19   local fwdir="$pkgdir/usr/lib/firmware/intel"
  20   mkdir -p "$fwdir"
  21
  22   cd sof-bin-$_binver
  23
  24   cp -at "$fwdir" sof-$_binver
  25   ln -sr "$fwdir"/{sof-$_binver,sof}
  26
  27   cp -at "$fwdir" sof-tplg-$_binver
  28   ln -sr "$fwdir"/{sof-tplg-$_binver,sof-tplg}
  29
  30   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 LICENCE* Notice*
  31 }
  32
  33 package_sof-tools() {
  34   pkgdesc+=" - tools"
  35   depends=(alsa-lib)
  36
  37   cd sof-bin-$_binver
  38
  39   install -Dt "$pkgdir/usr/bin" tools-$_binver/*
  40   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 LICENCE* Notice*
  41 }
  42
  43 # vim:set sw=2 sts=-1 et: